轉自：https://www.douban.com/note/331036776/
ARM彙編有ldr指令以及ldr、adr僞指令，他門都可以將標號表達式作爲操作數，下面通過分析一段代碼以及對應的反彙編結果來說明它們的區別。
ldr r0, _start
adr r0, _start
ldr r0, =_start
_start:
b _start
編譯的時候設置 RO 爲 0x30000000(運行地址，runaddress)，下面是反彙編的結果：
0x00000000: e59f0004 ldr r0, [pc, #4] ; 0xc
0x00000004: e28f0000 add r0, pc, #0 ; 0x0
0x00000008: e59f0000 ldr r0, [pc, #0] ; 0x10
0x0000000c: eafffffe b 0xc
0x00000010: 3000000c andcc r0, r0, ip
－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
1.ldr r0, _start:
簡單的說就是把 _start地址存放的值讀出來。
彙編程序計算出當前位置執行到_start（這裏是一個標號，相對程序的位置表達式）位置pc所要增加的數值＃4，然後由當前pc（其實是當前地址＋2個指令字節長）加上偏移量＃4，得到_start所在內存地址，然後將內存地址的值去出來放在r0中。只要此指令和標號_start的相對位置不變，R0的值相同 0xeafffffe
2.adr r0, _start
簡單的說就是把 _start地址讀出來，而且這個地址是相對當前pc的，所以和當前程序運行地址相關，如果在0x30000000運行，r0 = pc(0x30000004 + 0x08) + #0 = 0x3000000C;如果在0x00000000運行, r0 = pc(0x00000004 + 0x08) + #0 = 0x0000000C,所以在不同的位置運行，r0所得到的結果是不一樣的，唯一確定的相對偏移量。
U-boot中那段relocate代碼就是通過adr實現當前程序是在RAM中還是flash中，下面進行簡要分析。
--------------------------------------------------------------------------------
relocate: /* 把U-Boot重新定位到RAM */
adr r0, _start /* r0是代碼的當前位置 */
/* adr僞指令，彙編器自動通過當前PC的值算出 如果執行到_start時PC的值，放到r0中：
當此段在flash中執行時r0 = _start = 0；當此段在RAM中執行時_start = _TEXT_BASE(在board/smdk2410/config.mk中指定的值爲0x30000000，即u-boot在把代碼拷貝到RAM中去執行的代碼段的開始) */
ldr r1, TEXT_BA_SE /* 測試判斷是從Flash啓動，還是RAM */
/* 此句執行的結果r1始終是0x30000000，因爲此值是又編譯器指定的(ads中設置，或-D設置編譯器參數) */
cmp r0, r1 /* 比較r0和r1，調試的時候不要執行重定位 */
--------------------------------------------------------------------------------
3. ldr, r0, =_start
這是一條僞指令，取得得是_start的絕對地址，不管在身地方運行，r0 = 0x3000000C
//////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
看《嵌入式linux應用開發》第六章實例中看到個句：
adrl r2,men_cfg_val
最初對adr1相當不解，後來發現，那個不是數字1，而是字母l（認真看頭部，有點區別的）
這裏記錄下ADRL的用法：
功能：將相對於程序或相對於寄存器的地址載入寄存器中。 與 ADR 指令相似。ADRL 生成兩個數據處理指令，因此它比 ADR 加載的地址範圍要寬。
語法
ADRL{cond} Rd,label
其中：
cond：是一個可選的條件代碼。Rd：是要加載的寄存器。label：是相對於程序或寄存器的表達式。
上面給出的範圍是相對於位於當前指令地址後的、距離當前指令四個字節（在 Thumb 代碼中）或兩個字（在 ARM 代碼中）遠的點而言的。如果對齊爲 16 字節，或與此點的相關性更高，則遠程地址的範圍可更大。
查看ADRL的同時，看到篇講述ldr與adr的區別的博文，感覺寫的很好，摘錄下來。
http://coon.blogbus.com/logs/2738861.html
ldr r0, _start
adr r0, _start
ldr r0, =_start
nop
mov pc, lr
_start:
nop
編譯的時候設置 RO 爲 0x0c008000
↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓
0c008000 <_start-0x14>:
c008000: e59f000c ldr r0, [pc, #12] ; c008014 <_start>
c008004: e28f0008 add r0, pc, #8 ; 0x8
c008008: e59f0008 ldr r0, [pc, #8] ; c008018 <_start+0x4>
c00800c: e1a00000 nop (mov r0,r0)
c008010: e1a0f00e mov pc, lr
0c008014 <_start>:
c008014: e1a00000 nop (mov r0,r0)
c008018: 0c008014 stceq 0, cr8, [r0], -#80
分析：
ldr r0, _start
從內存地址 _start 的地方把值讀入。執行這個後，r0 = 0xe1a00000
adr r0, _start
取得 _start 的地址到 r0，但是請看反編譯的結果，它是與位置無關的。其實取得的時相對的位置。例如這段代碼在 0x0c008000 運行，那麼 adr r0, _start 得到 r0 = 0x0c008014；如果在地址 0 運行，就是 0x00000014 了。
ldr r0, =_start
這個取得標號 _start 的絕對地址。這個絕對地址是在 link 的時候確定的。看上去這只是一個指令，但是它要佔用 2 個 32bit 的空間，一條是指令，另一條是 _start 的數據（因爲在編譯的時候不能確定 _start 的值，而且也不能用 mov 指令來給 r0 賦一個 32bit 的常量，所以需要多出一個空間存放 _start 的真正數據，在這裏就是 0x0c008014）。
因此可以看出，這個是絕對的尋址，不管這段代碼在什麼地方運行，它的結果都是 r0 = 0x0c008014
看此文最大的收穫不在於說懂了這幾個命令的用法，關鍵卻在於反彙編的運用，有反彙編看出不同用法的具體差別。
注：反彙編用arm—linux_objdump就可以實現了。