![]()
.版本 2
.支持庫 HtmlView
.支持庫 iext
.支持庫 xplib
.程序集 窗口程序集1
.子程序 __啓動窗口_尺寸被改變
超文本瀏覽框1.移動 (, , 取用戶區寬度 (), 取用戶區高度 () － 超文本瀏覽框1.頂邊 － 狀態條1.高度)
編輯框1.移動 (, , 取用戶區寬度 () － 編輯框1.左邊 － 按鈕1.寬度 － 25, )
按鈕1.左邊 ＝ 編輯框1.左邊 ＋ 編輯框1.寬度 ＋ 10
.如果 (編輯框1.寬度 ＜ 200)
編輯框1.寬度 ＝ 200
按鈕1.可視 ＝ 假
.否則
按鈕1.可視 ＝ 真
.如果結束
.子程序 __啓動窗口_創建完畢
XP風格 (1)
編輯框1.獲取焦點 ()
超文本瀏覽框1.離線瀏覽 ＝ 假
.子程序 _工具條1_被下拉
.參數 按鈕索引, 整數型
.參數 下拉橫座標, 整數型
.參數 下拉縱座標, 整數型
彈出菜單 (字體, 下拉橫座標, 下拉縱座標)
.子程序 _工具條1_被單擊
.參數 按鈕索引, 整數型
.判斷開始 (按鈕索引 ＝ 0)
超文本瀏覽框1.執行命令 (#到首頁)
.判斷 (按鈕索引 ＝ 1)
超文本瀏覽框1.執行命令 (#後退)
.判斷 (按鈕索引 ＝ 2)
超文本瀏覽框1.執行命令 (#前進)
.判斷 (按鈕索引 ＝ 3)
超文本瀏覽框1.執行命令 (#停止)
.判斷 (按鈕索引 ＝ 4)
超文本瀏覽框1.執行命令 (#刷新)
.默認
.判斷結束
.子程序 _超文本瀏覽框1_即將跳轉, 邏輯型
狀態條1.置文本 (1, “正在轉到:” ＋ 超文本瀏覽框1.地址)
.子程序 _超文本瀏覽框1_載入進度改變
.參數 進度百分比, 整數型
狀態條1.置文本 (1, “已載入” ＋ 到文本 (進度百分比) ＋ “%”)
.子程序 _超文本瀏覽框1_已就緒
狀態條1.置文本 (1, “就緒”)
編輯框1.內容 ＝ 超文本瀏覽框1.地址
.子程序 _超文本瀏覽框1_標題被改變
標題 ＝ 超文本瀏覽框1.標題 ＋ “ - 雁子瀏覽器”
.子程序 _超文本瀏覽框1_命令狀態被改變
.參數 命令, 整數型
.參數 是否被允許, 邏輯型
.如果 (是否被允許 ＝ 假)
.判斷開始 (命令 ＝ #前進)
工具條1.加入狀態 (2, #禁止)
前進.禁止 ＝ 真
.判斷 (命令 ＝ #後退)
工具條1.加入狀態 (1, #禁止)
後退.禁止 ＝ 真
.默認
.判斷結束
.否則
.判斷開始 (命令 ＝ #前進)
工具條1.去除狀態 (2, #禁止)
前進.禁止 ＝ 假
.判斷 (命令 ＝ #後退)
工具條1.去除狀態 (1, #禁止)
後退.禁止 ＝ 假
.默認
.判斷結束
.如果結束
.子程序 _超文本瀏覽框1_字符輸入, 整數型
.參數 字符代碼, 整數型
.如果真 (字符代碼 ＝ #回車鍵)
超文本瀏覽框1.地址 ＝ 編輯框1.內容
.如果真結束
.子程序 _在新窗口中打開_被選擇
.局部變量 局_變量1, 文本型
.如果真 (輸入框 (“輸入”, , , 局_變量1, ))
超文本瀏覽框1.地址 ＝ 局_變量1
.如果真結束
.子程序 _另存爲_被選擇
超文本瀏覽框1.執行命令 (#另存爲)
.子程序 _打印_被選擇
超文本瀏覽框1.執行命令 (#打印)
.子程序 _打印預覽_被選擇
超文本瀏覽框1.執行命令 (#打印預覽)
.子程序 _頁面設置_被選擇
超文本瀏覽框1.執行命令 (#頁面設置)
.子程序 _退出_被選擇
結束 ()
.子程序 _前進_被選擇
超文本瀏覽框1.執行命令 (#前進)
.子程序 _後退_被選擇
超文本瀏覽框1.執行命令 (#後退)
.子程序 _到首頁_被選擇
超文本瀏覽框1.執行命令 (#到首頁)
.子程序 _到搜索頁_被選擇
超文本瀏覽框1.執行命令 (#到搜索頁)
.子程序 _刷新_被選擇
超文本瀏覽框1.執行命令 (#刷新)
.子程序 _停止_被選擇
超文本瀏覽框1.執行命令 (#停止)
.子程序 _最大_被選擇
選擇字體大小 (4)
.子程序 選擇字體大小
.參數 字體大小, 整數型
.局部變量 字體菜單項, 菜單, , "5"
.局部變量 容器1, 整數型
字體菜單項 [1] ＝ 最小
字體菜單項 [2] ＝ 較小
字體菜單項 [3] ＝ 中等
字體菜單項 [4] ＝ 較大
字體菜單項 [5] ＝ 最大
.計次循環首 (5, 容器1)
字體菜單項 [容器1].選中 ＝ 假
.計次循環尾 ()
字體菜單項 [字體大小 ＋ 1].選中 ＝ 真
超文本瀏覽框1.字體大小 ＝ 字體大小
.子程序 _較大_被選擇
選擇字體大小 (3)
.子程序 _中等_被選擇
選擇字體大小 (2)
.子程序 _較小_被選擇
選擇字體大小 (1)
.子程序 _最小_被選擇
選擇字體大小 (0)
.子程序 _關於易瀏覽器_被選擇
' 信息框 (“簡單瀏覽器”, 0, )
API_ShellAbout (取窗口句柄 (), “易瀏覽器”, “@雁子”, 0)
.子程序 _按鈕1_被單擊
超文本瀏覽框1.跳轉 (編輯框1.內容, , )
工程文件：http://www.kuaipan.cn/file/id_30136668824535061.htm
