MySQL 啓動助手v1.02.bat 批處理
測試：MySQL 5.5.28 絕對可以用。
今天寫了一個方便MySQL 在Windows下啓動和備份，等待小白來測試，有問題請留言告訴我，謝謝使用。
功能：1.啓動服務 3.查詢分析器 5.導出數據庫 7.設置手動
2.關閉服務 4.導入數據 6.導出數據表 8.設置自動
9.設置禁止 10.退出
1.02版本更新說明
1.增加設置手動，設置自動，設置禁用，MySQL服務
2.更新了菜單選項
使用說明：
1.請將下面的文件保存成 MySQL 啓動助手v1.01.bat
2.直接在Windows下雙擊運行。
@echo off
title MySQL啓動助手 v1.02
:: MySQL 用戶名
set USERNAME=root
:: MySQL 密碼
set PASSWORD=123456
::批處理解決十點前獲取小時補零
if %time:~0,2% lss 10 (set hour=0%time:~1,1%) else (set hour=%time:~0,2%)
::設置保存路徑
set BACKUP_NAME=%date:~0,4%%date:~5,2%%date:~8,2%^_%hour%%time:~3,2%%time:~6,2%
:menu
cls
echo. ------------------------------------------------------------
echo. + 歡迎使用MySQL啓動助手 +
echo. + 指令菜單： +
echo. + 1.啓動服務 3.查詢分析器 5.導出數據庫 7.設置手動 +
echo. + 2.關閉服務 4.導入數據 6.導出數據表 8.設置自動 +
echo. + 9.設置禁用 10.退出 +
echo. + +
echo. + 溫馨提醒： +
echo. + 1.請啓動服務器後，再進行備份 +
echo. + 2.導出數據存放在當前目錄 +
echo. + 導出的文件名(數據庫名_數據表_日期_時間.sql +
echo. + 3.導入數據庫時，如果數據庫不存在，請先創建再導入 +
echo. + 作者：風雲無痕 QQ：925776958 版本 1.02 時間：2013-02-05 +
echo. ------------------------------------------------------------
echo.
echo. 日期：%date% 時間：%time%
echo.
set choose=""
set /p choose= 請輸入指令[1/./n/./10]:
if /i "%choose%"=="1" (goto:start)
if /i "%choose%"=="2" (goto:stop)
if /i "%choose%"=="3" (goto:login)
if /i "%choose%"=="4" (goto:import)
if /i "%choose%"=="5" (goto:database_backup)
if /i "%choose%"=="6" (goto:table_backup)
if /i "%choose%"=="7" (goto:demand)
if /i "%choose%"=="8" (goto:auto)
if /i "%choose%"=="9" (goto:disabled)
if /i "%choose%"=="10" (goto:exit)
:: 1 → start
:start
echo.
net start mysql
echo 服務啓動完畢!
pause
goto:menu
:: 2 → stop
:stop
echo.
net stop mysql
echo 服務已關閉!
pause
goto:menu
:: 3 → login
:login
echo. 輸入密碼：
mysql -uroot -p
goto:menu
:: 4 → import
:import
set /p DATABASES= 需要導入的數據庫名字:
set /p file_name= 需要導入的文件路徑:
echo. 開始導入數據庫...
for %%D in (%file_name%) do (
echo. 正在導入 %%D 數據庫...
mysql -u%USERNAME% -p%PASSWORD% %DATABASES% < %%D
)
echo. 完成數據庫導入！
pause
goto menu
:: 5 → database_backup
: database_backup
set /p DATABASES= 需要導出的數據庫名字(多個用空格分隔):
echo. 開始導出數據庫...
for %%D in (%DATABASES%) do (
echo. 正在導出 %%D 數據庫...
mysqldump -u%USERNAME% -p%PASSWORD% %%D > %%D_%BACKUP_NAME%.sql 2>nul
)
echo. 完成數據庫導出！
pause
goto menu
:: 6 → table_backup
: table_backup
set /p DATABASES= 需要導出的數據庫名字(只能輸入一個):
set /p TABLES= 需要導出的表名字(多個用空格分隔):
echo. 開始導出數據庫...
for %%D in (%TABLES%) do (
echo. 正在導出 %DATABASES% 數據庫的 %%D 數據表...
mysqldump -u%USERNAME% -p%PASSWORD% %DATABASES% %%D > %DATABASES%_%%D_%BACKUP_NAME%.sql 2>nul
)
echo. 完成數據庫導出！
pause
goto menu
:: 7 → demand
: demand
sc config MySQL start= demand
pause
goto menu
:: 8 → auto
: auto
sc config MySQL start= auto
pause
goto menu
:: 9 → disabled
: disabled
sc config MySQL start= disabled
pause
goto menu
:: 10 → exit
:exit
cls
echo. 謝謝使用MySQL啓動助手...
ping -n 2 127.0.0.1>nul
exit
