ESP32cam--保存JPEG格式圖片到SD卡（Arduino IDE）

ESP32Cam模塊的原理圖

ESP32Cam自帶了一個SD卡模塊
但是在這裏SD卡的連線並沒有體現出SPI協議。

一張Micro SD卡引腳圖如下：

一張micro SD卡有8個引腳。下表描述了每個引腳的功能。

引腳序號	名稱	功能說明	ESP32cam原理圖
1	NC	未連接	HS2_DATA2（GPIO12）
2	CS	片選/從選擇（SS）	HS2_DATA3（GPI13）
3	DI	主輸出/從輸入（MOSI）	HS2_CMD（GPIO15）
4	VDD	電源電壓	VDD
5	CLK	時鐘（SCK）	HS2_CLK（GPIO14）
6	VSS	電源電壓地	VSS
7	DO	主輸入/從輸出（MISO）	HS2_DATA0（GPIO2）
8	RSV	保留	HS2_DATA1 （GPIO4）

坑

 由原理圖是已經可以知道各個引腳的連接，但是，基於Arduino的尿性，我還是不知道該怎麼配置。
 然後我就一直在糾結怎麼在SPI初始化的時候自定義引腳就像這樣：

SPI.begin(14,2,15,13);//SCK,MISO,MOSI,ss
delay(10);
if (!SD.begin(13, SPI, 40000000, "/sd")) {
	Serial.println("Card Mount Failed");
}

然後全部失敗！

希望

 可笑的是，在亞馬遜賣ESP32cam模塊的界面找到了，它的使用源碼並且找到了一個人寫的：https://github.com/v12345vtm/CameraWebserver2SD/blob/master/CameraWebserver2SD/CameraWebserver2SD.ino

這哥們用的是SD_MMC模塊來寫入SD卡的，最後終於搞定！

核心代碼：

   //acquire a frame
 camera_fb_t * fb = esp_camera_fb_get();
 if (!fb) 
 {
     Serial.print( "Camera capture failed");
 } 
 else 
 {
     if(fb->format != PIXFORMAT_JPEG)
     {
           Serial.print("jpeg error");
           esp_camera_fb_return(fb);
      } 
      else 
      {
           const char * path = "/capture.jpg";
           fs::FS &fs = SD_MMC; 
           Serial.printf("Writing file: %s\n", path);
           File file = fs.open(path, FILE_WRITE);
           if(!file)
           {
               Serial.println("Failed to open file for SDwriting547");
           } 
           else
           {
              file.write(fb->buf , fb->len); //payload , lengte vd payload
              Serial.println("succes to open file for SDwriting552");
           }
          esp_camera_fb_return(fb); 
      }
 }

最終的完整代碼

按鍵設置爲：GPIO16

#include "esp_camera.h"
#include "FS.h"
#include <SPI.h>
#include <SD.h>
#include "SD_MMC.h"

int buttonState = 0;
int btnHold = 0;

#define KEY_PIN       16

#define PWDN_GPIO_NUM     32
#define RESET_GPIO_NUM    -1
#define XCLK_GPIO_NUM      0
#define SIOD_GPIO_NUM     26
#define SIOC_GPIO_NUM     27

#define Y9_GPIO_NUM       35
#define Y8_GPIO_NUM       34
#define Y7_GPIO_NUM       39
#define Y6_GPIO_NUM       36
#define Y5_GPIO_NUM       21
#define Y4_GPIO_NUM       19
#define Y3_GPIO_NUM       18
#define Y2_GPIO_NUM        5
#define VSYNC_GPIO_NUM    25
#define HREF_GPIO_NUM     23
#define PCLK_GPIO_NUM     22

static camera_config_t camera_config = {
    .pin_pwdn = PWDN_GPIO_NUM,
    .pin_reset = RESET_GPIO_NUM,
    .pin_xclk = XCLK_GPIO_NUM,
    .pin_sscb_sda = SIOD_GPIO_NUM,
    .pin_sscb_scl = SIOC_GPIO_NUM,
    
    .pin_d7 = Y9_GPIO_NUM,
    .pin_d6 = Y8_GPIO_NUM,
    .pin_d5 = Y7_GPIO_NUM,
    .pin_d4 = Y6_GPIO_NUM,
    .pin_d3 = Y5_GPIO_NUM,
    .pin_d2 = Y4_GPIO_NUM,
    .pin_d1 = Y3_GPIO_NUM,
    .pin_d0 = Y2_GPIO_NUM,
    .pin_vsync = VSYNC_GPIO_NUM,
    .pin_href = HREF_GPIO_NUM,
    .pin_pclk = PCLK_GPIO_NUM,
    
    .xclk_freq_hz = 20000000,
    .ledc_timer = LEDC_TIMER_0,
    .ledc_channel = LEDC_CHANNEL_0,
    
    .pixel_format = PIXFORMAT_JPEG,
    .frame_size = FRAMESIZE_XGA,
    .jpeg_quality = 12,
    .fb_count = 1,
};

esp_err_t camera_init() {
    //initialize the camera
    esp_err_t err = esp_camera_init(&camera_config);
    if (err != ESP_OK) {
        Serial.print("Camera Init Failed");
        return err;
    }
    sensor_t * s = esp_camera_sensor_get();
    //initial sensors are flipped vertically and colors are a bit saturated
    if (s->id.PID == OV2640_PID) {
    //        s->set_vflip(s, 1);//flip it back
    //        s->set_brightness(s, 1);//up the blightness just a bit
    //        s->set_contrast(s, 1);
    }
    
    Serial.print("Camera Init OK");
    return ESP_OK;
}

void sd_init(void)
{
    Serial.print("Initializing SD card...");
    
    //SD card init
    if (!SD_MMC.begin()) {
        Serial.println("Card Mount Failed");
        return;
    }
    uint8_t cardType = SD_MMC.cardType();
    
    if (cardType == CARD_NONE) {
        Serial.println("No SD_MMC card attached");
        return;
    }
    
    Serial.print("SD_MMC Card Type: ");
    if (cardType == CARD_MMC) {
        Serial.println("MMC");
    } else if (cardType == CARD_SD) {
        Serial.println("SDSC");
    } else if (cardType == CARD_SDHC) {
        Serial.println("SDHC");
    } else {
        Serial.println("UNKNOWN");
    }
    
    if (SD_MMC.exists("test.txt")) {
        Serial.println("exist");
    }
    else 
    {
        Serial.println("doesn't exist");
    }
}

void setup() {
    Serial.begin(115200);
    
    camera_init();
    
    sd_init();

    pinMode(KEY_PIN, INPUT_PULLUP); //設置按鍵管腳輸入上拉模式

    Serial.println("sys is running!");
}

void loop() 
{
    buttonState = digitalRead(KEY_PIN); //讀取按鍵返回狀態值
    if (buttonState == LOW && btnHold == 0)
    { // 若按鍵被按下
        delay(100); //等待跳過按鍵抖動的不穩定過程
        if (buttonState == LOW) // 若按鍵被按下
        {
            Serial.print("click\r\n");
            btnHold = 1;
        
            //acquire a frame
            camera_fb_t * fb = esp_camera_fb_get();
            if (!fb)
            {
                Serial.print( "Camera capture failed");
            }
            else
            { 
                const char * path = "/capture.jpg";
                fs::FS &fs = SD_MMC;
                Serial.printf("Writing file: %s\n", path);
                
                File file = fs.open(path, FILE_WRITE);
                if (!file) 
                {
                    Serial.println("Failed to open file for SDwriting547");
                }
                else
                {
                    file.write(fb->buf , fb->len); //payload , lengte vd payload
                    Serial.println("succes to open file for SDwriting552");
                }
                //return the frame buffer back to the driver for reuse
                esp_camera_fb_return(fb);
            }
        }
    }
      
    if (buttonState == HIGH)
    {
        btnHold = 0;
    }
}