flex 異步 tree

例子一

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute">

    <mx:Script>
        <![CDATA[
            import flash.utils.Dictionary;

            import mx.events.TreeEvent;
            import mx.rpc.AsyncToken;
            import mx.rpc.events.FaultEvent;
            import mx.rpc.events.ResultEvent;

            private var dictionary:Dictionary = new Dictionary();

            private function itemOpenHandler(event:TreeEvent):void
            {
                var item:Object = event.item;
                if (item && item.@loadFlag == "false")
                {
                    service.url = item.@url;
                    var token:AsyncToken = service.send();
                    dictionary[token] = item;
                }
            }

            private function resultHandler(event:ResultEvent):void
            {
                var channel:XML = XML(dictionary[event.token]);
                var result:XML = XML(event.result);
                var items:XMLList = result..item;
                var item:XML = null;
                var node:XML = null;
                channel.@loadFlag = "true";
                delete channel.*;
                for each (item in items)
                {
                    node = <node/>;
                    node.@label = item.title;
                    channel.appendChild(node);
                }
            }

            private function faultHandler(event:FaultEvent):void
            {
                var channel:XML = XML(dictionary[event.token]);
                channel.@loadFlag = "true";
                delete channel.*;
            }

            private function getLabel(item:Object):String
            {
                var node:XML = XML(item);
                if (node.name().toString() == "item")
                    return node.title;
                else
                    return node.@label;
            }
        ]]>
    </mx:Script>

    <mx:XML id="blog">
        <root label="新浪博客">
            <channel label="文化" url="http://rss.sina.com.cn/blog/index/cul.xml" loadFlag="false">
                <node label="加載中..." />
            </channel>
            <channel label="八卦" url="http://rss.sina.com.cn/blog/index/ent.xml" loadFlag="false">
                <node label="加載中..." />
            </channel>
            <channel label="情感" url="http://rss.sina.com.cn/blog/index/feel.xml" loadFlag="false">
                <node label="加載中..." />
            </channel>
            <channel label="觀點" url="http://rss.sina.com.cn/blog/index/other.xml" loadFlag="false">
                <node label="加載中..." />
            </channel>
            <channel label="財經" url="http://rss.sina.com.cn/blog/index/stocks.xml" loadFlag="false">
                <node label="加載中..." />
            </channel>
        </root>
    </mx:XML>

    <mx:HTTPService id="service" concurrency="multiple" resultFormat="xml" 
        result="resultHandler(event)" fault="faultHandler(event)" />

    <mx:Tree id="tree" width="400" height="500" 
        dataProvider="{blog}" labelField="@label" 
        itemOpen="itemOpenHandler(event)" />

</mx:Application>

例子二

<?xml version="1.0" encoding="utf-8"?>
<mx:Canvas xmlns:mx="http://www.adobe.com/2006/mxml" width="100%" height="100%"
	 backgroundColor="#FFFFFF" creationComplete="vsstree.send();initEvent()">
 	<mx:HTTPService id="vsstree" showBusyCursor="true" method="POST" url="xml/tree.xml" useProxy="false" result="httpResult(event)" resultFormat="e4x">
    </mx:HTTPService>

	<mx:Script>
		<![CDATA[
			import action.myevent.EventNames;
			import action.myevent.CustomEvent;
			import mx.modules.IModuleInfo;
			import mx.modules.Module;
			import mx.modules.ModuleManager;
			import model.loginsuccess;
			import mx.core.Application;
			import mx.controls.Text;
			import mx.events.TreeEvent;
			import mx.collections.ArrayCollection;
			import mx.collections.ICollectionView;
			import mx.controls.Alert;
			import mx.rpc.events.ResultEvent;

			[Bindable]
		    private var listtree:XML;
		    private var selectedNode:XML;
		    private var catalogsid:String;
		    private function httpResult(event:ResultEvent):void
		    {
		        listtree= event.result as XML;
		    }

		    //點擊樹觸發事件：1、右側顯示當前目錄人員權限情況。2、可能要找出下級目錄
		    private function treeChange(e:Event):void{
		    	selectedNode = Tree(e.target).selectedItem as XML;
		    	catalogsid = selectedNode.attribute("id");
		    	CustomEvent.dispatcher.dispatchEvent(new CustomEvent(EventNames.CATALOGROW,catalogsid));
		    }

		    //點擊樹項目取到其下一級子目錄
		    private function initEvent():void{
				CustomEvent.dispatcher.addEventListener(EventNames.CATALOGROW,gettree);
			}

		    private function gettree(e:CustomEvent):void{
				catalogsid = e.data as String;
				remotetree.getTree(catalogsid);
			}

		    private function getResult(e:ResultEvent):void{
		    	//得到後臺返回的XML字符串
                var str:String = e.result as String;
		    	if(str!=null&&str!=""){
		    		var child:XML = new XML(str);
		    	/**
		    	 * 沒點擊過的需要appendChild，否則不需要。不然每點一次都會增加子目錄
		    	 * ??????????????碰到的問題：selectedNode.appendChild(child)增加的時候本級目錄下面會多出一級（跟本級目錄一樣）！！！
		    	 * ??????????????因爲後臺返回的是一個符合XML對象的字符串，一定要包含根節點（就是本級目錄），要想辦法把這個本級目錄去掉或者不顯示
		    	 * >>>>>>>>>>>>>>解決的辦法：將返回的XML對象加在本級目錄的父級目錄上，再把本級目錄刪掉就OK了
		    	 * 名詞解釋：本級目錄-->點擊的目錄，目錄-->節點
		    	 */
			    	if(selectedNode.children()==null||selectedNode.children().length()==0){
			    		//點擊不是root目錄的目錄
			    		if(selectedNode.parent()!=null){
			    			/**
			    			 * 在本級目錄的上級添加後臺返回的數據，此時效果相當於本級目錄的同級增加了一個目錄(後臺返回的數據)
			    			 * addChildAt參數說明：
			    			 * 1、要增加子目錄的位置，即子目錄放在哪個目錄下面	類型：Object
			    			 * 2、要增加的子目錄	類型：XML
			    			 * 3、增加的子目錄在父目錄中的位置索引		類型：int
			    			 * 4、包含此節點的整個集合  		類型：Object
			    			 */
			    			mytree.dataDescriptor.addChildAt(selectedNode.parent(),child,selectedNode.childIndex(),null);
			    			//把點擊的目錄刪掉
			    			delete selectedNode.parent().children()[selectedNode.childIndex()];
			    		}else{
			    			//點擊root目錄，直接appendChild然後不顯示root就達到我們想要的效果了
			    			selectedNode.appendChild(child);
			    			mytree.showRoot = false;
			    		}
			    	}
		    	}
            }

		    //樹上顯示其有幾個子目錄
		    private function tree_labelFunc(item:XML):String { 
                var children:ICollectionView; 
                var suffix:String = ""; 
                if (mytree.dataDescriptor.isBranch(item)) { 
                    children = mytree.dataDescriptor.getChildren(item); 
                    suffix = " (" + children.length + ")"; 
                } 
                return item[mytree.labelField] + suffix; 
            }

		]]>
	</mx:Script>
	<mx:RemoteObject id="remotetree" destination="Tree" result="getResult(event)"/>
	<mx:Canvas dropShadowEnabled="false" width="100%" height="100%">
		<mx:Tree id="mytree" width="100%" height="100%" 
					dataProvider="{listtree}" 
					change="treeChange(event)"
				    labelField="@label"
				    labelFunction="tree_labelFunc"
				    folderClosedIcon="@Embed('assets/image/foldericon.gif')"
				    folderOpenIcon="@Embed('assets/image/openfoldericon.gif')"
				    defaultLeafIcon="@Embed('assets/image/foldericon.gif')"/> 
	</mx:Canvas>

</mx:Canvas>