PowerDesigner列名、註釋內容互換

    在用PowerDesigner時，常常在NAME或Comment中寫中文在Code中寫英文，Name只會顯示給我們看，Code會使用在代碼中，但Comment中的文字會保存到數據庫TABLE的Description中，有時候我們寫好了Name再寫一次Comment很麻煩，以下兩段代碼就可以解決這個問題。
在PowerDesigner中PowerDesigner->Tools->Execute Commands->Edit/Run Scripts（Ctrl Shift X），然後將下面的腳本粘貼進去，並運行，即可

代碼一:將Name中的字符COPY至Comment中
'******************************************************************************
'* File:     name2comment.vbs
'* Purpose:   Database generation cannot use object names anymore
'         in version 7 and above.
'         It always uses the object codes.
'
'         In case the object codes are not aligned with your
'         object names in your model, this script will copy
'         the object Name onto the object Comment for
'         the Tables and Columns.
'
'* Title:
'* Version:   1.0
'* Company:   Sybase Inc.
'******************************************************************************
Option Explicit
ValidationMode = True
InteractiveMode = im_Batch

Dim mdl ' the current model

' get the current active model
Set mdl = ActiveModel
If (mdl Is Nothing) Then
  MsgBox "There is no current Model "
ElseIf Not mdl.IsKindOf(PdPDM.cls_Model) Then
  MsgBox "The current model is not an Physical Data model. "
Else
  ProcessFolder mdl
End If

' This routine copy name into comment for each table, each column and each view
' of the current folder
Private sub ProcessFolder(folder)
  Dim Tab 'running   table
  for each Tab in folder.tables
    if not tab.isShortcut then
      tab.comment = tab.name
      Dim col ' running column
      for each col in tab.columns
        col.comment= col.name
      next
    end if
  next

  Dim view 'running view
  for each view in folder.Views
    if not view.isShortcut then
      view.comment = view.name
    end if
  next

  ' go into the sub-packages
  Dim f ' running folder
  For Each f In folder.Packages
    if not f.IsShortcut then
      ProcessFolder f
    end if
  Next
end sub

代碼二:將Comment中的字符COPY至Name中
Option Explicit
ValidationMode = True
InteractiveMode = im_Batch

Dim mdl ' the current model

' get the current active model
Set mdl = ActiveModel
If (mdl Is Nothing) Then
  MsgBox "There is no current Model "
ElseIf Not mdl.IsKindOf(PdPDM.cls_Model) Then
  MsgBox "The current model is not an Physical Data model. "
Else
  ProcessFolder mdl
End If

Private sub ProcessFolder(folder)
On Error Resume Next
  Dim Tab 'running   table
  for each Tab in folder.tables
    if not tab.isShortcut then
      tab.name = tab.comment
      Dim col ' running column
      for each col in tab.columns
      if col.comment="" then
      else
        col.name= col.comment
      end if
      next
    end if
  next

  Dim view 'running view
  for each view in folder.Views
    if not view.isShortcut then
      view.name = view.comment
    end if
  next

  ' go into the sub-packages
  Dim f ' running folder
  For Each f In folder.Packages
    if not f.IsShortcut then
      ProcessFolder f
    end if
  Next
end sub

代碼三：將Name中的字符COPY至Comment中（優化）
'把pd中那麼name想自動添加到comment裏面
'如果comment爲空,則填入name;如果不爲空,則保留不變,這樣可以避免已有的註釋丟失.

Option Explicit
ValidationMode = True
InteractiveMode = im_Batch

Dim mdl ' the current model

' get the current active model
Set mdl = ActiveModel
If (mdl Is Nothing) Then
  MsgBox "There is no current Model "
ElseIf Not mdl.IsKindOf(PdPDM.cls_Model) Then
  MsgBox "The current model is not an Physical Data model. "
Else
  ProcessFolder mdl
End If

' This routine copy name into comment for each table, each column and each view
' of the current folder
Private sub ProcessFolder(folder)
  Dim Tab 'running   table
  for each Tab in folder.tables
    if not tab.isShortcut then
         if trim(tab.comment)="" then '如果有表的註釋,則不改變它.如果沒有表註釋.則把name添加到註釋裏面.
       tab.comment = tab.name
         end if
      Dim col ' running column
      for each col in tab.columns
        if trim(col.comment)="" then '如果col的comment爲空,則填入name,如果已有註釋,則不添加;這樣可以避免已有註釋丟失.
         col.comment= col.name
        end if
      next
    end if
  next

  Dim view 'running view
  for each view in folder.Views
    if not view.isShortcut and trim(view.comment)="" then
      view.comment = view.name
    end if
  next

  ' go into the sub-packages
  Dim f ' running folder
  For Each f In folder.Packages
    if not f.IsShortcut then
      ProcessFolder f
    end if
  Next
end sub