腳本自動編譯打包qt程序(windows)
使用環境
本文的測試環境爲win10 64位系統,工具使用qt5.7.1 msvc 2015版本,nsis ,cmd等
腳本實現及使用
腳本分爲兩部分,打包應用相關文件,包括qt動態庫,應用lisence等等
代碼部分
打包執行腳本
package.bat
::@echo off
echo Setting up environment for Qt usage...
set PATH=C:\Qt\Qt5.7.1\5.7\msvc2015_64\bin;%PATH%
echo qmake...
::qmake編譯pro文件,本腳本的pro文件在上季以目錄
qmake ..
echo nmake...
::qmake之後生成makefile 使用nmake編譯生成可執行文件
nmake release
::下面這些是打包成安裝文件的步驟
echo set app reference information...
::腳本第一參數是應用名稱(注意不用帶擴展)
set app_name=%1
::默認nmake生成的文件在當前腳本目錄的同級release文件夾下
set app_path=%~dp0\release
::設置應用版本,格式爲 v1.0.0
set app_version=%2
echo Copy Qt references...
::使用qt自帶程序拷貝qt相關文件
windeployqt "%app_path%\\%app_name%.exe"
echo Copy license etc.
::拷貝許可文件,就是安裝時候說的那堆責任神馬的東西
copy ..\apps\package\license.txt %app_path%
::這是msvc的運行庫安裝文件,偷懶了,其實可以直接複製動態庫的
copy ..\apps\package\vcredist_x64.exe %app_path%
::qt配置文件,我這裏主要是爲了配置一些高分辨率下字體大小的
copy ..\apps\package\qt.conf %app_path%
echo nsis package...
::開始用nsis打包成安裝文件
"C:\Program Files (x86)\NSIS\makensis.exe" "D:\work\gitlab\apps\package\normal_package.nsi"
nsis腳本
normal_package.bat
; Script generated by the HM NIS Edit Script Wizard.
; HM NIS Edit Wizard helper defines
!define DOLLAR "$"
!define PRODUCT_NAME $%app_name%
!define "CHECK_NAME_${PRODUCT_NAME}"
!echo "${DOLLAR}%app_name%"
!if ${PRODUCT_NAME} != "${DOLLAR}%app_name%"
!echo "app_name:${PRODUCT_NAME}"
!else
!echo CHECK_NAME_$%%app_name%
!error "app_name not specified!"
!endif
!define PACKAGE_PATH $%app_path%
!define "CHECK_NAME_${PACKAGE_PATH}"
!if ${PACKAGE_PATH} != "${DOLLAR}%app_path%"
!echo "app_path:${PACKAGE_PATH}"
!else
!error "app_path not specified!"
!endif
!define PRODUCT_VERSION $%app_version%
!define "CHECK_NAME_${PRODUCT_VERSION}"
!if ${PRODUCT_VERSION} != "${DOLLAR}%app_version%"
!echo "app_version:${PRODUCT_VERSION}"
!else
!error "app_version not specified!"
!endif
!define PRODUCT_PUBLISHER "INNFOS, Inc."
!define PRODUCT_WEB_SITE "http://www.innfos.com"
!define PRODUCT_DIR_REGKEY "Software\Microsoft\Windows\CurrentVersion\App Paths\${PRODUCT_NAME}.exe"
!define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
!define PRODUCT_UNINST_ROOT_KEY "HKLM"
; MUI 1.67 compatible ------
!include "MUI.nsh"
; MUI Settings
!define MUI_ABORTWARNING
!define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\Classic-install.ico"
!define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\modern-uninstall.ico"
; Welcome page
!insertmacro MUI_PAGE_WELCOME
; License page
!insertmacro MUI_PAGE_LICENSE "${PACKAGE_PATH}\license.txt"
; Directory page
!insertmacro MUI_PAGE_DIRECTORY
; Instfiles page
!insertmacro MUI_PAGE_INSTFILES
; Finish page
!define MUI_FINISHPAGE_RUN "$INSTDIR\${PRODUCT_NAME}.exe"
!insertmacro MUI_PAGE_FINISH
; Uninstaller pages
!insertmacro MUI_UNPAGE_INSTFILES
; Language files
!insertmacro MUI_LANGUAGE "English"
; MUI end ------
Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
OutFile "${PRODUCT_NAME}_Setup.exe"
;RequestExecutionLevel admin ;Require admin rights on NT6+ (When UAC is turned on)
InstallDir "$PROGRAMFILES\${PRODUCT_NAME}"
InstallDirRegKey HKLM "${PRODUCT_DIR_REGKEY}" ""
ShowInstDetails show
ShowUnInstDetails show
;RequestExecutionLevel admin
Section "MainSection" SEC01
SetOutPath "$INSTDIR"
SetOverwrite ifnewer
File "${PACKAGE_PATH}\*.dll"
File /r "${PACKAGE_PATH}\*.exe"
File /r "${PACKAGE_PATH}\*.conf"
File /nonfatal "${PACKAGE_PATH}\*.xml"
SetOutPath "$INSTDIR\imageformats"
File /r "${PACKAGE_PATH}\imageformats\*.dll"
SetOutPath "$INSTDIR\iconengines"
File /r "${PACKAGE_PATH}\iconengines\*.dll"
SetOutPath "$INSTDIR\platforms"
File /r "${PACKAGE_PATH}\platforms\*.dll"
CreateDirectory "$SMPROGRAMS\${PRODUCT_NAME}"
CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\${PRODUCT_NAME}.lnk" "$INSTDIR\${PRODUCT_NAME}.exe"
CreateShortCut "$DESKTOP\${PRODUCT_NAME}.lnk" "$INSTDIR\${PRODUCT_NAME}.exe"
;File "${PACKAGE_PATH}\D3Dcompiler_47.dll"
SetDetailsPrint textonly
DetailPrint 'add input rule ..'
ExecWait '"cmd.exe" /c netsh advfirewall firewall add rule name="${PRODUCT_NAME}" dir=in action=allow protocol=udp program="$INSTDIR\${PRODUCT_NAME}.exe"'
DetailPrint 'install VC++ library...'
SetOutPath $TEMP
File "${PACKAGE_PATH}\vcredist_x64.exe"
ExecWait '"$TEMP\vcredist_x64.exe" /Q'
Delete "$TEMP\vcredist_x64.exe"
;DetailPrint 'install serial port driver...'
;SetOutPath $TEMP
;File "${PACKAGE_PATH}\driver.exe"
;ExecWait '"$TEMP\driver.exe" /Q'
;Delete "$TEMP\driver.exe"
SetDetailsPrint both
SectionEnd
Section -AdditionalIcons
WriteIniStr "$INSTDIR\${PRODUCT_NAME}.url" "InternetShortcut" "URL" "${PRODUCT_WEB_SITE}"
CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\Website.lnk" "$INSTDIR\${PRODUCT_NAME}.url"
CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\Uninstall.lnk" "$INSTDIR\uninst.exe"
SectionEnd
Section -Post
WriteUninstaller "$INSTDIR\uninst.exe"
WriteRegStr HKLM "${PRODUCT_DIR_REGKEY}" "" "$INSTDIR\${PRODUCT_NAME}.exe"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayIcon" "$INSTDIR\${PRODUCT_NAME}.exe"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${PRODUCT_WEB_SITE}"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "Publisher" "${PRODUCT_PUBLISHER}"
SectionEnd
Function un.onUninstSuccess
HideWindow
MessageBox MB_ICONINFORMATION|MB_OK "$(^Name) 已成功地從你的計算機移除。"
FunctionEnd
Function un.onInit
MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "你確實要完全移除 $(^Name) ,其及所有的組件?" IDYES +2
Abort
FunctionEnd
Section Uninstall
Delete "$INSTDIR\${PRODUCT_NAME}.url"
Delete "$SMPROGRAMS\${PRODUCT_NAME}\Uninstall.lnk"
Delete "$SMPROGRAMS\${PRODUCT_NAME}\Website.lnk"
Delete "$DESKTOP\${PRODUCT_NAME}.lnk"
Delete "$SMPROGRAMS\${PRODUCT_NAME}\${PRODUCT_NAME}.lnk"
RMDir "$SMPROGRAMS\${PRODUCT_NAME}"
RMDir /r "$INSTDIR"
DeleteRegKey ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}"
DeleteRegKey HKLM "${PRODUCT_DIR_REGKEY}"
SetAutoClose true
SectionEnd
腳本就不過多解釋了,都比較簡單,如果哪裏不明白可自行百度
使用方法
1.使用上圖中的 64位環境的提示符
cd your_qt_project_dir
mkdir build
cd build
package.bat "your_app_name" "your_app_version"
回車,會在package.bat的同級目錄生成安裝文件,就可以安裝使用了