SQL分頁存儲過程

CREATE PROCEDURE [dbo].[sp_All_Pager] 
      @tblName nvarchar(255),--表名 
      @fldNames nvarchar(1000)='*',--字段列表(默認所有字段)
      @fldOrderName nvarchar(255),--主鍵字段(排序用) 
      @orderType bit =0,--排序類型,非0則降序(默認升序) 
      @pageIndex int=1,--頁碼 
      @pageSize int =20,--頁大小 
      @strWhere nvarchar(1500)='',--查詢條件,不帶where 
      @limitCount int =5000, --限制最多取5000條數據 
      @totalCount int output --總記錄數
  AS
  BEGIN
      SET NOCOUNT ON; 
      declare @strSQL nvarchar(4000)--主語句
      declare @strTable nvarchar(500)--主查詢臨時表 
      declare @strOrderSQL nvarchar(1000)--總數查詢語句 
      declare @strOutParam nvarchar(500)--輸出參數 
      declare @strTmp nvarchar(255)--臨時分頁字句 max 和min 
      declare @strOrder nvarchar(255)--排序參數    
      --設置排序 
      if(@orderType != 0)
      begin
          set @strTmp = ' <(select min '
          set @strOrder = ' order by [' + @fldOrderName +'] desc'
      end
      else
      begin
          set @strTmp = ' >(select max '
          set @strOrder = ' order by [' + @fldOrderName +'] asc'
      end
      --設置主查詢臨時表 
      if(@strWhere!='') 
          set @strTable='(select top '+STR(@limitCount)+' '+@fldNames+' from ['+@tblName+'] where '+@strWhere+') as tmpTable'
      else
          set @strTable='(select top '+STR(@limitCount)+' '+@fldNames+' from ['+@tblName+']) as tmpTable'
      --設置總數查詢語句和主語句 
      set @strOrderSQL=N'select @totalCountOut=count(1) from '+@strTable 
      set @strOutParam=N'@totalCountOut int output'
      if (@pageIndex = 1)
          set @strSQL = 'select top ' + str(@pageSize) +' '+@fldNames+ ' from ' + @strTable + @strOrder 
      else
          set @strSQL = 'select top ' + str(@PageSize) +' '+@fldNames+ ' from ' + @strTable + ' where [' + @fldOrderName + ']' + @strTmp + '(['+ @fldOrderName + ']) from (select top ' + str((@PageIndex-1)*@PageSize) + ' ['+ @fldOrderName + '] from ' + @strTable + @strOrder + ') as tblTmp) ' + @strOrder 
      exec sp_executesql @strOrderSQL,@strOutParam,@totalCountOut=@totalCount output
      exec sp_executesql @strSQL 
  END
  GO