SpringBoot JPA 自動生成代碼 (一) 生成實體類

之前做SSM項目時，一直使用的是Mybatis的Generator自動生成代碼工具，也是蠻好使的。現在換了SpringBoot，自動生成代碼使用的是人人開源項目修改來的，可以直接生成簡單的CRUD代碼和HTML頁面。

一次偶然的機會，幫羣裏一個老弟看代碼時，發現他們自動生成代碼是用的JPA，之前聽說過這個，但是沒有用過，所以也是一臉懵逼的。於是查了查怎麼用，之後發現也是很神奇的，也是可以直接生成實體類，然後Dao層和Service直接繼承就可以完成簡單的CRUD了，自己剛接觸，這裏記錄一下簡單的使用過程。

今天是第一次使用JPA生成代碼，在查了半天之後，發現自動生成的腳本的樣式是千奇百怪的，那個老弟還非要按照別人的代碼格式生成，但是人家又不給他生成代碼的腳本，讓他自己百度找，對於小白的我就很懵逼了。

這裏使用的是IDEA，其自帶的生成實體類的腳本Generate POJOs.groovy有點過於簡單了，那麼下面先看看自帶的這個腳本怎麼用。

首先是打開DataSource

這時會在右邊彈出如下圖的窗口，由於我這裏已經添加過數據庫了，第一次打開會提示使用Alt + Insert 進行添加數據庫，我這裏使用的是MySQL。


輸入需要連接的數據庫的信息，然後點擊左下角的下載工具，然後點擊Test Connection，如果提示Success 證明連接成功了，這時點擊Apply，ok即可。

下面還是使用的之前添加的jpa-demo這個數據庫，可以看到這裏只有一張User表，我們就拿這個來生成。

右鍵我們需要生成實體類的表格，這裏可以多選，可以看到如下圖。如果使用默認的腳本，可以直接點擊最後的Generate POJOs.groovy，這裏我們簡單的擴展一下，自定義我們自己的腳本。

可以看到，IDEA跳轉到這個頁面了，這個文件的內容就是系統自動帶的生成實體類的腳本。

第一次用的時候沒有仔細看，直接按照網上的博客直接生成了，感覺蠻神奇的，後來發現生成的跟那個項目裏面別人寫的不一樣，這才反應過來，看一下這個腳本文件的內容，發現這個腳本也是有固定的套路的。

這裏貼上一個簡單的生成實體類的腳本，可以隨意自己定製：

import com.intellij.database.model.DasTable
import com.intellij.database.model.ObjectKind
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

import java.text.SimpleDateFormat

/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */
packageName = ""
typeMapping = [
        (~/(?i)tinyint|smallint|mediumint/)      : "Integer",
        (~/(?i)int/)                             : "Long",
        (~/(?i)bool|bit/)                        : "Boolean",
        (~/(?i)float|double|decimal|real/)       : "BigDecimal",
        (~/(?i)datetime|timestamp|date|time/)    : "Date",
        (~/(?i)blob|binary|bfile|clob|raw|image/): "InputStream",
        (~/(?i)/)                                : "String"
]


FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable && it.getKind() == ObjectKind.TABLE }.each { generate(it, dir) }
}

def generate(table, dir) {
    def className = javaName(table.getName(), true)
    def fields = calcFields(table)
    packageName = getPackageName(dir)
    PrintWriter printWriter = new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "UTF-8"))
    printWriter.withPrintWriter { out -> generate(out, className, fields, table) }

//    new File(dir, className + ".java").withPrintWriter { out -> generate(out, className, fields,table) }
}

// 獲取包所在文件夾路徑
def getPackageName(dir) {
    return dir.toString().replaceAll("\\\\", ".").replaceAll("/", ".").replaceAll("^.*src(\\.main\\.java\\.)?", "") + ";"
}

def generate(out, className, fields, table) {
    out.println "package $packageName"
    out.println ""
    out.println "import javax.persistence.Column;"
    out.println "import javax.persistence.Entity;"
    out.println "import javax.persistence.Table;"
    out.println "import javax.persistence.Id;"
    out.println "import javax.persistence.GeneratedValue;"
    out.println "import java.io.Serializable;"
    Set types = new HashSet()

    fields.each() {
        types.add(it.type)
    }

    if (types.contains("Date")) {
        out.println "import java.util.Date;"
    }

    if (types.contains("BigDecimal")) {
        out.println "import java.math.BigDecimal;"
    }

    if (types.contains("InputStream")) {
        out.println "import java.io.InputStream;"
    }
    out.println ""
    out.println "/**\n" +
            " * @Description  \n" +
            " * @Author  linmengmeng\n" + //1. 修改idea爲自己名字
            " * @Date " + new SimpleDateFormat("yyyy-MM-dd HH:mm:ss").format(new Date()) + " \n" +
            " */"
    out.println ""
    out.println "@Entity"
    out.println "@Table ( name =\"" + table.getName() + "\" , schema = \"\")" //2. schema = \"後面添加自己的表空間名稱(mysql可以不添加, 不用這個schema屬性也行)
    out.println "public class $className  implements Serializable {"
    out.println ""
    out.println genSerialID()
    fields.each() {
        out.println ""
        // 輸出註釋
        if (isNotEmpty(it.commoent)) {
            out.println "\t/**"
            out.println "\t * ${it.commoent.toString()}"
            out.println "\t */"
        }

        if ((it.annos+"").indexOf("[@Id]") >= 0) out.println "\t@Id"

        if (it.annos != "") out.println "   ${it.annos.replace("[@Id]", "")}"


        // 輸出成員變量
        out.println "\tprivate ${it.type} ${it.name};"
    }

    // 輸出get/set方法
    fields.each() {
        out.println ""
        out.println "\tpublic ${it.type} get${it.name.capitalize()}() {"
        out.println "\t\treturn this.${it.name};"
        out.println "\t}"
        out.println ""

        out.println "\tpublic void set${it.name.capitalize()}(${it.type} ${it.name}) {"
        out.println "\t\tthis.${it.name} = ${it.name};"
        out.println "\t}"
    }

    // 輸出toString方法
    out.println ""
    out.println "\t@Override"
    out.println "\tpublic String toString() {"
    out.println "\t\treturn \"{\" +"
    fields.each() {
        out.println "\t\t\t\t\t\"${it.name}='\" + ${it.name} + '\\'' +"
    }
    out.println "\t\t\t\t'}';"
    out.println "\t}"

    out.println ""
    out.println "}"
}

def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())

        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        def comm = [
                colName : col.getName(),
                name    : javaName(col.getName(), false),
                type    : typeStr,
                commoent: col.getComment(),
                annos   : "\t@Column(name = \"" + col.getName() + "\" )"]
        if ("id".equals(Case.LOWER.apply(col.getName())))
            comm.annos += ["@Id"]
        fields += [comm]
    }
}

// 這裏是處理數據庫表前綴的方法，這裏處理的是t_xxx命名的表
// 已經修改爲使用javaName, 如果有需要可以在def className = javaName(table.getName(), true)中修改爲javaClassName
// 處理類名（這裏是因爲我的表都是以t_命名的，所以需要處理去掉生成類名時的開頭的T，
// 如果你不需要去掉表的前綴，那麼請查找用到了 javaClassName這個方法的地方修改爲 javaName 即可）
def javaClassName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    // 去除開頭的T  http://developer.51cto.com/art/200906/129168.htm
    s = s[1..s.size() - 1]
    capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def javaName(str, capitalize) {
//    def s = str.split(/(?<=[^\p{IsLetter}])/).collect { Case.LOWER.apply(it).capitalize() }
//            .join("").replaceAll(/[^\p{javaJavaIdentifierPart}]/, "_")
//    capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}

static String changeStyle(String str, boolean toCamel) {
    if (!str || str.size() <= 1)
        return str

    if (toCamel) {
        String r = str.toLowerCase().split('_').collect { cc -> Case.LOWER.apply(cc).capitalize() }.join('')
        return r[0].toLowerCase() + r[1..-1]
    } else {
        str = str[0].toLowerCase() + str[1..-1]
        return str.collect { cc -> ((char) cc).isUpperCase() ? '_' + cc.toLowerCase() : cc }.join('')
    }
}

//生成序列化的serialVersionUID 
static String genSerialID() {
    return "\tprivate static final long serialVersionUID =  " + Math.abs(new Random().nextLong()) + "L;"
}

腳本里面的註釋相信已經可以幫你進行自定義自己的腳本了，在自定義的時候，需要注意有個方法generate，這裏面有個生成文件的方法，裏面的參數需要保持一致，在我第一次修改整合幾個不同的模板的時候，就因爲這個報錯了，後來檢查了半天才發現這個問題。

腳本修改完了之後，就是自動生成了，還是打開之前的DataSource，右鍵需要生成的表，開始生成。由於上面腳本中packageName是默認的，這裏會有彈窗，需要我們選擇生成實體類的位置。


修改之後，再次生成，可以直接覆蓋掉原來生成的文件，這點還是蠻方便的。腳本生成的實體類如下：

package com.lin.model.jpaDemo.entity;

import javax.persistence.Column;
import javax.persistence.Entity;
import javax.persistence.Table;
import javax.persistence.Id;
import javax.persistence.GeneratedValue;
import java.io.Serializable;

/**
 * @Description  
 * @Author  linmengmeng
 * @Date 2019-09-28 11:06:00 
 */

@Entity
@Table ( name ="user" , schema = "")
public class User  implements Serializable {

	private static final long serialVersionUID =  7415787526169091091L;

	/**
	 * 主鍵ID
	 */
	@Id
   	@Column(name = "id" )
	private Long id;

	/**
	 * 姓名
	 */
   	@Column(name = "name" )
	private String name;

	/**
	 * 年齡
	 */
   	@Column(name = "age" )
	private Long age;

	/**
	 * 郵箱
	 */
   	@Column(name = "email" )
	private String email;

	public Long getId() {
		return this.id;
	}

	public void setId(Long id) {
		this.id = id;
	}

	public String getName() {
		return this.name;
	}

	public void setName(String name) {
		this.name = name;
	}

	public Long getAge() {
		return this.age;
	}

	public void setAge(Long age) {
		this.age = age;
	}

	public String getEmail() {
		return this.email;
	}

	public void setEmail(String email) {
		this.email = email;
	}

	@Override
	public String toString() {
		return "{" +
					"id='" + id + '\'' +
					"name='" + name + '\'' +
					"age='" + age + '\'' +
					"email='" + email + '\'' +
				'}';
	}

}