linux awk（全手冊）

awk是一種處理文本文件的語言，是一個強大的文本分析工具。

語法

awk [選項參數] 'script' var=value file(s)
或
awk [選項參數] -f scriptfile var=value file(s)

選項參數說明：

• -F fs or --field-separator fs
  指定輸入文件折分隔符，fs是一個字符串或者是一個正則表達式，如-F:。
• -v var=value or --asign var=value
  賦值一個用戶定義變量。
• -f scripfile or --file scriptfile
  從腳本文件中讀取awk命令。
• -mf nnn and -mr nnn
  對nnn值設置內在限制，-mf選項限制分配給nnn的最大塊數目；-mr選項限制記錄的最大數目。這兩個功能是Bell實驗室版awk的擴展功能，在標準awk中不適用。
• -W compact or --compat, -W traditional or --traditional
  在兼容模式下運行awk。所以gawk的行爲和標準的awk完全一樣，所有的awk擴展都被忽略。
• -W copyleft or --copyleft, -W copyright or --copyright
  打印簡短的版權信息。
• -W help or --help, -W usage or --usage
  打印全部awk選項和每個選項的簡短說明。
• -W lint or --lint
  打印不能向傳統unix平臺移植的結構的警告。
• -W lint-old or --lint-old
  打印關於不能向傳統unix平臺移植的結構的警告。
• -W posix
  打開兼容模式。但有以下限制，不識別：/x、函數關鍵字、func、換碼序列以及當fs是一個空格時，將新行作爲一個域分隔符；操作符**和**=不能代替^和^=；fflush無效。
• -W re-interval or --re-inerval
  允許間隔正則表達式的使用，參考(grep中的Posix字符類)，如括號表達式[[:alpha:]]。
• -W source program-text or --source program-text
  使用program-text作爲源代碼，可與-f命令混用。
• -W version or --version
  打印bug報告信息的版本。

---

基本用法

log.txt文本內容如下：

this is a log
do you like awk
This's a log
10 There are orange,apple,mongo

用法一：

awk '{[pattern] action}' {filenames}   # 行匹配語句 awk '' 只能用單引號

實例：

#每行按空格或TAB分割，輸出文本中的1項 

# awk '{print $1}' logs.txt 
this
do
This's
10

#每行按空格或者TAB輸出1，4項

# awk '{print $1,$4}' logs.txt 
this log
do awk
This's 
10 orange,apple,mongo

# 格式化輸出，第1項至少佔8位，第4項至少佔10位，且兩個展示時用空格隔開

# awk '{printf "%-8s %-10s\n",$1,$4}' logs.txt
this     log       
do       awk       
This's             
10       orange,apple,mongo

 

用法二：

awk -v  # 設置變量

實例：

awk -v a=2 '{print $1,$1+a}' logs.txt 
this 2
do 2
This's 2
10 12

變量 算數計算與字符串拼接

awk -v a=2 -v b=aabbcc '{print $1,$1+a,$1b}' logs.txt 
this 2 thisaabbcc
do 2 doaabbcc
This's 2 This'saabbcc
10 12 10aabbcc

 

用法四：

awk -f {awk腳本} {文件名}

實例：

寫一個awk的腳本，

# vim test.awk 

內容如下

{print $1}

使用腳本文件 執行

# awk -f test.awk logs.txt 
this
do
This's
10

---

運算符

運算符	描述
= += -= *= /= %= ^= **=	賦值
?:	C條件表達式
||	邏輯或
&&	邏輯與
~ 和 !~	匹配正則表達式和不匹配正則表達式
< <= > >= != ==	關係運算符
空格	連接
+ -	加，減
* / %	乘，除與求餘
+ - !	一元加，減和邏輯非
^ ***	求冪
++ --	增加或減少，作爲前綴或後綴
$	字段引用
in	數組成員

過濾第一列等於10的行

# awk '$1==10' logs.txt 
10 There are orange,apple,mongo

過濾第一列等於10並或者第一列等於'do'的行

# awk '$1==10||$1=="do"' logs.txt 
do you like awk
10 There are orange,apple,mongo

---

內建變量

變量	描述
$n	當前記錄的第n個字段，字段間由FS分隔
$0	完整的輸入記錄
ARGC	命令行參數的數目
ARGIND	命令行中當前文件的位置(從0開始算)
ARGV	包含命令行參數的數組
CONVFMT	數字轉換格式(默認值爲%.6g)ENVIRON環境變量關聯數組
ERRNO	最後一個系統錯誤的描述
FIELDWIDTHS	字段寬度列表(用空格鍵分隔)
FILENAME	當前文件名
FNR	各文件分別計數的行號
FS	字段分隔符(默認是任何空格)
IGNORECASE	如果爲真，則進行忽略大小寫的匹配
NF	一條記錄的字段的數目
NR	已經讀出的記錄數，就是行號，從1開始
OFMT	數字的輸出格式(默認值是%.6g)
OFS	輸出記錄分隔符（輸出換行符），輸出時用指定的符號代替換行符
ORS	輸出記錄分隔符(默認值是一個換行符)
RLENGTH	由match函數所匹配的字符串的長度
RS	記錄分隔符(默認是一個換行符)
RSTART	由match函數所匹配的字符串的第一個位置
SUBSEP	數組下標分隔符(默認值是/034)

# awk '{print NR,FNR,$1,$2,$3}' logs.txt
1 1 this is a
2 2 do you like
3 3 This's a log
4 4 10 There are

---

使用正則，字符串匹配

# 輸出第二列包含 "th"，並打印第二列與第四列

# awk '$1 ~ /th/ {print $1,$2,$3,$4}' logs.txt
this is a log

~ 表示模式開始。// 中是模式。

# 輸出包含"re" 的行

awk '/re/' logs.txt 
10 There are orange,apple,mongo

---

 

awk腳本

關於awk腳本，我們需要注意兩個關鍵詞BEGIN和END。

• BEGIN{ 這裏面放的是執行前的語句 }
• END {這裏面放的是處理完所有的行後要執行的語句 }
• {這裏面放的是處理每一行時要執行的語句}

假設有這麼一個文件（學生成績表）：

cat score.txt
Marry   2143 78 84 77
Jack    2321 66 78 45
Tom     2122 48 77 71
Mike    2537 87 97 95
Bob     2415 40 57 62

我們的awk腳本如下：

#cat cal.awk
#!/bin/awk -f
#運行前
BEGIN {
    math = 0
    english = 0
    computer = 0
 
    printf "NAME    NO.   MATH  ENGLISH  COMPUTER   TOTAL\n"
    printf "---------------------------------------------\n"
}
#運行中
{
    math+=$3
    english+=$4
    computer+=$5
    printf "%-6s %-6s %4d %8d %8d %8d\n", $1, $2, $3,$4,$5, $3+$4+$5
}
#運行後
END {
    printf "---------------------------------------------\n"
    printf "  TOTAL:%10d %8d %8d \n", math, english, computer
    printf "AVERAGE:%10.2f %8.2f %8.2f\n", math/NR, english/NR, computer/NR
}

我們來看一下執行結果：

awk -f cal.awk score.txt
NAME    NO.   MATH  ENGLISH  COMPUTER   TOTAL
---------------------------------------------
Marry  2143     78       84       77      239
Jack   2321     66       78       45      189
Tom    2122     48       77       71      196
Mike   2537     87       97       95      279
Bob    2415     40       57       62      159
---------------------------------------------
  TOTAL:       319      393      350 
AVERAGE:     63.80    78.60    70.00

---

另外一些實例

打印九九乘法表

# seq 9 | sed 'H;g' | awk -v RS='' '{for(i=1;i<=NF;i++)printf("%dx%d=%d%s", i, NR, i*NR, i==NR?"\n":"\t")}'
1x1=1
1x2=2	2x2=4
1x3=3	2x3=6	3x3=9
1x4=4	2x4=8	3x4=12	4x4=16
1x5=5	2x5=10	3x5=15	4x5=20	5x5=25
1x6=6	2x6=12	3x6=18	4x6=24	5x6=30	6x6=36
1x7=7	2x7=14	3x7=21	4x7=28	5x7=35	6x7=42	7x7=49
1x8=8	2x8=16	3x8=24	4x8=32	5x8=40	6x8=48	7x8=56	8x8=64
1x9=9	2x9=18	3x9=27	4x9=36	5x9=45	6x9=54	7x9=63	8x9=72	9x9=81