QT學習日誌 QML編程

QT學習日誌_QML編程

一、爲什麼要學習QML

熟悉Window編程的小夥伴，有很多的框架可以編寫我們的應用程序，比如MFC，C#的Winform，QT中也有類似的框架QT Widgets，使用這些框架可以寫出一些中規中矩的標準界面，但是想要做出很炫的界面，你得花費很大的精力。幸運的是，QT有這樣的解決方案 QML，使用QML可以很方便的寫出一些很炫的東西，而且QML的語法風格和HTML和CSS很相似，不知道是不是有借鑑的嫌疑。

二、QML簡介

這裏是引用 百度百科QML
QML是一種描述性的腳本語言，文件格式以.qml結尾。語法格式非常像CSS（參考後文具體例子），但又支持javascript形式的編程控制。QtDesigner可以設計出·ui界面文件，但是不支持和Qt原生C++代碼的交互。QtScript可以和Qt原生代碼進行交互，但是有一個缺點，如果要在腳本中創建一個繼承於QObject的圖形對象非常不方便，只能在Qt代碼中創建圖形對象，然後從QtScript中進行訪問。而QML可以在腳本里創建圖形對象，並且支持各種圖形特效，以及狀態機等，同時又能跟Qt寫的C++代碼進行方便的交互，使用起來非常方便。

貼幾個很炫的QML界面


三、QML 編程的Demo

簡單的計算機

貼點QML代碼

import CalculatorStateMachine 1.0
import QtQuick 2.5
import QtQuick.Window 2.0
import QtScxml 5.8

Window {
    id: window
    visible: true
    width: 320
    height: 480

    CalculatorStateMachine {
        id: statemachine
        running: true
        EventConnection {
            events: ["updateDisplay"]
            onOccurred: resultText.text = event.data.display
        }
    }

    Rectangle {
        id: resultArea
        anchors.left: parent.left
        anchors.right: parent.right
        anchors.top: parent.top
        height: parent.height * 3 / 8 - 10
        border.color: "white"
        border.width: 1
        color: "#46a2da"
        Text {
            id: resultText
            anchors.leftMargin: buttons.implicitMargin
            anchors.rightMargin: buttons.implicitMargin
            anchors.fill: parent
            horizontalAlignment: Text.AlignRight
            verticalAlignment: Text.AlignVCenter
            text: "0"
            color: "white"
            font.pixelSize: window.height * 3 / 32
            font.family: "Open Sans Regular"
            fontSizeMode: Text.Fit
        }
    }

    Item {
        id: buttons
        anchors.top: resultArea.bottom
        anchors.left: parent.left
        anchors.right: parent.right
        anchors.bottom: parent.bottom
        property real implicitMargin: {
            var ret = 0;
            for (var i = 0; i < visibleChildren.length; ++i) {
                var child = visibleChildren[i];
                ret += (child.implicitMargin || 0);
            }
            return ret / visibleChildren.length;
        }

        Repeater {
            id: operations
            model: ["÷", "×", "+", "-"]
            Button {
                y: 0
                x: index * width
                width: parent.width / 4
                height: parent.height / 5
                color: pressed ? "#5caa15" : "#80c342"
                text: modelData
                fontHeight: 0.4
                onClicked: statemachine.submitEvent(eventName)
                property string eventName: {
                    switch (text) {
                    case "÷": return "OPER.DIV"
                    case "×": return "OPER.STAR"
                    case "+": return "OPER.PLUS"
                    case "-": return "OPER.MINUS"
                    }
                }
            }
        }

        Repeater {
            id: digits
            model: ["7", "8", "9", "4", "5", "6", "1", "2", "3", "0", ".", "C"]
            Button {
                x: (index % 3) * width
                y: Math.floor(index / 3 + 1) * height
                width: parent.width / 4
                height: parent.height / 5
                color: pressed ? "#d6d6d6" : "#eeeeee"
                text: modelData
                onClicked: statemachine.submitEvent(eventName)
                property string eventName: {
                    switch (text) {
                    case ".": return "POINT"
                    case "C": return "C"
                    default: return "DIGIT." + text
                    }
                }
            }
        }

        Button {
            id: resultButton
            x: 3 * width
            y: parent.height / 5
            textHeight: y - 2
            fontHeight: 0.4
            width: parent.width / 4
            height: y * 4
            color: pressed ? "#e0b91c" : "#face20"
            text: "="
            onClicked: statemachine.submitEvent("EQUALS")
        }
    }
}