Linux_保護模式下尋址

保護模式下尋址（易懂）

：

網上看到的一強帖，不轉不行了，牛人啊，把這段代碼拿捏的相當到位 括號中是我的加註

段機制輕鬆體驗

[內存尋址]
實模式下的內存尋址：
讓我們首先來回顧實模式下的尋址方式
段首地址×16＋偏移量 ＝ 物理地址
爲什麼要×16？因爲在8086CPU中，地址線是20位，但寄存器是16位的，最高尋址64KB，它無法尋址到1M內存。於是，Intel設計了這種尋 址方式，先縮小4位成16位放入到段寄存器，用到時候，再將其擴大到20位，這也造成了段的首地址必須是16的倍數的限制。

保護模式下分段機制的內存尋址：
保護模式下 分段機制是利用一個稱作段選擇符的偏移量，從而到描述符表找到需要的段描述符，而這個段描述符中就存放着真正的段的物理首地址，再加上偏移量

一段話，出現了三個新名詞：
1、段選擇子 2、描述符表   3、段描述符

我們現在可以這樣來理解這段話： 有一個結構體類型，它有三個成員變量：段物理首地址 段界限 段屬性

內存中，維護一個該結構體類型的是一個數組。而分段機制就是利用一個索引，找到該數組對應的結構體，從而得到段的物理首地址，然後加上偏移量，得到真正的物理地址。

公式：xxxx:yyyyyyyy

其中，xxxx也就是索引，yyyyyyyy是偏移量（因爲32位寄存器，所以8個16進制）xxxx存放在段寄存器中。

現在，我們來到過來分析一下那三個新名詞。段描述符，一個結構體，它有三個成員變量：1、段物理首地址   2、段界限   3、段屬性

我們再來重溫一遍 描述符表，也就是一個數組，什麼樣的數組呢？是一個段描述符組成的數組。

接下來看看段選擇子：段選擇子，也就是數組的索引，但這時候的索引不在是高級語言中數組的下標，而是我們將要找的那個段描述符相對於數組首地址（也就是全局描述表的首地址）偏移位置。

就這麼簡單，如圖：

圖中，通過Selector（段選擇子）找到存儲在Descriptor Table（描述符表）中某個Descriptor（段描述符），該段描述符中存放有該段的物理首地址，所以就可以找到內存中真正的物理段首地址Segment
Offset（偏移量）：就是相對該段的偏移量 物理首地址 ＋ 偏移量 就得到了物理地址    本圖就是DATA
但這時，心細的朋友就發現了一個GDTR這個傢伙還沒有提到!
我們來看一下什麼是GDTR ？ Global Descriptor Table Register（全局描述符表寄存器）但是這個寄存器有什麼用呢 ？ 大家想一下，段描述符表現在是存放在內存中，那CPU是如何知道它在哪裏呢？所以，Intel 公司設計了一個全局描述符表寄存器，專門用來存放段描述符表的首地址，以便找到內存中段描述符表。這時，段描述符表地址被存到GDTR寄存器中了。

好了，分析就到這，我們來看一下正式的定義：
當x86 CPU 工作在保護模式時，可以使用全部32根地址線訪問4GB的內存，因爲80386的所有通用寄存器都是32位的，所以用任何一個通用寄存器來間接尋址，不用分段就可以訪問4G空間中任意的內存地址。也就是說我們直接可以用Eip寄存器就可以找到茫茫內存裏面所有的值！ 但這並不意味着，此時段寄存器就不再有用了[其實 還有部分原因是要與8086兼容] 。實際上，段寄存器更加有用了，雖然再尋址上沒有分段的限制了，但在保護模式下，一個地址空間是否可以被寫入，可以被多少優先級的代碼寫入，是不是允許執行等等涉及保護的問題就出來了。[想 想吧，單單就是靠eip找到所有內存的值顯然不夠的，醒醒吧，我們到了80386時代了，我們需要保護模式，要指示出來那些內存段是操作系統核心用的，那 些是你打遊戲時用的，打遊戲時的cpu不能訪問到操作系統核心所用的內存段。我們需要分出"級別"來] 。 要解決這些問題，必須對一個地址空間定義一些安全上的屬性。段寄存器這時就派上了用場。但是設計屬性和保護模式下段的參數，要表示的信息太多了，要用64 位長的數據才能表示。我們把着64位的屬性數據叫做段描述符，上面說過，它包含3個變量：
段物理首地址、段界限、段屬性 80386的段寄存器是16位（注意：通用寄存器在保護模式下都是32位，但段寄存器沒有被改變，比如cs還是16位的，16位的段寄存器怎麼可能裝下一個64位的段描述符）的，無法放下保護模式下64位的段描述符。如何解決這個問題呢？ 方法是把所 有段的段描述符順序存放在內存中的指定位置，組成一個段描述符表（Descriptor Table）；而段寄存器中的16位用來做索引信息，這時，段寄存器中的信息不再是段地址了，而是段選擇子（Selector）。可以通過它在段描述符表 中“選擇”一個項目已得到段的全部信息。 也就是說我們在另一個地方把段描述符放好，然後通過選擇子來找到這個段描述符。

那麼段描述符表存放在哪裏呢？80386引入了兩個新的寄存器來管理段描述符，就是GDTR和LDTR，（LDTR大家先忘記它，隨着學習的深入，我們會在以後學習）。

這樣，用以下幾步來總體體驗下保護模式下尋址的機制
1、段寄存器中存放段選擇子Selector
2、GDTR中存放着段描述符表的首地址
3、通過選擇子根據GDTR中的首地址，就能找到對應的段描述符
4、段描述符中有段的物理首地址，就得到段在內存中的首地址
5、加上偏移量，就找到在這個段中存放的數據的真正物理地址。

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝

好的，那我們開始編碼，看看如何實現先前描述的內容

首先，既然我們需要一個數組，全局描述符表，那我們就定義一塊連續的結構體：
[SECTION .gdt]    ;爲了代碼可讀性，我們將這個數組放到一個節中
；由一塊連續的地址組成的，不就是一個數組嗎？看下面代碼，^_^

段基地址    段界限 段屬性
GDT_BEGIN: Descriptor 0,       0,    0  
GDT_CODE32: Descriptor 0,    0,    DA_C

;上面，我定義了二個連續地址的結構體，大家先認爲Descriptor就是一個結構體類型，我們會在以後詳細講述
；第一個結構體，全部是0，是爲了遵循Interl規範，先記得就OK
；第二個定義了一個代碼段，段基地址和段界限我們暫且還不知道，先初始化爲0，但是因爲是個代碼段，代碼段具備執行的屬性，那麼DA_C就代表是一個可執行代碼段，DA_C是一個預先定義好的常量，我們會在詳細講解段描述符中講解。

我們繼續來實現，那麼下面，我們就需要設計段選擇子了，因爲上面代碼已經包含了段描述符和全局描述符表
還記得選擇子是個什麼東西嗎 ？
段選擇子：      也就是數組的索引，但這時候的索引不在是高級語言中數組的下標，而是我們將要找的那個段描述符相對於數組首地址（也就是全局描述表的首地址）偏移位置。
看我代碼怎麼實現，包含以上代碼不再說明:
[SECTION .gdt]
GDT_BEGIN: Descriptor 0, 0, 0
GDT_CODE32: Descriptor 0, 0, DA_C

;下面是定義代碼段選擇子，它就是相對數組首地址的偏移量
SelectorCode32 equ    GDT_CODE32 - GDT_BEGIN
;因爲第一個段描述符，不被使用，所以就不比設置段選擇子了。
＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝

偏移地址：
注意一點，我們在程序中使用的都是偏移地址，相對於段的偏移地址，用上面的例子來說，象 GDT_CODE32 GDT_BEGIN 這些結構體的首地址都是相對於數據段的偏移量。什麼意思呢 ？
因爲我們的程序到底加載到內存的哪個地方是不固定，不知道的，只需使用偏移地址操作就行了，如：
SelectorCode32 ，它本身就是一個偏移地址

但是SelectorCode32    equ GDT_CODE32 - GDT_BEGIN

怎麼解釋呢 ？ 
GDT_CODE32是相對於數據段的偏移量，
GDT_BEGIN也是相對於數據段的偏移量，雖然它是數組的首地址，說的羅索一些，GDT_BEGIN是數組的首地址，但是它是相對於數據段的偏移量
那麼兩個偏移量相減就是GDT_CODE32 相對於GDT_BEGIN的偏移量

所以，我們要時時刻刻記得，在程序中，我們永遠使用的是偏移量，因爲我們不知道程序將要被加載內存那塊地方。

好了，基礎也學的差不多了，下面我們要自己動手寫一段程序，實現實模式到保護模式之間的跳轉
=====================================================================
;實現從實模式到保護模式之間的跳轉
；參考：《自己動手寫操作系統》
----------------------------------------------------------------------
%include "pm.inc"

org 0100h
jmp LABEL_BEGIN

[SECTION .gdt]
GDT_BEGIN: Descriptor 0,    0,     0
GDT_CODE32: Descriptor 0,    LenOfCode32 - 1, DA_C + DA_32
GDT_VIDEO: Descriptor 0B8000H, 0FFFFH,     DA_DRW

GdtLen    equ    $ - GDT_BEGIN
GdtPtr    dw    GdtLen - 1
      dd    0

;定義段選擇子
SelectorCode32 equ    GDT_CODE32 - GDT_BEGIN
SelectorVideo equ    GDT_VIDEO - GDT_BEGIN

[SECTION .main]
[BITS 16]
LABEL_BEGIN:
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax

;初始化32位代碼段選擇子
;我們可以在實模式下通過段寄存器×16 ＋ 偏移兩 得到物理地址，
;那麼，我們就可以將這個物理地址放到段描述符中，以供保護模式下使用，
;因爲保護模式下只能通過段選擇子 ＋ 偏移量

xor eax, eax
mov ax, cs
shl eax, 4
add eax, LABEL_CODE32
mov word [GDT_CODE32 + 2],ax
shr eax, 16
mov byte [GDT_CODE32 + 4],al
mov byte [GDT_CODE32 + 7],ah

;得到段描述符表的物理地址，並將其放到GdtPtr中
xor eax, eax
mov ax, ds
shl eax, 4
add eax, GDT_BEGIN
mov dword [GdtPtr + 2],eax

;加載到gdtr,因爲現在段描述符表在內存中，我們必須要讓CPU知道段描述符    表在哪個位置
;通過使用lgdtr就可以將源加載到gdtr寄存器中
lgdt [GdtPtr]

;關中斷
cli

;打開A20線
in al, 92h
or al, 00000010b
out 92h, al

;準備切換到保護模式，設置PE爲1
mov eax, cr0
or eax, 1
mov cr0, eax

;現在已經處在保護模式分段機制下，所以尋址必須使用段選擇子：偏移量來    尋址

;跳轉到32位代碼段中
;因爲此時偏移量位32位，所以必須dword告訴編譯器，不然，編譯器將階段    成16位
jmp dword SelectorCode32:0;跳轉到32位代碼段第一條指令開始執行

[SECTION .code32]
[BITS 32]
LABEL_CODE32:
mov ax, SelectorVideo
mov es, ax

xor edi, edi
mov edi, (80 * 10 + 10)

mov ah, 0ch
mov al, 'G'

mov [es:edi],ax

jmp $
LenOfCode32 equ $ - LABEL_CODE32

這段代碼的大概意思是：
先在16位代碼段，實模式下運行，在實模式下，通過段寄存器×16+偏移量得到32位代碼的真正物理首地址，並將放入到段描述符表中，以供在保護模式下使 用，上面說過了，保護模式下尋址，是通過段選擇子，段描述符表，段描述符一起工作尋址的。所以在實模式下所做的工作就是初始化段描述符表裏的所有段描述 符。
我們來看一下段描述符表，它有3個段：
GDT_BEGIN
GDT_CODE32
GDT_VIDEO

GDT_BEGIN,遵循Intel公司規定，全部置0
GDT_CODE32,32位代碼段描述符，供保護模式下使用
GDT_VIDEO,顯存段首地址，我們知道，顯存首地址是0B8000H.

回想一下，我們在實模式下往顯示器上輸出文字時，我們設置段寄存器爲
0B800h,（注意後面比真正物理地址少一個0）。
而我們現在在保護模式下訪問顯存，那麼0B8000h就可以直接放到段描述符中即可。因爲段描述符中存放的是段的真正的物理地址。

下面我們來逐行分析該代碼
org    0100h
這句話告訴加載器，將這段程序加載到偏移段首地址0100h處，即：偏移256字節處，爲什麼要加載到偏移256個字節處呢 ？這是因爲，在DOS中，需要留下256個字節和DOS系統進行通信。
jmp    LABEL_BEGIN
執行這句話就跳轉到LABEL_BEGIN處開始執行。好，我們看一下LABEL_BEGIN在那塊，也就是16位代碼段

[SECTION .main]
[BITS 16]
LABEL_BEGIN: 
這樣程序就從.main節的第一段代碼開始執行。我們看一下上面的代碼，[BITS 16]告訴編譯器，這是一個16位代碼段，所使用的寄存器都是16位寄存器。該代碼段初始化所有段描述符表中的段物理首地址

首先在實模式下計算出32位代碼段的物理首地址
對照    段值 × 16 ＋ 偏移量    ＝ 物理地址

1    mov ax,    cs
2    shl eax, 4    ;向左移動4位，不就是×16嗎？呵呵
；到現在爲止，eax就是代碼段的物理首地址了，那麼。。。看
3    add eax, LABEL_CODE32
;爲eax （代碼段首地址）加上 LABEL_CODE32偏移量，得到的不就是LABEL_CODE32的真正物理地址了嗎 ？LABEL_CODE32在程序中，不就是32位代碼段的首地址嗎 ？

上面說過，代碼中，使用的變量，或者標籤 都是相對程序物理首地址的偏移量。

OK，現在我們已經知道了32位代碼段的物理首地址，那麼將eax放入到段描述符中就行了
我們先假設Descriptor就是一個結構體類型，（實際它是一個宏定義的數據結構，爲了不影響整體思路，我們放到以後講）
看一下這個Descriptor段描述符的內存模型：

; 高地址………………………………………………………………………低地址

; |     7     |     6     |     5     |     4     |     3     |     2     |     1     |     0      |
共 8 字節
; |--------========--------========--------========--------========|
; ┏━━━┳━━━━━━━┳━━━━━━━━━━━┳━━━━━━━┓
; ┃31..24 ┃     段屬性            ┃       段基址(23..0)                 ┃ 段界限(15..0)     ┃
; ┃           ┃                               ┃                                                ┃                              ┃
; ┃ 基址2 ┃                               ┃基址1b│     基址1a              ┃     段界限1        ┃
; ┣━━━╋━━━┳━━━╋━━━━━━━━━━━╋━━━━━━━┫
; ┃      %6 ┃    %5    ┃    %4    ┃    %3    ┃       %2                 ┃         %1                ┃
; ┗━━━┻━━━┻━━━┻━━━┻━━━━━━━┻━━━━━━━┛

(刺蝟: 這幅圖調整了很多次還是亂的，麻煩各位看官直接參照《自己動手寫操作系統》P43 圖3-2 )

由於歷史原因，段描述符的內存排列不是按照 段基地址 段界限 段屬性 這樣的來排列的，所以我們現在要想一種辦法，把eax裏所存放的物理首地址拆開，分別放到2,3,4,7字節處
那麼很顯然，我們可以將eax寄存器中的ax先放到2,3字節處
mov    word [GDT_CODE32 + 2],ax
因爲在偏移2個字節處，所以，首地址 + 2,才能定位到下標爲2的字節開頭處
而，word 告訴編譯器，我要一次訪問2個字節的內存

好，簡單的搞定了，那麼再看，我們現在要將eax高16字節分別放到下標爲4,7字節處。
雖然eax的ax代表低16位，但是Intel並沒有給高位一個名字定義，（不會是high ax，呵呵），所以，我們沒有辦法去訪問高位。但是我們可以將高16位放到低16位中，因爲這時，低16位我們已經不關心它的值了。
好，看代碼
shr    eax,    16
這句代碼就將eax向右移動16位，低位被拋棄，高位變成了低位。呵呵。。。

現在好辦了，低16位又可以分爲al,和 ah，那麼現在我們就將al放到4位置，ah放到7位置吧
mov    byte [GDT_CODE32 + 4], AL
mov    byte [GDT_CODE32 + 7], AH
不用我再解釋這段代碼了，自己去分析爲什麼吧。。。。

好了，32位代碼段描述符設置好了，其界限設置看代碼吧，爲什麼要那樣設置，很簡單的，界限 ＝ 長度 － 1，段屬性:
DA_C: 98h      可執行
DA_32: 4000h 32位代碼段
是個常量，換算成二進制位，對照段描述符屬性位置去看吧，參考任意一本保護模式書。

段描述符設置好了，但是，先段描述符表，還在內存中，我們必須想辦法放到寄存器中，這時，就用到了gdtr(Golbal Descriptor Table Register)，使用一條指令
lgdtr [GdtPtr]

就可以將GdtPtr加載到gdtr中
而gdtr的內存模型是：

-------------------------------------------------------
高字節                                   低字節

-------------------------------------------------------

但GdtPtr是什麼呢 ？
就是我們定義的和這個寄存器內存模型一摸一樣的結構體:
GdtLen    equ    $ - LABEL_BEGIN
GdtPtr    dw    GdtLen - 1     ；界限
dd    0       ；真正物理地址
那現在我們就要計算GdtPtr第二個字節 也就是真正物理地址了
xor eax, eax
mov ax,    ds
shl eax, 4
add eax, GDT_BEGIN
mov dword [GdtPtr + 2],eax
自己分析吧，和計算32位段首地址基本一樣的，
搞定後，使用lgdt [GdtPtr]就將此加載到寄存器GDTR中了

然後關中斷
cli    實模式下的中斷和保護模式下的中斷處理不一樣，那就關吧，規矩
開啓A20線
in al, 92h
or al, 00000010b
out 92h, al
如果不開啓A20線，就無辦法訪問1M之上的內存，沒辦法，開啓吧，規矩，想知道歷史了，去查吧

然後設置CR0的PE位
mov eax, cr0
or eax, 1
mov cr0, eax
這個簡單說一下，以後再詳細
CR0也是一個寄存器，其中有個PE位，如果爲0，就說明爲實模式，
如果置1，說明爲保護模式。現在我們要進入保護模式下工作，那麼就要設置PE爲1。

好了，看一下這個main節中的最後一個代碼
jmp    dword SelectorCode32 : 0
哈哈，現在已經再保護模式下了，當然要使用段選擇子 ＋ 偏移量來尋址啊，這樣不就是尋址到了32位代碼段中去了嗎，偏移量爲0不就說明從第一個代碼開始執行。
不是嗎 ？呵呵，那dword了？
因爲現在的代碼段是16位，編譯器只能將它編譯位16位，但處於保護模式下，它的偏移量應該是32位，所以，要顯示告訴編譯器，我這裏使用的是32位，把我這塊給編譯成32位的！！！
如果不加dword，
jmp    SelectorCode32:0
這句話不會出什麼問題，16位的0是0，32位的0還是0，但如果這樣呢？：
jmp    SelectorCode32:0x12345678
跳轉到偏移0x12345678中，這時就錯了
如果不將dword,編譯器就將該地址截斷成16位，取低位，變成了0x5678
你說對嗎 ？哈哈
所以我們必須這樣做：
jmp    dword SelectorCodde32:0x12345678

OKEY,我們繼續追擊，執行完上面那個跳轉後，
代碼就跳到了32位代碼段的中，開始執行第一條指令
mov ax, SelectorVideo
再看
mov es,ax
呵呵，實模式下，放的是16位的段值，而現在呢，不就是要將段選擇子放到段寄存器裏嗎 ？然後通過段選擇子（偏移量）找到描述符表中對應的段描述符的嗎 ！！！！
繼續看下面代碼
xor edi, edi
mov edi, (80 * 10 + 10)

mov ah, 0ch
mov al, 'G'
跟實模式下差不多，設置目標10行10列
設置現實字符：G
mov [es:edi],ax
也和實模式下一樣，
只不過實模式是這樣來尋址 ：
es×16 ＋ edi
而保護模式下呢
es是一個偏移，根據這個偏移找到段描述符表中的對應顯存段，然後這個顯存段裏存放的就是0B8000h，然後在加上偏移 不就的了嗎！！！
哈哈 。。。。程序分析完畢，細節之處，自己體會去

總結：
1. 注意程序中使用的全部是偏移地址。注意兩種偏移地址

A 對於程序的起始地址來說，所有變量和標籤都是相對於整個程序的偏移量
B 對於段中定義的代碼，有兩種偏移：
相對於程序起始地址的偏移
相對於段標籤的偏移。

2.不管是實模式下的物理地址，還是保護模式下的物理地址，反正他們都是物理地址，呵呵，實模式下求的物理地址，也能在保護模式下使用，只是他們不同的是，如何尋址的方式不一樣。

3.一個程序中可以包含多個不同位的段，32位或者16位，他們之間也可以互相跳轉，只是32位段用的是32位寄存器，16位代碼段用的是16位寄存器，如果要在16位段下使用32位寄存器，必須象高級語言中強制類型轉換一樣，顯示的定義 dword