快速切換jdk1.6、jdk1.7與jdk1.8的bat

1. 新建一個bat文件把下面這段粘貼進去
2. jdk的路徑自己改成自己電腦的路徑
3. 以管理員方試運行
4. 選擇與目標JDK版本對應的菜單
5. 完成切換

@echo OFF 
rem 修改背景/字體顏色爲黑/綠 
color 0A 

rem 自動設置JDK環境變量，本程序不會對 [系統環境變量] 造成破環！不需要重啓！！ 
rem 沒有%%JAVA_HOME%%變量值則設置%%JAVA_HOME%%，%%CLASSPATH%%,補充%%PATH%% 
rem 有%%JAVA_HOME%%變量值則設置過；會僅更新%%JAVA_HOME%% 
echo + 自動設置JDK環境變量，不需要重啓！！ 
echo + 首次使用注意： 
echo + 1.自行修改31,32行 
echo + [當前用戶環境變量] 
echo + JAVA_HOME: "%JAVA_HOME%" 
echo + CLASSPATH: "%CLASSPATH%" 
echo + PATH: "%PATH%" 

:menu 
echo. 
echo. 
echo ----------------------------------------------------- 
echo + 菜單 ............................[快捷鍵] + 
echo + 1 .設置環境變量爲JDK1.6 ..............[1] + 
echo + 2 .設置環境變量爲JDK1.7 ..............[2] + 
echo + 3 .設置環境變量爲JDK1.8 ..............[3] +
echo + m .返回顯示菜單 ......................[m] + 
echo + q .退出...............................[q] + 
echo ----------------------------------------------------- 
echo. 
echo. 

@rem 用戶設置jdk路徑 

set java6path=C:\Program Files\Java\jdk1.6.0
set java7path=C:\Program Files\Java\jdk1.7.0
set java8path=C:\Program Files\Java\jdk1.8.0

if "%JAVA_HOME%" == "" ( 
    echo 沒有檢測到%%JAVA_HOME%% 
    goto noJavaHome 
) else ( 
  echo 已檢測到%%JAVA_HOME%% 
  goto hasJavaHome 
) 

:noJavaHome 

set /p off=請輸入對應的快捷鍵1/2/3/m/q並按回車: 
if /i "%off%"=="1" goto noJavaHome_setJDK1.6 
if /i "%off%"=="2" goto noJavaHome_setJDK1.7 
if /i "%off%"=="3" goto noJavaHome_setJDK1.8 
if /i "%off%"=="m" goto menu 
if /i "%off%"=="q" exit 
echo 無效輸入。 
goto menu 

:hasJavaHome 

set /p off=請輸入對應的快捷鍵1/2/3/m/q並按回車: 
if /i "%off%"=="1" goto hasJavaHome_setJDK1.6 
if /i "%off%"=="2" goto hasJavaHome_setJDK1.7 
if /i "%off%"=="3" goto hasJavaHome_setJDK1.8 
if /i "%off%"=="m" goto menu 
if /i "%off%"=="q" exit 
echo 無效輸入。 
goto menu 

:noJavaHome_setJDK1.6 
echo + 1 .沒有檢測到%%JAVA_HOME%%；設置環境變量爲JDK1.6 + 
wmic ENVIRONMENT create name="JAVA_HOME",username="%UserName%",VariableValue="%java6path%" 
wmic ENVIRONMENT create name="CLASSPATH",username="%UserName%",VariableValue=".;%%JAVA_HOME%%\lib\tools.jar;%%JAVA_HOME%%\lib\dt.jar;"
wmic ENVIRONMENT create name="Path",username="%UserName%",VariableValue="%%JAVA_HOME%%\bin"
echo + 設置完畢，任意鍵退出 + 
goto anyKeyToExit 
:noJavaHome_setJDK1.7 
echo + 2 .沒有檢測到%%JAVA_HOME%%；設置環境變量爲JDK1.7 + 
wmic ENVIRONMENT create name="JAVA_HOME",username="%UserName%",VariableValue="%java7path%" 
wmic ENVIRONMENT create name="CLASSPATH",username="%UserName%",VariableValue=".;%%JAVA_HOME%%\lib\tools.jar;%%JAVA_HOME%%\lib\dt.jar;"
wmic ENVIRONMENT create name="Path",username="%UserName%",VariableValue="%%JAVA_HOME%%\bin"
echo + 設置完畢，任意鍵退出 + 
goto anyKeyToExit 
:noJavaHome_setJDK1.8 
echo + 3 .沒有檢測到%%JAVA_HOME%%；設置環境變量爲JDk1.8 + 
wmic ENVIRONMENT create name="JAVA_HOME",username="%UserName%",VariableValue="%java8path%" 
wmic ENVIRONMENT create name="CLASSPATH",username="%UserName%",VariableValue=".;%%JAVA_HOME%%\lib\tools.jar;%%JAVA_HOME%%\lib\dt.jar;"
wmic ENVIRONMENT create name="Path",username="%UserName%",VariableValue="%%JAVA_HOME%%\bin"
echo + 設置完畢，任意鍵退出 + 
goto anyKeyToExit 


:hasJavaHome_setJDK1.6 
echo + 1 .已檢測到%%JAVA_HOME%%；設置環境變量爲JDK1.6 + 
echo "%java6path%" 
wmic ENVIRONMENT where "name='JAVA_HOME'" set VariableValue="%java6path%" 
echo + 設置完畢，任意鍵退出 + 
goto anyKeyToExit 
:hasJavaHome_setJDK1.7 
echo "%java7path%" 
echo + 2 .已檢測到%%JAVA_HOME%%；設置環境變量爲JDK1.7 + 
wmic ENVIRONMENT where "name='JAVA_HOME'" set VariableValue="%java7path%" 
echo + 設置完畢，任意鍵退出 + 
goto anyKeyToExit 
:hasJavaHome_setJDK1.8 
echo "%java8path%" 
echo + 3 .已檢測到%%JAVA_HOME%%；設置環境變量爲JDk1.8 + 
wmic ENVIRONMENT where "name='JAVA_HOME'" set VariableValue="%java8path%" 
echo + 設置完畢，任意鍵退出 + 
goto anyKeyToExit 

:anyKeyToExit 

pause