--作業的應用,必須啓動Sql server agent進程。
--下面是sql2005創建一個作業的腳本。
--定義創建作業
DECLARE @jobid uniqueidentifier
EXEC msdb.dbo.sp_add_job
@job_name = N'臨時表添加一條記錄', --自己取一個作業名字,就像給小孩取名字
@job_id = @jobid OUTPUT
--定義作業步驟
DECLARE @sql nvarchar(400),@dbname sysname
SELECT @dbname=DB_NAME(), --作業步驟在當前數據庫中執行
@sql=N'INSERT INTO TempTable(Date)VALUES(getdate())' --一般定義的是使用TSQL處理的作業,這裏定義要執行的Transact-SQL語句 ,比如普通sql語句和存儲過程等
EXEC msdb.dbo.sp_add_jobstep
@job_id = @jobid,
@step_name = N'臨時表添加一條記錄步驟名稱', --自己取一個執行步驟名字
@subsystem = 'TSQL', --步驟的類型,一般爲TSQL
@database_name=@dbname,
@command = @sql
--創建調度(可以使用下面的各種調度方式。這裏就使用“日調度”:每1天的每隔1小時執行一次)
EXEC msdb.dbo.sp_add_jobschedule
@job_id = @jobid,
@name = N'調度名稱',
@freq_type=4, --日調度
@freq_interval=1, --指定每多少天發生一次,這裏是1天.
@freq_subday_type=0x8, --重複方式:0x1=在指定的時間,0x4=多少分鐘,0x8=多少小時執行一次
@freq_subday_interval=1, --重複週期數:這裏每小時執行一次
@active_start_date = NULL, --作業執行的開始日期,爲NULL時表示當前日期,格式爲YYYYMMDD
@active_end_date = 99991231, --作業執行的停止日期,默認爲99991231,格式爲YYYYMMDD
@active_start_time = 00000, --作業執行的開始時間,格式爲HHMMSS
@active_end_time = 235959 --作業執行的停止時間,格式爲HHMMSS
--添加目標服務器
DECLARE @servername sysname
SET @servername=CONVERT(nvarchar(128),SERVERPROPERTY(N'ServerName'))
EXEC msdb.dbo.sp_add_jobserver
@job_id = @jobid,
@server_name = @servername --使用當前SQL實例
-----------------------------------------------------------------------------------------以上完成一個作業的創建
其他作業調度方法:
--調度模板定義
--@freq_type標記是哪一種調度類型,如下:
--1:僅執行一次 ;4:日調度;8:周調度 ;16:月調度(每X個月的每月幾號) ;
32:月調度(每X個月的相對時間) ;64:在特定時候執行的作業調度
--/*--只執行一次的作業調度
EXEC msdb.dbo.sp_add_jobschedule
@job_id = @jobid,
@name = N'調度名稱',
@freq_type=1, --僅執行一次
@active_start_date = NULL, --作業執行的開始日期,爲NULL時表示當前日期,格式爲YYYYMMDD
@active_start_time = 00000 --作業執行的開始時間,格式爲HHMMSS
--*/
--/*--日調度
EXEC msdb.dbo.sp_add_jobschedule
@job_id = @jobid,
@name = N'調度名稱',
@freq_type=4, --日調度
@freq_interval=1, --指定每多少天發生一次,這裏是1天.
@freq_subday_type=0x8, --重複方式,0x1=在指定的時間,0x4=多少分鐘,0x8=多少小時執行一次
@freq_subday_interval=1, --重複週期數,這裏每小時執行一次
@active_start_date = NULL, --作業執行的開始日期,爲NULL時表示當前日期,格式爲YYYYMMDD
@active_end_date = 99991231, --作業執行的停止日期,默認爲99991231,格式爲YYYYMMDD
@active_start_time = 00000, --作業執行的開始時間,格式爲HHMMSS
@active_end_time = 235959 --作業執行的停止時間,格式爲HHMMSS
--*/
--/*--周調度
EXEC msdb.dbo.sp_add_jobschedule
@job_id = @jobid,
@name = N'調度名稱',
@freq_type = 8, --周調度
@freq_recurrence_factor = 1, --每多少周執行一次,這裏是每週
@freq_interval = 62, --在星期幾執行,由POWER(2,N)表示,N的值爲0~6,代表星期日~星期六,如果指定兩個,則將值相加,例如,值爲65表示在星期天和星期日執行(POWER(2,0)+POWER(2,6))
@freq_subday_type = 0x8, --重複方式,0x1=在指定的時間,0x4=多少分鐘,0x8=多少小時執行一次
@freq_subday_interval = 1, --重複週期數,這裏每小時執行一次
@active_start_date = NULL, --作業執行的開始日期,爲NULL時表示當前日期,格式爲YYYYMMDD
@active_end_date = 99991231, --作業執行的停止日期,默認爲99991231,格式爲YYYYMMDD
@active_start_time = 00000, --作業執行的開始時間,格式爲HHMMSS
@active_end_time = 235959 --作業執行的停止時間,格式爲HHMMSS
--*/
--/*--月調度(每X個月的每月幾號)
EXEC msdb.dbo.sp_add_jobschedule
@job_id = @jobid,
@name = N'調度名稱',
@freq_type = 16, --月調度(每X個月的每月幾號)
@freq_recurrence_factor = 2, --每多少月執行一次,這裏是每2個月
@freq_interval = 2, --在執行月的第幾天執行,這裏是第2天
@freq_subday_type = 0x8, --重複方式,0x1=在指定的時間,0x4=多少分鐘,0x8=多少小時執行一次
@freq_subday_interval = 1, --重複週期數,這裏每小時執行一次
@active_start_date = NULL, --作業執行的開始日期,爲NULL時表示當前日期,格式爲YYYYMMDD
@active_end_date = 99991231, --作業執行的停止日期,默認爲99991231,格式爲YYYYMMDD
@active_start_time = 00000, --作業執行的開始時間,格式爲HHMMSS
@active_end_time = 235959 --作業執行的停止時間,格式爲HHMMSS
--*/
--/*--月調度(每X個月的相對時間)
EXEC msdb.dbo.sp_add_jobschedule
@job_id = @jobid,
@name = N'調度名稱',
@freq_type = 32, --月調度(每X個月的相對時間)
@freq_recurrence_factor = 2, --每多少月執行一次,這裏是每2個月
@freq_interval = 9, --在當月的那個時間執行,1~7=星期日至星期六,8=日 ,9=工作日,10=週末
@freq_relative_interval = 1, --在第幾個相對時間執行,允許的值爲1,2,4,8代表第1~4個相對時間,16表示最後一個相對時間
@freq_subday_type = 0x8, --重複方式,0x1=在指定的時間,0x4=多少分鐘,0x8=多少小時執行一次
@freq_subday_interval = 1, --重複週期數,這裏每小時執行一次
@active_start_date = NULL, --作業執行的開始日期,爲NULL時表示當前日期,格式爲YYYYMMDD
@active_end_date = 99991231, --作業執行的停止日期,默認爲99991231,格式爲YYYYMMDD
@active_start_time = 00000, --作業執行的開始時間,格式爲HHMMSS
@active_end_time = 235959 --作業執行的停止時間,格式爲HHMMSS
--*/
--/*--在特定時候執行的作業調度
EXEC msdb.dbo.sp_add_jobschedule
@job_id = @jobid,
@name = N'調度名稱',
@freq_type = 64 --64=在SQLServerAgent 服務啓動時運行
--/*--計算機空閒時運行
EXEC msdb.dbo.sp_add_jobschedule
@job_id = @jobid,
@name = N'調度名稱',
@freq_type = 128 --128=計算機空閒時運行
--*/