awk
報告生成器,格式化文本輸出
常用選項
awk -F :“分隔符” 指明輸入時用到的字段分隔符
-v : 變量賦值
基本用法
基本格式:awk [options] 'program' file…
Program:pattern{action statements;..}pattern和action
pattern部分決定動作語句何時觸發及觸發事件
BEGIN,END
action statements對數據進行處理,放在{}內指明
print, printf分割符、域和記錄
awk執行時,由分隔符分隔的字段(域)標記$1,$2...$n稱爲域標識。$0 爲所有域,注意:此時和shell中變量$符含義不同
文件的每一行稱爲記錄
省略action,則默認執行 print $0 的操作
示例:
取出第三列的域名
取分區利用率
取分區利用率並去掉%
一步直接取出df分區利用率
取/etc/passwd文件第一列和第三列
運算
awk變量
變量:內置和自定義變量
FS
輸入字段分隔符,默認爲空白字符
awk -v FS=':' '{print $1,FS,$3}' /etc/passwd
awk –F: '{print $1,$3,$7}' /etc/passwd
示例:
RS
輸入記錄分隔符,指定輸入時的換行符
awk -v RS=' ' ‘{print }’ /etc/passwd
ORS
輸出記錄分隔符,輸出時用指定符號代替換行符
awk -v RS=' ' -v ORS='###' '{print $0}' /etc/passwd
示例
以冒號爲分隔符,取第一個字符,默認換行
以等號爲分隔符,不換行
NF
字段數量
awk -F:'{print NF}' /etc/fstab 引用變量時,變量前不需加$
awk -F:'{print $(NF-1)}' /etc/passwd
示例:
倒數第一個
-1倒數第二個
取出倒數第二個
進行排序
NR
記錄號
awk '{print NR}' /etc/fstab ;
awk END '{print NR}' /etc/fstab
示例
$0打印所有字符,並添加編號
以冒號爲分隔符,打印出文件內容,加上編號
FNR
各文件分別計數,記錄號
awk '{print FNR}' /etc/fstab /etc/inittab
FILENAME:當前文件名
awk '{print FILENAME}' /etc/fstab
ARGC
命令行參數的個數
awk '{print ARGC}' /etc/fstab /etc/inittab
awk 'BEGIN {print ARGC}' /etc/fstab /etc/inittab
ARGV
數組,保存的是命令行所給定的各參數
awk 'BEGIN {print ARGV[0]}' /etc/fstab /etc/inittab
awk 'BEGIN {print ARGV[1]}' /etc/fstab /etc/inittab
練習
自定義變量並運算
賦值並取出USER的值
賦值取出USER和UID的值
先變量後使用,不然會出現以下情況
printf命令
格式化輸出:printf “FORMAT”, item1, item2, ...
(1) 必須指定FORMAT
(2) 不會自動換行,需要顯式給出換行控制符,\n
(3) FORMAT中需要分別爲後面每個item指定格式符
格式符:與item一一對應
%c:顯示字符的ASCII碼
%d, %i:顯示十進制整數
%e, %E:顯示科學計數法數值
%f:顯示爲浮點數
%g, %G:以科學計數法或浮點形式顯示數值
%s:顯示字符串
%u:無符號整數
%%:顯示%自身
修飾符
#[.#] 第一個數字控制顯示的寬度;第二個#表示小數點後精度,%3.1f
- 左對齊(默認右對齊) %-15s
- 顯示數值的正負符號 %+d
示例
格式化輸出
加n換行
取出分區利用率並且15個佔位符後用冒號隔開
可以構建表格
操作符
算術操作符
x+y, x-y, x*y, x/y, x^y, x%y
-x:轉換爲負數
+x:將字符串轉換爲數值
字符串操作符
沒有符號的操作符,字符串連接
賦值操作符:
=, +=, -=, *=, /=, %=, ^=,++, --
下面兩語句有何不同
awk 'BEGIN{i=0;print ++i,i}'
awk 'BEGIN{i=0;print i++,i}'
比較操作符:
==, !=, >, >=, <, <=
模式匹配符:
~:左邊是否和右邊匹配,包含
!~:是否不匹配
示例:
awk -F: '$0 ~ /root/{print $1}' /etc/passwd
awk '$0~“^root"' /etc/passwd
awk '$0 !~ /root/' /etc/passwd
awk -F: '$3==0' /etc/passwd
示例:
實現條件過濾
打印20行之後的內容
打印出非#開頭的行
取出IP地址
CentoS6的命令
邏輯操作符
與&&,或||,非!
示例:
awk -F: '$3>=0 && $3<=1000 {print $1}' /etc/passwd
awk -F: '$3==0 || $3>=1000 {print $1}' /etc/passwd
awk -F: '!($3==0) {print $1}' /etc/passwd
awk -F: '!($3>=500) {print $3}' /etc/passwd
示例
取出分區利用率在5到15之間的分區
後面每條命令都會處理一次
取出分區利用率大於5小於10的分區
取出分區利用率小於5的分區
條件表達式(三目表達式)
selector?if-true-expression:if-false-expression
示例:
awk -F: '{$3>=1000?usertype="Common User":usertype="SysUser";
printf "%15s:%-s\n",$1,usertype}' /etc/passwd
示例:
判斷分區利用率,大於等於5的顯示disk full,否則顯示NOT FULL
過濾掉第一行
awk PATTERN
PATTERN:根據pattern條件,過濾匹配的行,再做處理
- (1)如果未指定:空模式,匹配每一行
- (2) /regular expression/:僅處理能夠模式匹配到的行,需要用/ /括起來
awk '/^UUID/{print $1}' /etc/fstab
awk '!/^UUID/{print $1}' /etc/fstab- (3) relational expression: 關係表達式,結果爲“真”纔會被處理
真:結果爲非0值,非空字符串
假:結果爲空字符串或0值
示例:
awk -F: 'i=1;j=1{print i,j}' /etc/passwd
awk '!0' /etc/passwd ; awk '!1' /etc/passwd
Awk -F: '$3>=1000{print $1,$3}' /etc/passwd
awk -F: '$3<1000{print $1,$3}' /etc/passwd
awk -F: '$NF=="/bin/bash"{print $1,$NF}' /etc/passwd
awk -F: '$NF ~ /bash$/{print $1,$NF}' /etc/passwd- (4) line ranges:行範圍
startline,endline:/pat1/,/pat2/ 不支持直接給出數字格式
awk -F: ‘/^root\>/,/^nobody\>/{print $1}' /etc/passwd
awk -F: ‘(NR>=10&&NR<=20){print NR,$1}' /etc/passwd- (5) BEGIN/END模式
BEGIN{}:僅在開始處理文件中的文本之前執行一次
END{}:僅在文本處理完成之後執行一次
示例:
取出以UUID開頭的行
取不是以UUID開頭的行
取出三個磁盤的利用信息
取出遠程連接IP
取出連接三次以上的IP
找出遠程連接三次以上的IP地址,視爲**放進防火牆
不是空不是0就是真,是空的或者0就是假
取出文件中b到f開頭的行
awk action
常用的action分類
- (1) Expressions:算術,比較表達式等
- (2) Control statements:if, while等
- (3) Compound statements:組合語句
- (4) input statements
- (5) output statements:print等
awk控制語句
{ statements;… } 組合語句
if(condition) {statements;…}
if(condition) {statements;…} else {statements;…}
while(conditon) {statments;…}
do {statements;…} while(condition)
for(expr1;expr2;expr3) {statements;…}
break
continue
delete array[index]
delete array
exit
awk控制語句if-else
語法:
if(condition){statement;…}[else statement]
if(condition1){statement1}else if(condition2){statement2}else{statement3}使用場景
對awk取得的整行或某個字段做條件判斷
示例:
awk -F: '{if($3>=1000)print $1,$3}' /etc/passwd
awk -F: '{if($NF=="/bin/bash") print $1}' /etc/passwd
awk '{if(NF>5) print $0}' /etc/fstab
awk -F: '{if($3>=1000) {printf "Common user: %s\n",$1} else {printf "root or Sysuser: %s\n",$1}}' /etc/passwd
awk -F: '{if($3>=1000) printf "Common user: %s\n",$1; else printf "root or Sysuser: %s\n",$1}' /etc/passwd
df -h|awk -F% '/^\/dev/{print $1}'|awk '$NF>=80{print $1,$5}'
awk 'BEGIN{ test=100;if(test>90){print "very good"}
else if(test>60){ print "good"}else{print "no pass"}}'
示例:
判斷分區利用率是否快慢,並且打印出利用率
用{}替換;
請提取”.magedu.com”前面的主機名部分
awk控制語句
while循環
語法:while(condition){statement;…}
條件“真”,進入循環;條件“假”,退出循環
使用場景:
對一行內的多個字段逐一類似處理時使用
對數組中的各元素逐一處理時使用示例:
- awk '/^[[:space:]]*linux16/{i=1;while(i<=NF)
- {print $i,length($i); i++}}' /etc/grub2.cfg
- awk '/^[[:space:]]*linux16/{i=1;while(i<=NF)
- {if(length($i)>=10){print $i,length($i)}; i++}}' /etc/grub2.cfg
for循環
語法
for(expr1;expr2;expr3) {statement;…}
常見用法
for(variable assignment;condition;iteration process) {for-body}
特殊用法
能夠遍歷數組中的元素 語法:for(var in array) {for-body}
示例
awk '/^[[:space:]]*linux16/{for(i=1;i<=NF;i++) {print $i,length($i)}}' /etc/grub2.cfg
示例:
用for循環運算1加到100
把文件每一段用空格隔開,合計每行每段有多少個字符
性能比較
分別用wak(for循環和while循環)和shell計算1加到100萬的運算,並且看出awk時間短效率高
awk數組
關聯數組:array[index-expression]
index-expression:
- (1) 可使用任意字符串;字符串要使用雙引號括起來
- (2) 如果某數組元素事先不存在,在引用時,awk會自動創建此元素,並將其值 初始化爲“空串”
- (3) 若要判斷數組中是否存在某元素,要使用“index in array”格式進行遍歷
示例:
weekdays["mon"]="Monday"
awk 'BEGIN{weekdays["mon"]="Monday";weekdays["tue"]="Tuesday";
print weekdays["mon"]}‘
awk '!line[$0]++' dupfile
awk '{!line[$0]++;print $0, line[$0]}' dupfile- 若要遍歷數組中的每個元素,要使用for循環
- for(var in array) {for-body}
- 注意:var會遍歷array的每個索引
示例:
awk 'BEGIN{weekdays["mon"]="Monday";weekdays["tue"]="Tuesday";
for(i in weekdays) {print weekdays[i]}}'
netstat -tan | awk '/^tcp/{state[$NF]++}
END{for(i in state) { print i,state[i]}}'
awk '{ip[$1]++}END{for(i in ip) {print i,ip[i]}}' /var/log/httpd/access_log
awk函數
數值處理:
rand():返回0和1之間一個隨機數
awk 'BEGIN{srand(); for (i=1;i<=10;i++)print int(rand()*100) }'字符串處理:
- length([s]):返回指定字符串的長度
- sub(r,s,[t]):對t字符串搜索r表示模式匹配的內容,並將第一個匹配內容替換爲s
echo "2008:08:08 08:08:08" | awk 'sub(/:/,"-",$1)'
echo "2008:08:08 08:08:08" | awk '{sub(/:/,"-",$1);print $0}'- gsub(r,s,[t]):對t字符串進行搜索r表示的模式匹配的內容,並全部替換爲s所表示的內容
echo "2008:08:08 08:08:08" | awk 'gsub(/:/,"-",$0)'
echo "2008:08:08 08:08:08" | awk '{gsub(/:/,"-",$0);print $0}'- split(s,array,[r]):以r爲分隔符,切割字符串s,並將切割後的結果保存至array所 表示的數組中,第一個索引值爲1,第二個索引值爲2,…
netstat -tn | awk '/^tcp\>/{split($5,ip,":");count[ip[1]]++}
END{for (i in count) {print i,count[i]}}'
示例:
打印出TCP連接IP並統計連接次數
自定義函數格式
function name ( parameter, parameter, ... ) {
statements
return expression
}
示例:
cat fun.awk
function max(x,y) {
x>y?var=x:var=y
return var
}
BEGIN{a=3;b=2;print max(a,b)}
awk -f fun.awk
awk中調用shell命令
- system命令
- 空格是awk中的字符串連接符,如果system中需要使用awk中的變量可以使用 空格分隔,或者說除了awk的變量外其他一律用""引用起來
awk 'BEGIN{system("hostname") }'
awk 'BEGIN{score=100; system("echo your score is " score) }'
awk腳本
- 將awk程序寫成腳本,直接調用或執行
- 示例:
cat f1.awk
{if($3>=1000)print $1,$3}
awk -F: -f f1.awk /etc/passwd
.
cat f2.awk
#!/bin/awk –f
#this is a awk script
{if($3>=1000)print $1,$3}
chmod +x f2.awk
f2.awk -F: /etc/passwd
向awk腳本傳遞參數
格式:
awkfile var=value var2=value2... Inputfile
注意:
在BEGIN過程中不可用。直到首行輸入完成以後,變量纔可用。可以通 過-v 參數,讓awk在執行BEGIN之前得到變量的值。命令行中每一個指定的變 量都需要一個-v參數
示例:
cat test.awk
#!/bin/awk –f
{if($3 >=min && $3<=max)print $1,$3}
chmod +x test.awk
test.awk -F: min=100 max=200 /etc/passwd