在Oracle10g裏面，已經不贊成使用DBMS_JOB，推薦使用DBMS_SCHEDULER，它的健壯爲調度提供更好的規劃和結構。下面我只簡單寫一個例子。
begin
DBMS_SCHEDULER.CREATE_PROGRAM(
program_name => 'guozhw',
program_type => 'STORED_PROCEDURE',
program_action => 'guozhwTest',
number_of_arguments => 0,
enabled => true,
comments => '定時調度測試'
);
end;
program_name:program的名字
program_type:program的類型。STORED_PROCEDURE存儲過程
program_action:要執行的程序。guozhwTest 存儲過程的名字
舉例如下：
BEGIN
DBMS_SCHEDULER.CREATE_PROGRAM (
program_name => 'PRM_CREATEDUNDATA',
program_action => 'PKG_SCHEDULER.CREATEDUNDATA',
program_type => 'STORED_PROCEDURE',
enabled => FALSE,
number_of_arguments => 5,
comments => '生成催繳數據'
);
DBMS_SCHEDULER.DEFINE_PROGRAM_ARGUMENT(PROGRAM_NAME => 'PRM_CREATEDUNDATA',
ARGUMENT_POSITION => 1,
ARGUMENT_NAME => 'I_BILLINGCYCLEID',
ARGUMENT_TYPE => 'VARCHAR2',
DEFAULT_VALUE => NULL,
OUT_ARGUMENT => FALSE);
DBMS_SCHEDULER.DEFINE_PROGRAM_ARGUMENT(PROGRAM_NAME => 'PRM_CREATEDUNDATA',
ARGUMENT_POSITION => 2,
ARGUMENT_NAME => 'I_BUSINESSTYPE',
ARGUMENT_TYPE => 'VARCHAR2',
DEFAULT_VALUE => NULL,
OUT_ARGUMENT => FALSE);
DBMS_SCHEDULER.DEFINE_PROGRAM_ARGUMENT(PROGRAM_NAME => 'PRM_CREATEDUNDATA',
ARGUMENT_POSITION => 3,
ARGUMENT_NAME => 'I_STATE',
ARGUMENT_TYPE => 'VARCHAR2',
DEFAULT_VALUE => NULL,
OUT_ARGUMENT => FALSE);
DBMS_SCHEDULER.DEFINE_PROGRAM_ARGUMENT(PROGRAM_NAME => 'PRM_CREATEDUNDATA',
ARGUMENT_POSITION => 4,
ARGUMENT_NAME => 'I_BANKCODE',
ARGUMENT_TYPE => 'VARCHAR2',
DEFAULT_VALUE => NULL,
OUT_ARGUMENT => FALSE);
DBMS_SCHEDULER.DEFINE_PROGRAM_ARGUMENT(PROGRAM_NAME => 'PRM_CREATEDUNDATA',
ARGUMENT_POSITION => 5,
ARGUMENT_NAME => 'I_OPERATORCODE',
ARGUMENT_TYPE => 'VARCHAR2',
DEFAULT_VALUE => NULL,
OUT_ARGUMENT => FALSE);
DBMS_SCHEDULER.ENABLE(NAME => 'PRM_CREATEDUNDATA');
COMMIT;
END;
之後就可以在select * from sys.USER_SCHEDULER_PROGRAMS t中看到program了
×××××××××××××××××××××××××××××××××××××××××***********************************************************
最近遇到一個CASE，要做定時任務，想來想去，還是先看看Oracle提供了啥..
Oracle10g引入了一種新的作業調度程序：dbms_scheduler，通過如下命令可以查看它包含一些什麼功能，
SQL> desc sys.dbms_scheduler;
...
不過，最好還是用PL/SQL dev或者TOAD來展開包頭，這樣所有功能和註釋都一幕瞭然了。
在Oracle9i，我們都是job來運行定時任務，例如定時備份一些數據，定時清理一下歸檔。在Oracle10g裏面，已經不
贊成試用DBMS_JOB，而是推薦使用DBMS_SCHEDULER，它更加的複雜和健壯，爲調度提供更好的規劃和結構。
dbms_scheduler把創建一個作業分成了不同的部分：dbms_scheduler，program和job，下面我們依次來創建一個例子。
首先創建一個測試表:
SQL> desc user118800;
Name Type Nullable Default Comments
------------- ------------ -------- ------- --------
SN NUMBER 序列
AREACODE VARCHAR2(4) 區號
DEVICESNUMBER VARCHAR2(12) 電話號碼
READ INTEGER 0 是否讀取
BIT INTEGER 業務位
DDATE DATE Y
有如下存儲過程：
create or replace procedure pro_test is
begin
UPDATE user118800 SET READ=1,ddate=SYSDATE WHERE READ=0 AND ROWNUM <2;
COMMIT;
--sys.dbms_lock.sleep(120);
end pro_test;
這個測試，就是用過程來更新user118800表裏面的一行數據，並記錄下更新時間，接着我們就創建作業來定時執行。
創建一個scheduler：
/*************************************************************
* Schedule Administration Procedures
*************************************************************
*/
-- Schedule attributes which can be used with set_attribute/get_attribute are :
--
-- repeat_interval - VARCHAR2
-- an expression using the calendar syntax
-- comments - VARCHAR2
-- an optional comment.
-- end_date - TIMESTAMP WITH TIME ZONE
-- cutoff date after which the schedule will not specify
-- any dates
-- start_date - TIMESTAMP WITH TIME ZONE
-- start or reference date used by the calendar syntax
--
-- Schedules cannot be enabled and disabled.
-- Create a named schedule. This must be a valid schedule.
PROCEDURE create_schedule(
schedule_name IN VARCHAR2,
start_date IN TIMESTAMP WITH TIME ZONE DEFAULT NULL,
repeat_interval IN VARCHAR2,
end_date IN TIMESTAMP WITH TIME ZONE DEFAULT NULL,
comments IN VARCHAR2 DEFAULT NULL);
這是創建scheduler的存儲過程，運行如下：
begin
-- Call the procedure
sys.dbms_scheduler.create_schedule(schedule_name => 'your schedule_name',
start_date => '27-8月 -07 12.00.00.000 上午',
repeat_interval => 'FREQ=MINUTELY; INTERVAL=1',
end_date => '28-8月 -07 12.00.00.000 上午',
comments => 'TEST SCHEDULER');
end;
這裏需要注意的是，參數start_date和end_date都是TIMESTAMP 類型，在輸入的時候要遵循它們的格式，
往往doc裏面的格式都是英文環境下的，這個時候你要通過查詢字典nls_database_parameters或者
select to_timestamp(sysdate) from dual; 來獲得格式。
repeat_interval是調度運行的時間間隔，本例是每分鐘運行一次
repeat_interval => 'FREQ=HOURLY; INTERVAL=1'
每小時運行一次
repeat_interval => 'FREQ=DAILY INTERVAL=1'
每天運行一次
更詳細的說明，要查詢doc。另外它還有一個過程dbms_scheduler.evaluate_calendar_string是估算下一次運行的時間的。
第二步，創建一個program
/*************************************************************
* Program Administration Procedures
*************************************************************
*/
-- Program attributes which can be used with set_attribute/get_attribute are:
--
-- program_action - VARCHAR2
-- This is a string specifying the action. In case of:
-- 'PLSQL_BLOCK': PLSQL code
-- 'STORED_PROCEDURE: name of the database object
-- representing the type (optionally with schema).
-- 'EXECUTABLE': Full pathname including the name of the
-- executable, or shell script.
-- program_type - VARCHAR2
-- type of program. This must be one of the supported
-- program types. Currently these are
-- 'PLSQL_BLOCK', 'STORED_PROCEDURE', 'EXECUTABLE'
-- comments - VARCHAR2
-- an optional comment. This can describe what the
-- program does, or give usage details.
-- number_of_arguments- PLS_INTEGER
-- the number of arguments of the program that can be set
-- by any job using it, these arguments MUST be defined
-- before the program can be enabled
-- enabled - BOOLEAN
-- whether the program is enabled or not. When the program
-- is enabled, checks are made to ensure that the program
-- is valid.
-- Create a new program. The program name can be optionally qualified with a
-- schema. If enabled is set to TRUE, validity checks will be performed and
-- the program will be created in an enabled state if all are passed.
PROCEDURE create_program(
program_name IN VARCHAR2,
program_type IN VARCHAR2,
program_action IN VARCHAR2,
number_of_arguments IN PLS_INTEGER DEFAULT 0,
enabled IN BOOLEAN DEFAULT FALSE,
comments IN VARCHAR2 DEFAULT NULL);
運行如下：
begin
-- Call the procedure
sys.dbms_scheduler.create_program(program_name => 'your program_name',
program_type => 'PLSQL_BLOCK',
program_action => 'BEGIN PRO_TEST; END;',
number_of_arguments => 0,
enabled => TRUE,
comments => 'comments');
end;
這裏需要注意的是program_type,如果你要運行PLSQL塊，則選擇PLSQL_BLOCK，如果是sh腳本，則'EXECUTABLE'。
這裏我選擇PLSQL塊。
第三步創建一個job
-- create a job using a named schedule object and a named program object.
-- If enabled is set TRUE, it will be attempted to enable this job after
-- creating it.
-- Values must be set for each argument of the program that does not have a
-- default_value specified (before enabling the job).
PROCEDURE create_job(
job_name IN VARCHAR2,
program_name IN VARCHAR2,
schedule_name IN VARCHAR2,
job_class IN VARCHAR2 DEFAULT 'DEFAULT_JOB_CLASS',
enabled IN BOOLEAN DEFAULT FALSE,
auto_drop IN BOOLEAN DEFAULT TRUE,
comments IN VARCHAR2 DEFAULT NULL);
實際在10g提供的過程裏面，有6中create job的方法，而且也可以單獨創建作業，但這裏我們選擇其中一種。
begin
-- Call the procedure
sys.dbms_scheduler.create_job(job_name => 'my test job',
program_name => 'your program_name',
schedule_name => 'your schedule_name',
job_class => 'DEFAULT_JOB_CLASS',
enabled => true,
auto_drop => true,
comments => 'comments');
end;
這樣就完成了一個job的創建，下面就是運行它：
begin
-- Call the procedure
sys.dbms_scheduler.run_job(job_name => 'my test job',
use_current_session => 'false');
end;
use_current_session 這個參數要定義爲false，它才能在後臺運行。
創建以後的監控：
查看調度
SELECT * FROM User_Scheduler_Schedules;
查看作業
SELECT * FROM User_Scheduler_Jobs;
查看程序
SELECT * FROM User_Scheduler_Programs;
查看執行中的作業，也就是PRO_TEST在運行階段的作業。前面的過程中，我定義了一個sys.dbms_lock.sleep(120);
實際就是爲了查看這個視圖。
SELECT * FROM User_Scheduler_Running_Jobs;
查看job的日誌
SELECT * FROM User_Scheduler_Job_Log;
如果日誌中有FAILeD的狀態，那麼就要查看altersid.log了。
好了，一個基本的調度例子就完成了。如果想更詳細的瞭解它，請閱讀該包頭的註釋，和查閱相關DOC
Oracle® Database
PL/SQL Packages and Types Reference
10g Release 2 (10.2)
在9i的時候，job有一個煩人的問題，就是延時，一個job的執行耗時是10分鐘，inteval爲1天，第一次執行爲晚上12點，
在以後的執行過程中，該job爲逐漸按10分鐘遞增時間。10g的Scheduler解決了這個問題，但是我還是發現Scheduler同樣無法異步的執行，我的inteval是1分鐘，但在程序中如果打開
sleep(120)後，實際inteval就變成了120秒...它還是和job一樣，必須等待上一次任務的完成，這樣也沒有達到我的初衷。
最後，我也應用中是否最終會使用Scheduler，還有待測試。除了Scheduler，在中間層，如EJB和Spring....