awk是一個強大的文本分析工具，同時也是處理文本的編程語言工具。相對於grep的查找，sed的編輯，awk在其對數據分析並生成報告時，顯得尤爲強大。簡單來說awk就是把文件逐行的讀入，以空格爲默認分隔符將每行切片，切開的部分再進行各種分析處理。
awk有3個不同版本：
awk
nawk：New awk
gawk：GNU awk
格式：
# awk [options] 'script' file1 file2, ...
# awk [options] 'PATTERN { action }' file1 file2, ...
awk輸出：
一、print
print的使用格式：
print item1, item2, ...
要點：
1、各項目之間使用逗號隔開，而輸出時則以空白字符分隔；
2、輸出的item可以爲字符串或數值、當前記錄的字段(如$1)、變量或awk的表達式；數值會先轉換爲字符串，而後再輸出；
3、print命令後面的item可以省略，此時其功能相當於print $0，因此，如果想輸出空白行，則需要使用print ""；
Example：
# awk 'BEGIN {print "line one\nline two\nline three"}'
# awk -F: '{ print $1, $3 }' /etc/passwd
二、awk變量
1、awk內置變量 - 記錄變量：
FS：field separator，讀取文本時，所使用字段分隔符；
RS：Record separator，輸入文本信息所使用的換行符；
OFS：Output Filed Separator，輸出字段分隔符；
ORS：Output Row Separator，輸出行分隔符；
awk -F:
OFS="#"
FS=":"
Example：
# awk 'BEGIN{OFS=":"} {print $1,$2}' file
2、awk內置變量 - 數據變量：
NR：The number of input records，awk命令所處理的行數；如果有多個文件，這個數目會把處理的多個文件中行統一計數；
NF：Number of Field，統計當前行的字段個數；
FNR：與NR不同的是，FNR用於統計每個文件被處理的行數；
ARGV：數組，保存命令行本身這個字符串，如awk '{print $0}' a.txt b.txt這個命令中，ARGV[0]保存awk，ARGV[1]保存a.txt；
ARGC：awk命令的參數個數；
FILENAME：awk命令所處理的文件名稱；
ENVIRON：當前shell環境變量及其值的關聯數組；
Example：
# awk 'BEGIN{print ENVIRON["PATH"]}'
3、用戶自定義變量
gawk允許用戶自定義變量以便在程序代碼中使用，變量名命名規則與大多數編程語言相同，只能使用字母、數字和下劃線，且不能以數字開頭。gawk變量名稱區分字符大小寫。
3.1、在腳本中賦值變量
在gawk中給變量賦值使用賦值語句進行，例如：
# awk 'BEGIN{var="variable testing";print var}'
3.2、在命令行中使用賦值變量
gawk命令也可以在"腳本"外爲變量賦值，並在腳本中進行引用。例如，上述的例子還可以改寫爲：
# awk -v var="variable testing" 'BEGIN{print var}'
三、printf
printf命令的使用格式：
printf format, item1, item2, ...
要點：
1、其與print命令的最大不同是，printf需要指定format；
2、format用於指定後面的每個item的輸出格式；
3、printf語句不會自動打印換行符；\n
format格式的指示符都以%開頭，後跟一個字符；如下：
%c：顯示字符的ASCII碼；
%d, %i：十進制整數；
%e, %E：科學計數法顯示數值；
%f：顯示浮點數；
%g, %G：以科學計數法的格式或浮點數的格式顯示數值；
%s：顯示字符串；
%u：無符號整數；
%%：顯示%自身；
修飾符：
N：顯示寬度；
-：左對齊；
+：顯示數值符號；
Example：
# awk -F: '{printf "%-15s %i\n",$1,$3}' /etc/passwd
四、輸出重定向
print items > output-file
print items >> output-file
print items | command
特殊文件描述符：
/dev/stdin：標準輸入
/dev/sdtout：標準輸出
/dev/stderr：錯誤輸出
/dev/fd/N：某特定文件描述符，如/dev/stdin就相當於/dev/fd/0；
Example：
# awk -F: '{printf "%-15s %i\n",$1,$3 > "/dev/stderr" }' /etc/passwd
五、awk的操作符
1、算術操作符：
-x：負值
+x：轉換爲數值
x^y：x的y次冪
x**y：x的y次方(與x^y一樣)
x*y：乘法
x/y：除法
x+y：加法
x-y：減法
x%y：取餘
2、字符串操作符：
xy：'x''y'變成'xy'，只有一個，而且不用寫出來，用於實現字符串連接；
Example：awk 'BEGIN{a="a";b="b";c=(a b);print c}'
3、賦值操作符：
x=y：將y的值賦給x；
x+=y：將x+y的值賦給x；
x-=y：將x-y的值賦給x；
x*=y：將x*y的值賦給x；
x/=y：將x/y的值賦給x；
x%=y：將x%y的值賦給x；
x^=y：將x^y的值賦給x；
x**=y：將x**y的值賦給x；
x++：使用後x+1，相當於x = x + 1；
x--：使用後x-1，相當於x = x - 1；
++x：x+1後使用x，相當於x + 1 = x；
--x：x-1後使用x，相當於x - 1 =x；
# 需要注意的是，如果某模式爲=號，此時使用/=/可能會有語法錯誤，應以/[=]/替代；
4、布爾值：
awk中，任何非0值或非空字符串都爲真，反之就爲假；
5、比較操作符：
x < y：x小於y；
x <= y：x小於等於y；
x > y：x大於y；
x >= y：x大於等於y；
x == y：x等於y；
x != y：x不等於y；
x ~ /y/：x匹配y；
x !~ /y/：x不匹配y；
6、表達式間的邏輯關係符：
&&：與
||：或
7、條件表達式：
selector?if-true-exp:if-false-exp
Example：
awk -F: '{printf ("%s is %s user\n",$1,($3>=500?"normal":"system"))}' /etc/passwd
相當於：
if selector; then
if-true-exp
else
if-false-exp
fi
8、函數調用：
function_name (para1,para2)
六、awk的模式
awk 'program' input-file1 input-file2 ...
其中的program爲：
pattern { action }
pattern { action }
...
1、常見的模式類型：
1.1、Regexp：正則表達式，格式爲/regular expression/
1.2、expresssion：表達式，其值非0或爲非空字符時滿足條件，如：$1 ~ /foo/ 或 $1 == "root"，用運算符~(匹配)和!~(不匹配)；
1.3、Ranges： 指定的匹配範圍，格式爲pat1,pat2；
1.4、BEGIN/END：特殊模式，僅在awk命令執行前運行一次或結束前運行一次；
1.5、Empty(空模式)：匹配任意輸入行；
示例：
正則表達式：
# awk -F: '/^r/{print $1}' /etc/passwd
# awk -F: '$3>=500{print $1,$3}' /etc/passwd
表達式：
# awk -F: '$7~"bash$"{print $1,$7}' /etc/passwd
# awk -F: '$7!~"bash$"{print $1,$7}' /etc/passwd
# awk -F: '$7=="/bin/bash"{print $1,$7}' /etc/passwd
匹配範圍：
# awk -F: '$3==0,$7~"nologin"{print $1,$3,$7}' /etc/passwd
特殊模式：
# awk -F: 'BEGIN{print "USERNAME ID Shell"}$3==0,$7~"nologin"{printf "%-10s%-10s%-10s\n",$1,$3,$7}' /etc/passwd
# awk -F: 'BEGIN{print "USERNAME ID Shell"}{printf "%-20s%-10s%-10s\n",$1,$3,$7}' /etc/passwd
# awk -F: 'BEGIN{print "USERNAME ID Shell"}{printf "%-20s%-10s%-10s\n",$1,$3,$7}END{print "END OF REPORT."}' /etc/passwd
空模式：
# awk -F: '{printf "%-20s%-10s%-10s\n",$1,$3,$7}' /etc/passwd
2、常見的Action
2.1、Expressions：表達式
2.2、Control statements：控制語句
2.3、Compound statements：複合語句
2.4、Input statements：輸入語句
2.5、Output statements：輸出語句
/正則表達式/：使用通配符的擴展集。
關係表達式：可以用下面運算符表中的關係運算符進行操作，可以是字符串或數字的比較，如$2>%1選擇第二個字段比第一個字段長的行。
模式匹配表達式：
模式，模式：指定一個行的範圍。該語法不能包括BEGIN和END模式。
BEGIN：讓用戶指定在第一條輸入記錄被處理之前所發生的動作，通常可在這裏設置全局變量。
END：讓用戶在最後一條輸入記錄被讀取之後發生的動作。
七、控制語句
1、if-else
語法：if (condition) {then-body} else {[ else-body ]}
Example：
# awk -F: '{if ($1=="root") print $1, "Admin"; else print $1, "Common User"}' /etc/passwd
# awk -F: '{if ($1=="root") printf "%-15s: %s\n", $1,"Admin"; else printf "%-15s: %s\n", $1, "Common User"}' /etc/passwd
# awk -F: -v sum=0 '{if ($3>=500) sum++}END{print sum}' /etc/passwd
2、while(循環字段，做字段處理)
語法： while (condition) {statement1; statment2; ...}
# awk -F: '{i=1;while (i<=3) {print $i;i++}}' /etc/passwd
# awk -F: '{i=1;while (i<=NF) {if (length($i)>=4) print $i;i++}}' /etc/passwd
3、do-while
語法： do {statement1, statement2, ...} while (condition)
# awk -F: '{i=1;do {print $i;i++}while(i<=3)}' /etc/passwd
4、for
語法： for ( variable assignment; condition; iteration process) { statement1, statement2, ...}
# awk -F: '{for(i=1;i<=3;i++) print $i}' /etc/passwd
# awk -F: '{for(i=1;i<=NF;i++) { if (length($i)>=4) {print $i}}}' /etc/passwd
for循環還可以用來遍歷數組元素：
語法： for (i in array) {statement1, statement2, ...}
# awk -F: '$NF!~/^$/{BASH[$NF]++}END{for(A in BASH){printf "%-15s:%i\n",A,BASH[A]}}' /etc/passwd
5、case
語法：switch (expression) { case VALUE or /REGEXP/: statement1, statement2,... default: statement1, ...}
6、break 和 continue
常用於循環或case語句中。
7、next
提前結束對本行文本的處理，並接着處理下一行；例如，下面的命令將顯示其ID號爲奇數的用戶：
# awk -F: '{if($3%2==0) next;print $1,$3}' /etc/passwd
八、awk中使用數組
1、數組
array[index-expression]
index-expression可以使用任意字符串；需要注意的是，如果某數據組元素事先不存在，那麼在引用其時，awk會自動創建此元素並初始化爲空串；因此，要判斷某數據組中是否存在某元素，需要使用index in array的方式。
要遍歷數組中的每一個元素，需要使用如下的特殊結構：
for (var in array) { statement1, ... }
其中，var用於引用數組下標，而不是元素值；
Example：統計每個shell出現的次數；
# awk -F: '{shell[$NF]++}END{for(i in shell) {print i,shell[i]}}' /etc/passwd
# netstat -ant | awk '/^tcp/ {++S[$NF]} END {for(a in S) print a, S[a]}'
# netstat -atn | awk '/^tcp/ {S[$NF]++} END {for (i in S) {print i,S[i]}}'
每出現一被/^tcp/模式匹配到的行，數組S[$NF]就加1，NF爲當前匹配到的行的最後一個字段，此處用其值做爲數組S的元素索引；
# awk '{counts[$1]++} END {for(ip in counts) print counts[ip], ip}' /var/log/httpd/access_log
用法與上一個例子相同，用於統計某日誌文件中IP地的訪問量；
2、刪除數組變量
從關係數組中刪除數組索引需要使用delete命令。使用格式爲：
delete array[index]
九、awk的內置函數
split(string, array [, fieldsep [, seps ] ])
功能：將string表示的字符串以fieldsep爲分隔符進行分隔，並將分隔後的結果保存至array爲名的數組中；數組下標爲從0開始的序列；
# netstat -ant | awk '/:80\>/{split($5,clients,":");IP[clients[1]]++}END{for(i in IP){print IP[i],i}}' | sort -rn | head -50
length([string])
功能：返回string字符串中字符的個數；
substr(string, start [, length])
功能：取string字符串中的子串，從start開始，取length個；start從1開始計數；
system(command)
功能：執行系統command並將結果返回至awk命令；
systime()
功能：取系統當前時間；
tolower(s)
功能：將s中的所有字母轉爲小寫；
toupper(s)
功能：將s中的所有字母轉爲大寫；
十、用戶自定義函數
自定義函數使用function關鍵字。格式如下：
function F_NAME([variable])
{
statements
}
函數還可以使用return語句返回值，格式爲“return value”。