UCOS-II移植ARM的讀書筆記（12.25）

 __OSStartHighRdy
        MSR     CPSR_c, #(NoInt | SYS32Mode)    ;調整到管理模式
                                                ;告訴uC/OS-II自身已經運行
        LDR     R4, =OSRunning
        MOV     R5, #1
        STRB    R5, [R4]   ;標記多任務運行標記爲真

        BL      OSTaskSwHook                    ;調用鉤子函數，可以運行用戶自定義的函數

        LDR     R6, =OSTCBHighRdy    ;R6存有最高優先級的就緒任務的控制塊地址
        LDR     R6, [R6]
        B       OSIntCtxSw_1     ;轉到前面編寫的中斷返回函數塊的任務跳轉部分的代碼，因爲這兩個函數都要用到這部分代碼，進入這段代碼之前高優先級的就緒任務的任務控制快地址存在R6中。

        AREA    SWIStacks, DATA, NOINIT,ALIGN=2
SvcStackSpace      SPACE   SVC_STACK_LEGTH * 4  ;管理模式堆棧空間 

OSIntCtxSw_1的代碼：

OSIntCtxSw_1
                                                    ;獲取新任務堆棧指針
        LDR     R4, [R6] ;任務控制塊的堆棧指針放在R6中，現在放在R4中
        ADD     SP, R4, #68                         ;17寄存器CPSR,OsEnterSum,R0-R12,LR,SP
        LDR     LR, [SP, #-8]
        MSR     CPSR_c, #(NoInt | SVC32Mode)        ;進入管理模式
        MOV     SP, R4                              ;設置堆棧指針，R4存有沒有改動過的堆棧指針

        LDMFD   SP!, {R4, R5}                       ;CPSR,OsEnterSum
                                                    ;恢復新任務的OsEnterSum
        LDR     R3, =OsEnterSum
        STR     R4, [R3]
   
        MSR     SPSR_cxsf, R5                       ;恢復CPSR
        LDMFD   SP!, {R0-R12, LR, PC }^             ;運行新任務，恢復現場，異常處理返回；中斷返回指令的寄存器列表其中必須包括PC後的^符號，表示這是一條特殊形式的指令。這條指令在從存儲器中裝載PC的同時，CPSR也得到恢復。這裏使用的堆棧指針SP是屬於異常模式的寄存器，每個異常模式有自己的堆棧指針。

 

 

 

SoftwareInterrupt
        LDR     SP, StackSvc            ; 重新設置堆棧指針
        STMFD   SP!, {R0-R3, R12, LR}     ;保存寄存器
        MOV     R1, SP                  ; R1指向參數存儲位置

        MRS     R3, SPSR
        TST     R3, #T_bit              ; 中斷前是否是Thumb狀態
        LDRNEH  R0, [LR,#-2]            ; 是: 取得Thumb狀態SWI號
        BICNE   R0, R0, #0xff00
        LDREQ   R0, [LR,#-4]            ; 否: 取得arm狀態SWI號
        BICEQ   R0, R0, #0xFF000000
                                        ; r0 = SWI號，R1指向參數存儲位置
        CMP     R0, #1
        LDRLO   PC, =OSIntCtxSw
        LDREQ   PC, =__OSStartHighRdy   ; SWI 0x01爲第一次任務切換

        BL      SWI_Exception
       
        LDMFD   SP!, {R0-R3, R12, PC}^
       
StackSvc           DCD     (SvcStackSpace + SVC_STACK_LEGTH * 4 - 4)

 

OSIntCtxSw
                                                    ;下面爲保存任務環境
        LDR     R2, [SP, #20]                       ;獲取PC（LR）
        LDR     R12, [SP, #16]                      ;獲取R12
        MRS     R0, CPSR

        MSR     CPSR_c, #(NoInt | SYS32Mode)
        MOV     R1, LR
        STMFD   SP!, {R1-R2}                        ;保存LR,PC
        STMFD   SP!, {R4-R12}                       ;保存R4-R12

        MSR     CPSR_c, R0
        LDMFD   SP!, {R4-R7}                        ;獲取R0-R3
        ADD     SP, SP, #8                          ;出棧R12,PC
       
        MSR     CPSR_c, #(NoInt | SYS32Mode)
        STMFD   SP!, {R4-R7}                        ;保存R0-R3
       
        LDR     R1, =OsEnterSum                     ;獲取OsEnterSum
        LDR     R2, [R1]
        STMFD   SP!, {R2, R3}                       ;保存CPSR,OsEnterSum

                                                    ;保存當前任務堆棧指針到當前任務的TCB
        LDR     R1, =OSTCBCur
        LDR     R1, [R1]
        STR     SP, [R1]

        BL      OSTaskSwHook                        ;調用鉤子函數
                                                    ;OSPrioCur <= OSPrioHighRdy
        LDR     R4, =OSPrioCur
        LDR     R5, =OSPrioHighRdy
        LDRB    R6, [R5]
        STRB    R6, [R4]             ;把OSPrioHighRdy最高優先級的就緒任務傳給OSPrioCur
                                                    ;OSTCBCur <= OSTCBHighRdy
        LDR     R6, =OSTCBHighRdy
        LDR     R6, [R6]
        LDR     R4, =OSTCBCur
        STR     R6, [R4]         ;將最高優先級的任務控制塊指針傳給當前任務控制塊指針