切換JDK版本

因爲工作需要或者是其他開發需求,部分開發者可能需要切換jdk版本,傳統的方式需要手動修改環境變量，重新啓動等繁瑣的步驟,

前段時間在網上見一位大神使用下面這種編寫.bat文件的方式,很是牛X,自己也根據自己的實際情況親測了一下,確實很屌,分享給大家!

@echo off
rem 切換Java jdk版本
echo 請以管理員來進行切換
java -version
:menu
echo =============================================
echo 請選擇要切換的jdk版本
echo 1:Java jdk 1.6
echo 2:Java jdk 1.7
echo 3:Java jdk 1.8
echo 4: 取消
echo =============================================
set /p ch=請選擇：
if "%ch%"=="1" goto java1.6
if "%ch%"=="2" goto java1.7
if "%ch%"=="3" goto java1.8
if "%ch%"=="4" goto exit
goto menu
:java1.6
set JAVA_HOME=C:\Program Files (x86)\Java\jdk1.6.0_24
set JRE_HOME=C:\Program Files (x86)\Java\jdk1.6.0_24\jre
set JAVA_VERSION=1.6
goto exec
:java1.7
set JAVA_HOME=C:\Program Files\Java\jdk1.7.0_79
set JRE_HOME=C:\Program Files\Java\jdk1.7.0_79\jre
set JAVA_VERSION=1.7
goto exec
:java1.8
set JAVA_HOME=C:\Program Files\Java\jdk1.8.0_74
set JRE_HOME=C:\Program Files\Java\jdk1.8.0_74\jre
set JAVA_VERSION=1.8
goto exec
:exec
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Development Kit" /v CurrentVersion /t REG_SZ /f /d "%JAVA_VERSION%"
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Runtime Environment" /v CurrentVersion /t REG_SZ /f /d "%JAVA_VERSION%"
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v JAVA_HOME /t REG_SZ /f /d "%JAVA_HOME%"
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v JRE_HOME /t REG_SZ /f /d "%JRE_HOME%"
del /f "C:\Windows\System32\java.exe"
copy /Y "%JAVA_HOME%\bin\java.exe" "C:\Windows\System32\java.exe"
del /f "C:\Windows\System32\javaw.exe"
copy /Y "%JAVA_HOME%\bin\javaw.exe" "C:\Windows\System32\javaw.exe"
del /f "C:\Windows\System32\javaws.exe"
copy /Y "%JAVA_HOME%\bin\javaws.exe" "C:\Windows\System32\javaws.exe"
set JAVA_PATH=C:\ProgramData\Oracle\Java\javapath
del /f "%JAVA_PATH%\java.exe"
mklink "%JAVA_PATH%\java.exe" "%JAVA_HOME%\bin\java.exe"
del /f "%JAVA_PATH%\javaw.exe"
mklink "%JAVA_PATH%\javaw.exe" "%JAVA_HOME%\bin\javaw.exe"
del /f "%JAVA_PATH%\javaws.exe"
mklink "%JAVA_PATH%\javaws.exe" "%JAVA_HOME%\bin\javaws.exe"
echo 已切換到JDK %JAVA_VERSION%
goto exit
:exit

以上,大家可以根據自身情況對相關路徑進行修改配置,

將文件保存爲switchjdk.bat文件放入system32中,

然後以管理員身份運行身份運行命令行執行該bat文件即可!

可以通過java -version 來驗證是否切換成功,

有問題的話重新安裝一下jdk基本就ok了.

(ps:千萬要注意,命令窗要以管理員身份運行)
有更好的方法也希望大神指導.