Delphi中的“委託”

.NET中有委託（Delegate）的概念，其聲明形式如下所示：

public delegate void MyDelegate(int aIntParam, string aStringParam);

　　依個人所見，委託實際上就是規定一種接口，提供一種規範，任何符合該委託簽名的函數/過程都屬於同一類。

　　在Delphi中，也有類似於“委託”的概念（不過可沒有C#的功能豐富，不過兩者從根本上說都應該是函數指針），如下所示：

type
TMyDelegateFunc = function (AIntParam: integer; AStringParam: string): Boolean;
TMyDelegateProc = procedure (AIntParam: integer; AStringParam: string);

　　在以上的聲明中，還可以用of object關鍵字來規定所定義的“委託”是應用於對象的函數/過程，還是應用於非對象的函數/過程，例：

type
TMyObjectDelegate = procedure (AIntParam: integer; AStringParam: string) of object; //對象的

函數/過程
TMyRegularDelegate = procedure (AIntParam: integer; AStringParam: string); //非對象的（一般的）函數/過程

　　以下舉個簡單的例子來說明一下Delphi中“委託”的應用。附件爲完整程序。
　　

{type
    TMyDelegateFunc = function (AIntParam: integer; AStringParam: string): Boolean;
    TMyDelegateProc = procedure (AIntParam: integer; AStringParam: string);

//在以上的聲明中，還可以用of object關鍵字來規定所定義的“委託”是應用於對象的函數/過程，還是應用於非對象的函數/過程，例：

type
    TMyObjectDelegate = procedure (AIntParam: integer; AStringParam: string) of object; //對象的函數/過程
    TMyRegularDelegate = procedure (AIntParam: integer; AStringParam: string); //非對象的（一般的）函數/過程

//以下舉個簡單的例子來說明一下Delphi中“委託”的應用。附件爲完整程序。    }
　　
unit UnitFrmTest;
interface
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
type
  TDelegateType = (dtObject, dtRegular);
  
  //對象的函數委託
  TObjectNumFuncs = function (const ANumOne: Double;
    const ANumTwo: Double): Double of object;
  //非對象（一般）的函數委託
  TRegularNumFuncs = function (const ANumOne: Double;
    const ANumTwo: Double): Double;
type
  TfrmTest = class(TForm)
    edtNumOne: TEdit;
    edtNumTwo: TEdit;
    btnAdd: TButton;
    btnSub: TButton;
    btnMultiply: TButton;
    btnDivide: TButton;
    lblResult: TLabel;
    rbObjectDelegate: TRadioButton;
    rbRegularDelegate: TRadioButton;
    procedure rbRegularDelegateClick(Sender: TObject);
    procedure rbObjectDelegateClick(Sender: TObject);
    procedure MyButtonClick(Sender: TObject);
  private
    { Private declarations }
    //指示當前是使用對象的函數，還是非對象的函數
    FDelegateType: TDelegateType;
    
    { 對象的函數列表 }
    function Add(const ANumOne: Double;
      const ANumTwo: Double): Double;
    function Sub(const ANumOne: Double;
      const ANumTwo: Double): Double;
    function Multiply(const ANumOne: Double;
      const ANumTwo: Double): Double;
    function Divide(const ANumOne: Double;
      const ANumTwo: Double): Double;
    { 對象的函數列表　結束 }
    function DoObjectCalc(const ANumOne: Double;
      const ANumTwo: Double; AMethod: TObjectNumFuncs): Double;
  public
    { Public declarations }
  end;

{ 非對象（一般）的函數列表 }
  function Add(const ANumOne: Double; const ANumTwo: Double): Double;
  function Sub(const ANumOne: Double; const ANumTwo: Double): Double;
  function Multiply(const ANumOne: Double; const ANumTwo: Double): Double;
  function Divide(const ANumOne: Double; const ANumTwo: Double): Double;
  function DoRegularCalc(const ANumOne: Double; const ANumTwo: Double;
    AMethod: TRegularNumFuncs): Double;
{ 非對象（一般）的函數列表　結束 }
var
  frmTest: TfrmTest;
implementation
{$R *.dfm}
{ 非對象（一般）的函數列表 }
function Add(const ANumOne: Double; const ANumTwo: Double): Double;
begin
  Result := ANumOne + ANumTwo;
end;
function Sub(const ANumOne: Double; const ANumTwo: Double): Double;
begin
  Result := ANumOne - ANumTwo;
end;
function Multiply(const ANumOne: Double; const ANumTwo: Double): Double;
begin
  Result := ANumOne * ANumTwo;
end;
function Divide(const ANumOne: Double; const ANumTwo: Double): Double;
begin
  try
    Result := ANumOne / ANumTwo;
  except
    on E: EZeroDivide do
    begin
      frmTest.edtNumTwo.SetFocus();
      frmTest.lblResult.Caption := '除數不能爲零';
      Abort();
    end;
  end;
end;
function DoRegularCalc(const ANumOne: Double; const ANumTwo: Double;
  AMethod: TRegularNumFuncs): Double;
begin
  Result := AMethod(ANumOne, ANumTwo);
end;
{ 非對象（一般）的函數列表　結束 }
{ TfrmTest }
{ 對象的函數列表 }
function TfrmTest.Add(const ANumOne, ANumTwo: Double): Double;
begin
  Result := ANumOne + ANumTwo;
end;
function TfrmTest.Divide(const ANumOne, ANumTwo: Double): Double;
begin
  try
    Result := ANumOne / ANumTwo;
  except
    on E: EZeroDivide do
    begin
      edtNumTwo.SetFocus();
      lblResult.Caption := '除數不能爲零';
      Abort;
    end;
  end;
end;
function TfrmTest.DoObjectCalc(const ANumOne, ANumTwo: Double;
  AMethod: TObjectNumFuncs): Double;
begin
  Result := AMethod(ANumOne, ANumTwo);
end;
function TfrmTest.Multiply(const ANumOne, ANumTwo: Double): Double;
begin
  Result := ANumOne * ANumTwo;
end;
procedure TfrmTest.MyButtonClick(Sender: TObject);
var
  dblNumOne, dblNumTwo, dblResult: Double;
begin
  if not (Sender is TButton) then Exit;
  dblNumOne := StrToFloatDef(Trim(edtNumOne.Text), 0.0);
  dblNumTwo := StrToFloatDef(Trim(edtNumTwo.Text), 0.0);
  
  case (Sender as TButton).Tag of
    0: //加
      begin
        case Self.FDelegateType of
          dtObject:
            begin
              dblResult := Self.DoObjectCalc(dblNumOne, dblNumTwo, Self.Add);
              //若爲
              //dblResult := Self.DoObjectCalc(dblNumOne, dblNumTwo, UnitFrmTest.Add);
              //則會提示以下錯誤：
              //E2009 Incompatible types: 'regular procedure and method pointer'
            end;
          dtRegular:
            begin
              dblResult := DoRegularCalc(dblNumOne, dblNumTwo, UnitFrmTest.Add);
              //若爲
              //dblResult := DoRegularCalc(dblNumOne, dblNumTwo, Self.Add);
              //則會提示以下錯誤：
              //E2009 Incompatible types: 'regular procedure and method pointer'
            end;
        end;
      end;
    1: //減
      begin
        case Self.FDelegateType of
          dtObject:
            begin
              dblResult := Self.DoObjectCalc(dblNumOne, dblNumTwo, Self.Sub);
            end;
          dtRegular:
            begin
              dblResult := DoRegularCalc(dblNumOne, dblNumTwo, UnitFrmTest.Sub);
            end;
        end;
      
      end;
    2: //乘
      begin
        case Self.FDelegateType of
          dtObject:
            begin
              dblResult := Self.DoObjectCalc(dblNumOne, dblNumTwo, Self.Multiply);
            end;
          dtRegular:
            begin
              dblResult := DoRegularCalc(dblNumOne, dblNumTwo, UnitFrmTest.Multiply);
            end;
        end;
      
      end;
    3: //除
      begin
        case Self.FDelegateType of
          dtObject:
            begin
              dblResult := Self.DoObjectCalc(dblNumOne, dblNumTwo, Self.Divide);
            end;
          dtRegular:
            begin
              dblResult := DoRegularCalc(dblNumOne, dblNumTwo, UnitFrmTest.Divide);
            end;
        end;
      
      end;
    
  end;
  lblResult.Caption := '結果：' + FloatToStr(dblResult);
end;
procedure TfrmTest.rbObjectDelegateClick(Sender: TObject);
begin
  Self.FDelegateType := dtObject;
end;
procedure TfrmTest.rbRegularDelegateClick(Sender: TObject);
begin
  Self.FDelegateType := dtRegular;
end;
function TfrmTest.Sub(const ANumOne, ANumTwo: Double): Double;
begin
  Result := ANumOne - ANumTwo;
end;
{ 對象的函數列表　結束 }
end.

Delphi中的“委託”

win11關閉自動檢測病毒刪文件

千兆寬帶實際網速能到達多少？

Delphi函數指針的兩種定義

做程序員要細心,並且要懷疑自己

Delphi中的內存對齊與 Packed關鍵字

Delphi 的動態數組1

C/C++中的內存管理

https://yachay.unat.edu.pe/blog/index.php?comment_area=format_blog&comment_component=blog&comment_co

linux以太網驅動總結