今天，給大家介紹一個Microsoft365（原Office365）Excel新增函數--XLOOKUP函數。ps：還沒用上Microsoft365的後臺聯繫我，免費安裝！
函數說明：
作用：
XLOOKUP 函數搜索區域或數組，然後返回對應於它找到的第一個匹配項的項。如果不存在匹配項，則 XLOOKUP 可以返回最接近 (匹配) 值。
語法：
XLOOKUP(lookup_value,lookup_array, return_array, [if_not_found], [match_mode], [search_mode])
參數：
lookup_value：必需，要查找的值
lookup_array：必需，要查找的數組或區域
return_array：必需，要返回的數組或區域
[if_not_found]：可選，如果找不到有效的匹配項，則返回此參數，忽略則顯示#N/A錯誤。
[match_mode]：可選，指定匹配類型：
0 - 精確匹配。如果未找到，則返回 #N/A。這是默認選項。
-1 - 模糊匹配。如果沒有找到，則返回下一個較小的項。
1 - 模糊匹配。如果沒有找到，則返回下一個較大的項。
2 - 通配符匹配，其中 *, ? 和 ~ 有特殊含義。
[search_mode]：可選，指定要使用的查找方式：
1 - 從第一項開始執行搜索。這是默認選項。
-1 - 從最後一項開始執行反向搜索。
2 - 執行依賴於 lookup_array 按升序排序的二進制搜索。如果未排序，將返回無效結果。
-2 - 執行依賴於 lookup_array 按降序排序的二進制搜索。如果未排序，將返回無效結果。
用法示例：
1單條件精確查詢
查找各個人的電話號碼。
公式：=XLOOKUP(E2,A:A,C:C)
2屏蔽錯誤值
查找各個人的電話號碼，找不到的就顯示“找不到”。
公式：=XLOOKUP(E2,A:A,C:C,"找不到")
3單條件模糊查詢
查找姓名包含“麻子”的特長。
公式：=XLOOKUP("*"&E2&"*",A:A,B:B,"找不到",2)
4區間查詢
根據分數區間查詢每個學生的等級。
公式：=XLOOKUP(C2,$F$2:$F$5,$G$2:$G$5,,-1)
5從後往前查
查找每個人最近一次的銷售額。
公式：=XLOOKUP(E2,$B$2:$B$11,$C$2:$C$11,"找不到",0,-1)
6橫向查找
查找張三的語文成績。
公式：=XLOOKUP(F1,B1:D1,B2:D2)
7返回標題排列順序一致的多列結果
返回標題排列順序一致的多列結果
公式：=XLOOKUP(F2,A:A,B:D)
8返回標題排列不一致的多列結果
返回標題排列不一致的多列結果
公式：=XLOOKUP($F2,$A$2:$A$11,XLOOKUP(G$1,$B$1:$D$1,$B$2:$D$11))
9多條件查詢
多條件查詢
公式：=XLOOKUP(E2&F2,$A$2:$A$11&$B$2:$B$11,$C$2:$C$11)
10引用使用
求2021年3月到2021年7月的銷售額總和。
公式：=SUM(XLOOKUP(E1,A2:A10,B2:B10):XLOOKUP(E2,A2:A10,B2:B10))
11向左查找
查找特長爲Power Query的人的姓名。
公式：=XLOOKUP(D2,B:B,A:A)
寫在最後：
作者只是拋磚引玉，更多更強大的功能等你來發現！
▼近期好文推薦▼
—END—