在《【開篇】SAP ABAP性能優化 - 在哪些方面進行優化？》中介紹了在ABAP程序運行時，訪問不同位置數據的時間消耗。毫無疑問，ABAP程序在訪問DB進行相關的操作時，訪問數據的速度是最慢的，那麼如何儘可能地減少DB的訪問次數呢？
方法1：儘量使用內表進行數據庫的批量操作
這個原則很好理解，例如，要向數據庫中插入100條數據，那麼可以通過內表批量操作。
* -- Bad -- *
LOOP AT lt_sflight INTO ls_sflight.
INSERT INTO sflight VALUES ls_sflight.
ENDLOOP.
* -- Good-- *
INSERT INTO sflight FROM TABLE lt_sflight .
方法2：使用Join進行在DB層級進行數據的處理
如果通過JOIN能夠完成數據的處理，則儘可能減少在ABAP的AS進行處理。
* -- Bad -- *
SELECT carrid connid fldate
FROM sflight INTO (xcarrid, xconnid, xfldate)
WHERE planetype = '727-200'.
SELECT bookid FROM sbook INTO ybookid
WHERE carrid = xcarrid
AND connid = xconnid
AND fldate = xfldate.
WRITE: / xcarrid, xconnid, ybookid.
ENDSELECT.
ENDSELECT.
* -- Good-- *
SELECT f~carrid f~connid b~bookid
INTO (xcarrid, xconnid, ybookid)
FROM sflight AS f
INNER JOIN sbook AS b
ON f~carrid = b~carrid
AND f~connid = b~connid
AND f~fldate = b~fldate
WHERE planetype = '727-200'.
WRITE: / xcarrid, xconnid, ybookid.
ENDSELECT.
方法3：將常用的INNER JOIN創建成DDIC的JOIN VIEW
通過這種方式，在ABAP程序中，可以直接使用VIEW來讀取數據多個表的JOIN數據集。
方法4：使用子查詢
當需要對同一張表進行多次訪問時，可以考慮使用子查詢的方式，減少DB的訪問次數。
* 舉例：確定哪一天的航班預定出座位最多的？
* 方式1：雙層select。首先選擇出預定最多的航班信息，再確定具體的日期。
DATA: ls_sflight TYPE sflight,
lv_max TYPE i.
SELECT carrid connid MAX( seatsocc )
FROM sflight
INTO (ls_sflight-carrid, ls_sflight-connid, lv_max)
GROUP BY carrid connid.
SELECT fldate FROM sflight
INTO ls_sflight-fldate
WHERE carrid = ls_sflight-carrid
AND connid = ls_sflight-connid
AND seatsocc = lv_max.
WRITE: / ls_sflight-carrid, ls_sflight-connid, ls_sflight-fldate.
ENDSELECT.
ENDSELECT.
* 方式2：使用子查詢。單層SELECT直接選擇出航班信息和日期信息，將最大的座位數在子查詢中確定。
SELECT carrid connid fldate
FROM sflight AS f
INTO (ls_sflight-carrid, ls_sflight-connid, ls_sflight-fldate)
WHERE seatsocc IN ( SELECT MAX( seatsocc )
FROM sflight
WHERE carrid = f~carrid
AND connid = f~connid ).
WRITE: / ls_sflight-carrid, ls_sflight-connid, ls_sflight-fldate.
ENDSELECT.