使用puppet模塊管理mysql

 參考資料：Pro puppet

          http://docs.puppetlabs.com/

續http://urchin.blog.51cto.com/4356076/986571

使用puppet模塊管理mysql

模塊的目錄結構

modules/mysql/
├── files
│   └── my.cnf
├── manifests
│   ├── config.pp
│   ├── init.pp
│   ├── install.pp
│   └── service.pp
└── templates

mysql::install類

# vi ../modules/mysql/manifests/install.pp
class mysql::install {
     package { ["mysql", "mysql-server", "mysql-test", "mysql-devel" ]:
        ensure => present,
        require => User["mysql"],
     }
     user { "mysql":            ##資源類型：用戶
        ensure => present,
        comment => "mysql user",##/etc/passwd文件第五段信息
        gid => "mysql",         ##用戶的組
        shell => "/bin/false",  ##用戶的shell
        require => Group["mysql"],##mysql用戶依賴於mysql組
     }
     group { "mysql":   ##資源類型：組
        ensure => present,
     }
}

mysql::conifg類

# vi ../modules/mysql/manifests/config.pp
class mysql::config {
     file { "/etc/my.cnf":
        ensure => present,
        source => "puppet:///modules/mysql/my.cnf",
        owner => 'mysql',
        group => 'mysql',
        require => Class["mysql::install"],
        notify => Class["mysql::service"],
     }
}

mysql::service類

# vi ../modules/mysql/manifests/service.pp
class mysql::service {
     service { "mysqld":
        ensure => running,
        hasstatus => true,
        hasrestart => true,
        enable  => true,
        require => Class["mysql::config"],
     }
}

modules/mysql/manifest/init.pp

# vi ../modules/mysql/manifests/init.pp
class mysql {
     include mysql::install, mysql::config, mysql::service
}

../puppet/manifest/nodes.pp

node 'agent.test.com' {
        include ssh
        include mysql
}

注：各元參數含義請移至http://urchin.blog.51cto.com/4356076/986571