vb做的類似打鼴鼠的遊戲,簡單,十分推薦初學vb 想做遊戲的人學習

 

vb做的類似打鼴鼠的遊戲,簡單,十分推薦初學vb 想做遊戲的人學習

2007年01月16日 01:26

類似打鼴鼠的遊戲 ,每段時間 隨機更新 小球 ,能記錄打中和打錯的個數

添加 一個form1 窗體上添加 一個picture控件 一個timer

全部代碼:

'***********************************************

Dim OneX&, OneY             '每塊的長寬
Dim ys(4, 4) As Boolean     '5*5的數組 記錄是否有鼴鼠
Dim suc&, fail&             '點對和點錯的個數
Private Sub Form_Load()
    Me.Show
    OneX = Picture1.Width / 5
    OneY = Picture1.Height / 5
    InitLine
    RefreshCaption
    Timer1_Timer
End Sub
Sub InitLine()
    Dim i&
    For i = 1 To 4
        Picture1.Line (OneX * i, 0)-(OneX * i, Picture1.Height)
    Next
    For i = 1 To 4
        Picture1.Line (0, OneY * i)-(Picture1.Width, OneY * i)
    Next
End Sub

Private Sub Picture1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
    Dim dx&, dy&
    dx = Fix(X / OneX)
    dy = Fix(Y / OneY)
    If dx > 4 Or dy > 4 Then Exit Sub
    
    If ys(dx, dy) Then
        suc = suc + 1
        ys(dx, dy) = False
    Else
        fail = fail + 1
    End If
    RefreshCaption
    RefreshPic
End Sub

Private Sub RefreshCaption()
    Me.Caption = "打中 " & suc & "個 打錯 " & fail & "個"
End Sub

Private Sub RefreshPic()
    Dim i&, j&
    For j = 0 To 4
        For i = 0 To 4
            If ys(i, j) Then
                Picture1.Circle (i * OneX + OneX / 2, j * OneY + OneY / 2), IIf(OneX > OneY, OneY / 2 - 2, OneX / 2 - 2)
            Else
                Picture1.Line (OneX * i + 1, OneY * j + 1)-(OneX * (i + 1) - 1, OneY * (j + 1) - 1), vbWhite, BF
            End If
        Next
    Next
    InitLine
End Sub

Private Sub Timer1_Timer()
    Randomize
    Dim RndNum&, i&, j&
    For j = 0 To 4
        For i = 0 To 4
            If Int(Rnd * 15) <= 2 Then
                ys(i, j) = True
            End If
        Next
    Next
    RefreshPic
End Sub

'***********************************************

最終效果如下:

因百度無法提供上傳 請+QQ:627083940 或+QQ羣:5773874 大家共同學習