第十三章 文本處理工具awk

文本處理工具awk

awk工作原理和基本用法說明

awk: Aho, Weinberger, Kernighan,報告生成器，格式化文本輸出，GNU/Linux發佈的AWK目前由自由軟件基會(FSF) 進行開發和維護，通常也稱它爲GNU AWK

有多種版本：

• AWK：原先來源於AT & T實驗室的AWK
• NAWK：New awk, AT & T實驗室的AWK的升級版
• GAWK：即GNU AWK。所有的GNU/Linux發佈版都自帶GAWK，它與AWK和NAWK完全兼容

gawk：模式掃描和處理語言，可以實現下面功能

• 文本處理
• 輸出格式化的文本報表
• 執行算數運算
• 執行字符串操作等等

格式：

awk [options] 'program' var=value file...
awk [options] -f programfile var=value file...

說明：

program 通常是被放在單引號中，並可以由三種部分組成

• BEGIN語句塊
• 模式匹配的通用語句塊
• END語句塊

常用選項：

• -F “分隔符” 指明輸入時用到的字段分隔符
• -v var=value 變量賦值

Program格式：

pattern{action statements;...}

pattern:決定動作語句何時觸發及觸發事件，比如：BEGIN，END
action statements：對數據進行處理，放在{}內指明，常見：print,printf

awk工作過程

第一步：執行BEGIN{action;…}語句塊中的語句
第二步：從文件或標準輸入(stdin)讀取一行，然後執行pattern{action;…}語句塊，它逐行掃描文件，從第一行到最後一行重複這個過程，指導文件全部被讀取完畢。
第三步：當讀至輸入流末尾時，執行END{action;…}語句塊

BEGIN語句塊在awk開始從輸入流中讀取行之前被執行，這是一個可選的語句塊，比如變量初始化、打印輸出表格的表頭等語句通常可以寫在BEGIN語句塊中

END語句塊在awk從輸入流中讀取完所有的行之後即被執行，比如打印所有行的分析結果，這類信息彙總都是在END語句塊中完成，它也是一個可選語句塊

pattern語句塊中的通用命令是最重要的部分，也是可選的。如果沒有提供pattern語句塊，則默認執行{print}，即打印每一個讀取到的行，awk讀取的每一行都會執行該語句塊。

分隔符、域和基量

• 由分隔符分隔的字段（列，域）標記$1,$2...$n稱爲域標識，$0爲所有域，注意：和shell中變量$符號含義不同
• 文件的每一行稱爲記錄record
• 如果省略action，則默認執行print $0的操作

常用的action分類

• output statements:print,printf
• Expressions:算術，比較表達式
• Compound statements：組合語句
• Control statements, if, while等
• input statements

awk控制語句

• {statements;…} 組合語句
• if(condition){statements;…}
• if(condition){statements;…}else{statements;…}
• while(condition){statements;…}
• do{statements;…}while(condition)
• for(expr1;expr2;expr3){statements;…}
• break
• continue
• exit

動作print

格式:

print item1, item2, ...

說明：

• 逗號分隔符
• 輸出item可以是字符串，也可是數值；當前記錄的字段、變量或awk的表達式
• 如省略item，相當於print $0

範例：

awk '{print "hello,awk"}'
awk -F: '{print}' /etc/passwd
awk -F: '{print $0}' /etc/passwd
awk -F: '{print "wang"}' /etc/passwd
awk -F: '{print $1}' /etc/passwd
awk -F: '{print $1,$2}' /etc/passwd
awk -F: '{print $1"\t"$2}' /etc/passwd
grep "^UUID" /etc/fstab | awk '{print $2,$4}'

[root@centos7: ~]#df | awk -F"[[:space:]]+|%" '{print $5}'
Use
84
0
1
2
0
18
1
1
0

awk變量

awk中的變量分爲：內置和自定義變量
常見的內置變量

FS：輸入字段分隔符，默認爲空白字符，相當於-F

範例：

awk -v FS=':' '{print $1,FS,$3}' /etc/passwd
awk -F: '{print $1,$3,$7}' /etc/passwd
S=:;awk -v FS=$S '{print $1,FS,$3}' /etc/passwd

OFS：輸出字段分隔符,默認空白字符

範例：

awk -v FS=':' -v OFS=':' '{print $1,$3,$7}' /etc/passwd

RS:輸入記錄分隔符，指定輸入時的換行符

範例：

awk -v RS=' ' '{print }' /etc/passwd

[root@centos7: ~]#cat awk.txt 
a,b,c;d,e
f;h,i,j
k;l;m;
n,o,p
[root@centos7: ~]#awk -F"," '{print $2}' awk.txt 
b
i

o
# 默認輸入是回車換行爲分割記錄（使用RS變量指定分號切割記錄）
[root@centos7: ~]#awk -F"," -v RS=";"  '{print $2}' awk.txt 
b
e
f
i


o

ORS:輸出記錄分隔符，輸出時用指定符號代替換行符

範例：

awk -v RS=' ' -v ORS='###' '{print $0}' /etc/passwd

[root@centos7: ~]#awk -F"," -v RS=";" -v ORS='##'  '{print $2}' awk.txt 
b##e
f##i######o##

NF:字段數量

範例:

#引用變量時，變量前不需加$
awk -F: '{print NF}' /etc/fstab 
awk -F: '{print $(NF-1)}' /etc/passwd

範例：發現連接數超過3個以上的IP拒絕訪問

cat deny_dos.sh
while true;do
	ss -nt | grep "^ESTAB" | awk -F"[[:space:]]+|:" '{print $(NF-2)}' |sort | uniq -c | while read count ip; do
	if [ ${count} -gt 3 ]; then
		iptables -A INPUT -s ${ip} -j REJECT
	fi
  done
  sleep 1000;
done  

NR:記錄號

範例:

#統計所有行行號
[root@centos7: ~]#awk '{print NR}' /etc/fstab;
1
2
3
4
5
6
7
8
9
10
11
12
#統計最後一行的行號
awk 'END {print NR}' /etc/fstab
12

FNR:各文件分別計數，記錄號

範例:

#每個文件獨立的記錄行號
[root@centos7: ~]#awk -F: '{print FNR}' /etc/passwd /etc/fstab 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
1
2
3
4
5
6
7
8
9
10
11
12

FILENAME:當前文件名

範例：

awk '{print FILENAME}' /etc/fstab

ARGC:命令行參數的個數

範例：

[root@centos7: ~]#awk 'BEGIN {print ARGC}' /etc/fstab /etc/inittab
3
[root@centos7: ~]#awk 'BEGIN {print ARGV[0],ARGV[1],ARGV[2]}' /etc/fstab /etc/inittab
awk /etc/fstab /etc/inittab

ARGV：數組，保存的是命令行所給定的各參數

範例：

[root@centos7: ~]#awk 'BEGIN {print ARGV[0]}' /etc/fstab /etc/inittab
awk
[root@centos7: ~]#awk 'BEGIN {print ARGV[1]}' /etc/fstab /etc/inittab
/etc/fstab

自定義變量（區分字符大小寫）

• -v var=value
• 在program中直接定義

範例：

#程序外定義變量
[root@centos7: ~]#awk -v name="cfl" '{print name}' /etc/issue
cfl
cfl
cfl
#程序內定義
[root@centos7: ~]#awk 'BEGIN {name="cfl";print name}' /etc/issue
cfl

#將程序(單引號中的內容)定義在文件中，然後命令調用文件
[root@centos7: ~]#cat f1.awk 
BEGIN {name="cfl";print name}
[root@centos7: ~]#awk -f f1.awk /etc/issue
cfl

動作printf

printf可以實現格式化輸出

格式：

printf "FORMAT", item1, item2,...

說明：

• 必須指定FORMAT
• 不會自動換行，需要顯式地給出換行控制符，\n
• FORMAT中需要分別爲後面每個item指定格式符

格式符：與item一一對應

• %c：顯示字符的ASCII碼
• %d,%l：顯示十進制整數
• %e,%E:顯示科學計數法數值
• %f：顯示爲浮點數
• %g,%G：以科學計數法或浮點形式顯示數值
• %s：顯示字符串
• %u：無符號整數
• %%：顯示%自身

修飾符

#[.#] 第一個數字控制顯示的寬度；第二個#表示小數點後的精度，如%3.1f
- 左對齊（默認右對齊）如%-15s
+ 顯示數值的正負符號  如%+d

範例：

awk -F '{printf "%s",$1}' /etc/passwd
awk -F '{printf "%s\n",$1}' /etc/passwd
awk -F:  '{printf "%s===%d\n",$1,$3}' /etc/passwd
#左對齊
awk -F:  '{printf "%-20s===%20d\n",$1,$3}' /etc/passwd

awk -F:  'BEGIN{print "--------------------------------"} {printf "%-20s|%10d\n",$1,$3}' /etc/passwd

操作符

算數操作符

x+y,x-y,x*y,x/y,x^y,x%y
-x:轉換爲負數
+x：將字串轉換爲數值

字符串操作符：沒有符號的操作符，字符串連接

賦值操作符：

=,+=,-=,*=,/=,%=,^=,++,--

範例:

awk 'BEGIN{i=0;print ++i, i}'
awk 'BEGIN{i=0;print i++, i}'

比較操作符：

==,!=,>,>=,<,<=

模式匹配符：

~ 左邊是否和右邊匹配，包含關係
!~ 是否不匹配

範例：

[root@centos7: ~]#awk -F: '$0 ~ /root/{print $1}' /etc/passwd
root
operator

[root@centos7: ~]#awk '$0 ~"^root"' /etc/passwd
root:x:0:0:root:/root:/bin/bash

awk '%0 !~ /root/' /etc/passwd
#省略{}表示{print $0}
[root@centos7: ~]#awk -F: '$3==0' /etc/passwd
root:x:0:0:root:/root:/bin/bash

邏輯操作符：

與&&，或||，非!

範例：

awk -F: '$3>=0 && $3 <=1000 {print $1}' /etc/passwd
[root@centos7: ~]#awk -F: '$3==0 || $3>=1000{print $1}' /etc/passwd
root
nfsnobody
centos7
mage

awk -F: '!($3==0){print $1}' /etc/passwd
awk -F: '!($3>=500){print $3}' /etc/passwd

條件表達式（三目表達式）

selector?if-true-expression:if-false-expression

範例：

[root@centos7: ~]#awk -F: '{$3>=1000?usertype="Common User":usertype="sysUser"; printf "%-20s:%12s\n",$1,usertype}' /etc/passwd

模式PATTERN

PATTERN：根據pattern條件，過濾匹配的行，再做處理

1.如果未指定：空模式，匹配每一行

範例：

awk -F: '{print $1}' /etc/passwd

2./regular expression/：僅處理能夠模式匹配到的行，需要用/ / 括起來

範例：

awk '/^UUID/{print $1}' /etc/fstab
awk '!/^UUID/{print $1}' /etc/fstab

3.relational expression:關係表達式，結果爲“真”纔會被處理

真：結果爲非0值，非空字符串

假：結果爲空字符串或0值
範例：

awk -F: 'i=1;j=1{print i,j}' /etc/passwd
awk '!0' /etc/passwd
awk '!1' /etc/passwd
awk -F: '$3>=1000{print $1,$3}' /etc/passwd
awk -F: '$3<1000{print $1,$3}' /etc/passwd
awk -F: '$NF=="/bin/bash"{print $1,$NF}' /etc/passwd
awk -F: '$NF ~ /bash$/{print $1,$NF}' /etc/passwd

4.line range:行範圍

/pat1/，/pat2/ 不支持直接給出數字格式

範例：

awk -F: '/^root\>/,/^nobody\>/{print $1}' /etc/passwd
awk -F: 'NR>=10&&NR<=20{print NR,$1}' /etc/passwd

5.BEGIN/END模式

BEGIN{}：僅再開始處理文件中的文本之前執行一次

END{}：僅在文本處理完成之後執行一次

範例：

awk -F: 'BEGIN{print "USER USERID"}{print $1":"$3}END{print "END FILE"}' /etc/passwd
awk -F: '{print "USER USERID";print $1":"$3}END{print "END FILE"}' /etc/passwd
seq 10 | awk 'i=0'
seq 10 | awk 'i=1'
seq 10 | awk 'i=!i'
seq 10 | awk '{i=!i;print i}'
seq 10 | awk '!(i=!i)'
seq 10 | awk -v i=1 'i=!i'

條件判斷if-else

語法：

if(condition){statement;...}[else statement]
if(condition1){statement1}eles if(condition2){statement2}else{seatement3}

使用場景：對awk取得的整行或某個字段做條件判斷

範例：

awk -F: '{if($3>=1000)print $1,$3}' /etc/passwd
awk -F: '{if($NF=="/bin/bash") print $1}' /etc/passwd
awk '{if(NF>5)print $0}' /etc/fstab
awk -F: '{if($3>=1000){printf "common user:%s\n", $1} else {printf "root or Sysuser: %s\n", $1}}' /etc/passwd
awk -F: '{if($3>=1000) printf "common user:%s\n", $1; else printf "root or Sysuser:%s\n", $1}' /etc/passwd
df -h|awk -F% '/^\/dev/{print $1}' | awk '$NF >=80{print $1,$3}'
awk 'BEGIN{test=100;if(test>90){print "very good"}else if (test>60){print "good"} else{print "no pass"}}'

while 循環

語法：while(condition){statement;…}
條件“真”，進入循環；條件"假"，退出循環
使用場景：
對一行內的多個字段逐一類似處理時使用
對數組中的各元素逐一處理時使用

示例：

awk '/^[[:space:]]*linux16/{i=1;while(i<=NF){print $i,length($i);i++}}' /etc/grub2.cfg

awk '/^[[:space:]]*linux16/{i=1;while(i<=NF){if(length($i)>=10){print $i,length($i)};i++}}' /etc/grub2.cfg

do-while循環

語法：

do{statement;...}while(condition)

意義：無論真假，至少執行一次循環體
範例：

awk 'BEGIN{total=0;i=0;do{total+=i;i++}while(i<=100);print total}'

for循環

語法：

for(epr1;expr2;expr3){statement;...}

常見用法：

for(variable assignment;condition;iteration process){for-body}

特殊用法：能夠遍歷數組中的元素

for(var in array){for-body}

範例：

[root@centos7: ~]#awk 'BEGIN{for(i=0;i<=100;i++){total+=i};print total}'
5050

範例：

awk '/^[[:space:]]*linux16/{for(i=1;i<=NF;i++){print $i,length($i)}}' /etc/grub2.cfg

性能比較

time (awk 'BEGIN{total=0;for(i=0;i<=10000;i++){total+=i;}print total;}')

time (total=0; for i in{1..10000};do total=$(($total+i));done;echo $total)

time(for ((i=0;i<=10000;i++));do let total+=i;done;echo $total)

time(seq -s "+" 10000|bc)

switch語句

語法：

switch(expression){case value or/REGEX/:statement1:case valuse2 or /REGEXP2/:statement2;...default:statement}

break和continue

格式:

break [n]
continue [n]

範例：

awk 'BEGIN{sum=0;for(i=1;i<=100;i++){if(i%2==0)continue;sum+=i}print sum}'
awk 'BEGIN{sum=0;for(i=1;i<=100;i++){if(i==66)break;sum+=i}print sum}'

next

next可以提前結束對本行處理而直接進入下一行處理(awk自身循環)

範例：

awk -F: '{if($3%2!=0)next;print $1,$3}' /etc/passwd

數組

awk的數組爲關聯數組
格式

array[index-expression]

index-pression

• 可使用任意字符串；字符串要使用雙引號括起來
• 如果某數組元素事先不存在，在引用時，awk會自動創建此元素，並將其值初始化爲“空串”
• 若要判斷數組中是否存在某元素，要使用“index in array” 格式進行遍歷

範例：

weekdays["mon"]="Monday"
[root@centos7: ~]#awk 'BEGIN{weekdays["mon"]="Monday";weekdays["tue"]="Tuesday";print weekdays["mon"]}'
Monday
# 去重打印
awk '!line[$0]++' dupfile
awk '{!line[$0]++;print $0,line[$0]}' dupfile

若要遍歷數組中的每個元素，要使用for循環

for(var in array){for-body}

注意：var會遍歷array的每個索引
範例：判斷數組索引是否存在

[root@centos7: ~]#awk 'BEGIN{a["i"]="x";a["j"]="y";print "i" in a, "y" in a}'
1 0

範例：遍歷數組

[root@centos7: ~]#awk 'BEGIN{weekdays["mon"]="Monday";weekdays["tue"]="Tuesday";for(var in weekdays){print weekdays[var]}}'
Tuesday
Monday


[root@centos7: ~]#awk -F: '{user[$1]=$3}END{for(i in user){print "username: "i,"userid: "user[i]}}' /etc/passwd
username: adm userid: 3
username: rpc userid: 32
username: radvd userid: 75
username: sync userid: 5
...

範例：多維數組

[root@centos7: ~]#awk 'BEGIN{array[1][1]=11; array[1][2]=12; for (i in array)for(j in array[i])print array[i][j]}'
11
12

awk 函數

awk 的函數分爲內置和自定義函數

常見內置函數

數值處理：
rand()：返回0和1之間一個隨機數

srand()：配合rand()生成隨機數的種子
int()：返回整數

範例：

awk 'BEGIN{srand();for(i=1;i<=10;i++)print int(rand()*100)}'

字符串處理：

length([s])：返回字符串的長度

sub(r, s, [t])：對字符串搜索r表示模式匹配的內容，並將第一個匹配內容替換爲s

範例：

[root@centos7: ~]#echo "2008:08:08 08:08:08" | awk 'sub(/:/,"-",$1)'
2008-08:08 08:08:08

[root@centos7: ~]#echo "2008:08:08 08:08:08" | awk '{sub(/:/,"-",$1);print $0}'
2008-08:08 08:08:08

gsub(r, s[t])：對t字符串進行搜索r表示的模式匹配的內容,並全部替換爲s所表示的內容

範例：

[root@centos7: ~]#echo "2008:08:08 08:08:08" | awk 'gsub(/:/,"-",$0)'
2008-08-08 08-08-08

[root@centos7: ~]#echo "2008:08:08 08:08:08" | awk '{gsub(/:/,"-",$0);print $0}'
2008-08:08 08-08-08

split(s, array, [r])：以r爲分隔符，切割字符串s， 並將切割後的結果保存至array所表示的數組中，第一個索引值爲1，第二個索引值爲2，…

範例：

[root@centos7: ~]#netstat -tn | awk '/^tcp/ {split($5,ip,":"); count[ip[1]]++}END{for (i in count){print i,count[i]}}'
127.0.0.1 2
192.168.2.100 1
192.168.2.1 1

system 函數：可以awk中調用shell命令
空格是awk中的字符串連接符，如果system中需要使用awk中的變量可以使用空格分隔，或者說除了awk的變量外其它一律用""引用起來

awk 'BEGIN{system("hostname")}'
awk 'BEGIN{score=100;system("echo your score is" score)}'

自定義函數

自定義函數格式：

function name(parameter, parameter, ...) {
	statements
	return expression
}

範例：

root@centos7: ~]#cat fun.awk
function max(x, y){
	x>y?var=x:var=y
	return var
}
BEGIN {print max(a,b)}

[root@centos7: ~]#awk -v a=20 -v b=30 -f fun.awk 
3

awk腳本

將awk程序寫成腳本，直接調用或執行

範例：

cat f1.awk
{if($3>=1000)print $1,$3}
awk -F: -f f1.awk /etc/passwd

[root@centos7: ~]#awk -F: -f f1.awk /etc/passwd
nfsnobody 65534
centos7 1000
mage 1010

範例：

cat f3.awk
#!/bin/awk -f
#this is a awk script
{if($3>=1000)print $1,$3}

[root@centos7: ~]#vim f3.awk 
[root@centos7: ~]#./f3.awk -F: /etc/passwd
nfsnobody 65534
centos7 1000
mage 1010

向awk腳本傳遞參數

格式：

awkfile var=value var2=value2... Inputfile

注意：在BEGIN過程中不可用。直到首行輸入完成以後，變量纔可用。可以通過-v參數，讓awk在BEGIN之前得到變量的值。命令行中每一個指定的變量都需要一個-v參數

範例：

[root@centos7: ~]#cat test.awk
#!/bin/awk -f
{if($3 >=min&&$3<=max)print $1,$3}

[root@centos7: ~]#chmod +x test.awk
[root@centos7: ~]#./test.awk -F: min=100 max=200 /etc/passwd
systemd-network 192
abrt 173
rtkit 172
pulse 171
qemu 107
usbmuxd 113