此貼只有威望大於等於 0 的才能查看）
[這個貼子最後由xzf在 2005/08/31 00:21pm 第 4 次編輯]
前 言
因 EasyBoot 調用文件大多數是 IMG 映像文件, 而 IMG 映像文件編輯需要懂 DOS 命令, 但到現在懂 DOS 知識的人越來越不多了，在做 IMG 映像文件時，論壇上到處求助幫助說，這個應該這樣寫那個應該是怎樣寫，爲了大家的學習，首先需要從DOS的基本學起，所以我花費一點時間來寫一篇從 DOS 基礎開始的詳細解說到製作 IMG 映像文件的實戰教程，希望大家能學到一點 DOS 知識和經驗，在本教課程過程中有需要用到文件和小工具我會提供上來的，大家不必亂找，和廢時間， 但我本人時間有限，不能及時發上課教程上來時不要心急，需耐心等待哦。
一、在本教課程中如有 DOS 前輩高手來閱覽時， 希望前輩指出有不到之處的地方，望前輩指正錯誤，以免誤導大家，我衷心的感謝前輩的指出。
二、這篇文章大多數是蒐集自網上，但經我整理和加入我自己的一併發上來，希望大家仔細閱讀和實例式式，不然是很難理解的。只有你自己請自使用過，纔會明白用意哦。
注：未經同意, 不準轉貼, 謝謝合作! QQ 羣號: 11175590
第一課 基本 DOS 命令集詳細解說
path 指向路徑命令:
path=c:\dos;c:\windows;c:\ 這條命令就是說，當我們執行一個文件時，
電腦先在當前目錄下查找這個文件，找到則執行，如果沒有找到，則電腦按照
path命令所指定的目錄順序去查找，先在C盤dos目錄下，然後在windows目錄
下，最後在C盤根目錄下尋找這個文件
edit 編輯命令:
edit w.bat回車（就是編輯 w.bat文件的意思）
ren 改名命令:
例如把abc.txt改成bne.dat，就可以輸入ren abc.txt bne.dat。
type 查看命令:
我想知道abc.txt文件的內容，就從鍵盤上輸入type abc.txt 。
diskcopy 磁盤複製命令:
diskcopy命令的格式很簡單：diskcopy 源驅動器名 目的驅動器名。舉個例子來
說，如果要在A驅動器上覆制磁盤，就輸入：diskcopy a: a: （奇怪吧，哪來兩
個Ａ盤，且看下文電腦是如何理解的）。
chkdsk 磁盤查看命令:
就輸入chkdsk C:
cd 改變當前目錄命令:
用法,就輸入cd abc
sys 製作DOS系統盤命令:
用法,就輸入sys a:
copy 拷貝文件命令:
用法,就輸入copy c:\abc.txt a:\
del 刪除文件命令:
用法,就輸入 del c:\abc.txt
deltree 刪除目錄樹命令:
用法,就輸入 deltree c:\abc
dir 查看命令:
用法,就輸入 dir 如:
用法1、dir /w
用法2、dir /p
用法3、dir /w/p
format 格式化磁盤命令:
用法1,就輸入format a:(完全格式化不帶任何信息)
用法2,就輸入format a:/q(快速格式化不帶任何信息)
用法3,就輸入format a:/s(完全格式化並寫入DOS啓動主文件)
用法4,就輸入format a:/q/s(快速格式化並寫入DOS啓動主文件)
md 建立目錄命令:
用法,就輸入md abc
mem 查看內存狀況命令:
用法,就輸入mem
rd 刪除目錄命令:
用法,就輸入rd abc
cls 清屏命令:
用法,就輸入cls
適用場合:屏幕上太亂了，或是屏幕上出現亂碼了， 清除屏幕上顯示內容但不影響
電腦內部任何信息.
move 移動文件與改目錄名:
用法,就輸入c:\>move c:\autoexec.bat c:\old (移動autoexec.bat文件至old目錄下)
用法,就輸入c:\>move c:\config.sys c:\temp (移動config.sys文件至temp目錄下)
more 分屏顯示命令:
用法,就輸入C:\>type msdos.w40 | more
適用場合:當輸出很多一屏顯示不下時採用，幾乎適合所有命令，尤其是type等命令
時很有用。 使用more時磁盤不能有寫保護，也不適合光驅。
xcopy 拷貝目錄和文件命令:
用法,就輸入xcopy *.* [目錄] /s
適用場合:在進行連同子目錄一起拷貝時很有用，在拷貝大量文件時比COPY命令要快得多 .
attrib 設置文件屬性命令:
用法1,就輸入attrib +r abc.txt
用法2,就輸入attrib +h *.* /s? 隱含所有文件
參數:
attrib +r或-r [文件名] 設置文件屬性是否爲只讀
attrib +h或-h [文件名] 設置文件屬性是否隱含
attrib +s或-s [文件名] 設置文件屬性是否爲系統文件
attrib +a或-a [文件名] 設置文件屬性是否爲歸檔文件
attrib /s 設置包括子目錄的文件在內的文件屬性
date 顯示及修改日期命令:
用法,就輸入C:\>date 03-20-2005? 將日期改爲2005年3月20日
lable 設置卷標號命令:
用法,就輸入label [盤符] [卷標名] 設定指定盤的卷標
例 子 C:\>label?
Volume in drive C is WANG
Volume Serial Number is 2116-1DD0
volume label (11 characters,Enter for none)?
可以輸入卷標，直接回車後
Delete current volume label (Y/N)?
按y刪除舊卷標，按n不更改
defrag 磁盤碎片整理命令:
用法,就輸入C:\>defrag
doskey 調用和建立DOS宏命令命令:
用法,就輸入 doskey /reinstall 重新安裝doskey
doskey /bufsize= 設置緩衝區的大小
doskey /macros 顯示所有doskey宏
doskey /history 顯示內存中所有命令
doskey /insert|overstrike 設置新鍵入的字符是否覆蓋舊的字
例 子］ C:\>DOSKEY?
C:\>dir
C:\>copy C:\temp\*.* a:
C:\>del c:\temp\*.*
C:\>copy b:\*.* c:\temp
C:\>doskey di=dir/w/p? 定義di爲宏命令，意思是執行dir/w/p
fdisk 硬盤分區命令:
用法,就輸入fdisk後按回車即可進入提示界面
emm386 擴展內存管理命令:
用法 lh [程序]
將程序裝入高端內存 使用此命令時，config.sys文件中需有下面兩條語句。
device=emm386.exe dos=umb
lh [程序] /l:區號 將程序裝入指定的umb區
lh /s 一般是由memmaker專用
例子: C:\MOUSE\>lh mouse? 將鼠標驅動程序裝入高端內存
memmaker 內存優化管理命令:
用法,就輸入C:\>memmaker 回車,出現提示一直回車 2. 回車繼續，F3退出
msd 系統檢測命令:
用法,就輸入 C:\>msd 回車後可見到實例
undelete 恢復被刪除的文件命令:
用法,就輸入undelete
undelete /all 恢復文件且不再詢問是否恢復
undelete /list 列可恢復的文件名
prompt 設置提示符命令:
適用場合:當你厭煩了c:\>的提示符或者您想使您的提示符與衆不同時，您可以
試一試，非常有趣的DOS命令，可以隨時顯示時間與日期。
［用法］ prompt $p$g 以當前目錄名和>號爲提示符，這是最常用的提示符
prompt $t 表示時間 prompt $d 表示日期
prompt $$ 表示$ prompt $q 表示=
prompt $v 表示當前版本 prompt $l 表示<
prompt $b 表示| prompt $h 表示退位符
prompt $e 表示Esc代表的字符 prompt $_ 表示回車換行
［例子］ C:\DOS>prompt wang$g? 將wang>作爲提示符
WANG>prompt $t$d$g? 使用時間、日期和>號做爲提示符
0:01:07.77Thu 08-29-1996>prompt $p$g?
C:\DOS>
restore 恢復已備份的文件命令:
建議:如果以前用backup做過文件備份，則當原文件損壞時可以用它來恢復
文件,將用backup命令備份的磁盤中的文件恢復到另一磁盤中，備份磁盤中
應有backup.00X和control.00X這兩條文件。
［用法］ restore [備份盤符] [目標盤符]
將備份盤上備份文件恢復到指定盤上
restore /s 將備份文件包括子目錄都恢復到指定盤上
restore /p 讓用戶判斷是否恢復文件
restore /b:日期 恢復日期以前的文件
restore /a:日期 恢復日期之後的文件
restore /l:時間 恢復時間之前的文件
restore /e:時間 恢復時間之後的文件
restore /m 只恢復上次備份後修改過的文件
restore /n 只恢復上次備份後已刪 除的文件
restore /d 只顯示要恢復的文件名
［例子］ C:\DOS>restore a: c:?
Insert backup diskette 01 in drive A:
Press any key to continue . . .
在A驅中放入第一張備份盤，按任意鍵即可，恢復完第一張後，按順
序放入其它盤即可。
當您用上述命令不能正確恢復文件時請用：
C:\DOS>restore a: c:\ /s
time 顯示及修改時間命令:
用法,就輸入time 即可按提示修改,不修改按回車忽略修改
set 設置環境變量命令:
用法,就輸入set [環境變量]=[字符串]
例子: C:\>set path=c:\dos 與path c:\dos含義相同, 這條命令常常用在autoexec.bat中
smartdrv 設置磁盤加速器命令:
用法,它可以提高硬盤訪問速度，最好在autoexec.bat文件中加載吧。
用法: smartdrv /x
執行並駐留內存，開闢磁盤加速緩存區，並屏蔽所有驅動器緩存，是
較常用的方法（一般用這個命令就夠了）
smartdrv /c 將緩存內的信息都寫入硬盤
smartdrv /e: 數字 設置一次移動的信息量
smartdrv /b: 數字 設置預先讀取的緩衝區大小
append 設置非執行文件的路徑命令:
適用場合: 當您無法在多個目錄中尋找到自己輸入的文稿時，可以試一試這
個命令，用法類似path。
用法: append [路徑];[路徑]
例子: C:\>append c:\test?
設置尋找非可執行文件路徑爲c:\test如果該目錄下有文件1.txt時，
在其它目錄下調用1.txt找不到時，可自動尋找到c:\test目錄。
D:\UCDOS>edit 1.txt 可找到C:\test\1.txt文件
debug 程序調試命令:
如果你學過彙編語言，那你應該會使用debug，如果沒學過，最好別使用.
用法 debug [文件名]
diskcomp 比較磁盤命令:
適用場合: 比較兩張盤是否相同，沒想到什麼時候會用到，在比較用
diskcopy拷貝的兩張盤，爲什麼不用diskcopy/v校驗呢？
［用法］diskcomp [盤符1] [盤符2] 比較盤1和盤2
diskcomp /1 只比較磁盤的第一面
diskcomp /8 只比較沒磁道的前8個扇區
［例子］C:\>diskcomp a: a:
在同一軟驅中比較兩張盤
Insert FIRST diskette in drive A:
放入第一張盤
Press any key to continue . . .
Comparing 80 tracks 18 sectors per track, 2 side(s)
Insert SECOND diskette in drive A:
放入第二張盤
Press any key to continue . . . Compare OK
比較未發現不同
Compare another diskette (Y/N) ?n
是否比較其它盤，選y繼續比較，選n停
expand 解壓工具命令:
微軟公司軟件原始安裝盤中有許多後綴以"_"結尾的壓縮文件，可以用它解壓，
解除您因爲少數幾個文件丟失造成的麻煩。(Windows下用Winrar就可以解壓)
用法,C:\>expand a:vsafe.co_ c:\dos\vsafe.com
fasthelp 快速顯示幫助信息命令:
用法,在DOS下輸入abc.exe /fasthelp 同/?
fc 文件比較命令:
用法,就輸入fc[文件名1][文件名2]比較兩文件的不同參數還有: a c l Lbn n t w nnnn
subst 路徑替換命令:
用法 subst 顯示當前的替代路徑
subst [盤符] [路徑]
將指定的路徑替代盤符，該路徑將作爲驅動器使用
subst /b 解除替代
［例子］C:\DOS>subst a: c:\temp? 用c盤temp目錄替代a盤
C:\>subst a: /d? 解除替代
[這個貼子最後由xzf在 2005/08/31 00:21pm 第 4 次編輯]
前 言
在這篇裏解說的是批處理中所常要用到的一些命令和作用, 請仔細閱讀, 配合上一篇的解說, 記住這些命令和作用, 你就能夠明白 DOS 的工作原理了, 也就能修改自己所需要用的功能了, 這篇就寫到這裏。
注：未經同意, 不準轉貼, 謝謝合作! QQ 羣號: 11175590
第二課 基本 DOS 批處理詳細解說
一、echo、@、call、pause、rem 是批處理文件最常用的幾個命令，我們就從他們
開始學起
echo 表示顯示此命令後的字符
echo off 表示在此語句後所有運行的命令都不顯示命令行本身
@ 與echo off相象，但它是加在其它命令行的最前面，表示運行時
不顯示命令行本身。
call 調用另一條批處理文件（如果直接調用別的批處理文件 ，執行完
那條文件後將無法執行當前文件後續命令）
pause 運行此句會暫停，顯示 Press any key to continue... 等待用戶
按任意鍵後繼續
rem 表示此命令後的字符爲解釋行，不執行，只是給自己今後查找用的
二、if 、goto 、choice 、for 是批處理文件中比較高級的命令，如果這幾個你用
得很熟練，你就是批處理文件的專家啦。
if 表示將判斷是否符合規定的條件，從而決定執行不同的命令。 有三種格式:
1、if "參數" == "字符串" 待執行的命令
參數如果等於指定的字符串，則條件成立，運行命令，否則運行下一句。
(注意是兩個等號）
如：if "%1"=="a" format a:
2、if exist 文件名 待執行的命令
如果有指定的文件，則條件成立，運行命令，否則運行下一句。
如：if exist config.sys edit config.sys
3、if errorlevel 數字 待執行的命令
如果返回碼等於指定的數字，則條件成立，運行命令，否則運行下一句。
如if errorlevel 2 goto x2 DOS程序運行時都會返回一個數字給DOS，
稱爲錯誤碼errorlevel或稱返回碼
goto 批處理文件運行到這裏將跳到goto 所指定的標號處，一般與 if 配合使用。
如:
goto end
:end
echo this is the end
: 這是標號字符(所在位是冒號),是用來執行被 goto 跳轉所用的標號字符，
標號所在行是不會被執行,如:
:end 等等...
choice 使用此命令可以讓用戶輸入一個字符，從而運行不同的命令。使用時應該
加/c:參數，c:後應寫提示可輸入的字符，之間無空格。它的返回碼爲1234……
如: choice /c:dme defrag,mem,end
將顯示
defrag,mem,end[D,M,E]?
例如，test.bat的內容如下:
@echo off
choice /c:dme defrag,mem,end
if errorlevel 3 goto defrag 應先判斷數值最高的錯誤碼
if errorlevel 2 goto mem
if errotlevel 1 goto end
:defrag
c:\dos\defrag
goto end
:mem
mem
goto end
:end
echo good bye
此文件運行後，將顯示 defrag,mem,end[D,M,E]? 用戶可選擇d m e ，
然後if語句將作出判斷，d表示執行標號爲defrag的程序段，m表示執行
標號爲mem的程序段，e表示執行標號爲end的程序段，每個程序段最後都
以goto end將程序跳到end標號處，然後程序將顯示good bye，文件結束。
for 循環命令，只要條件符合，它將多次執行同一命令。
格式FOR [%%f] in (集合) DO [命令]
只要參數f在指定的集合內，則條件成立，執行命令
如果一條批處理文件中有一行:
for %%c in (*.bat *.txt) do type %%c
含義是如果是以bat或txt結尾的文件，則顯示文件的內容。
device和devicehigh
加載一些內存駐留程序，用於管理設備。比如內存管理程序和
光驅驅動程序等。
如： device=c:\dos\himem.sys
device=c:\dos\emm386.exe ram
devicehigh=c:\cdrom\cdrom.sys
himem.sys和emm386.exe
DOS只能直接使用640K的內存，即基本內存，必須依靠其它內存管理程序來
使用更多的內存，這兩條命令就是最常用的內存管理程序。
himem.sys 負責管理擴展內存。
emm386.exe 負責管理高端內存並在擴展內存中模擬擴充內存供某些軟件使用。
爲了使用更多的內存，配置文件中應有:
device=c:\dos\himem.sys
device=c:\dos\emm386.exe ram
注意：EMM386.exe 要求先安裝 himem.sys，因而必須確保
安裝 himem.sys 的配置命令在 emm386.exe 之前。
dos=high,umb 這兩個參數也可以分開寫成兩條語句，即：
dos=high
dos=umb
應在config.sys中加入這條命令，這樣會將DOS的系統文件移入高端
內存，空出更多的基本內存給其它軟件使用。 注意，如果用戶沒有
安裝emm386.exe，umb這個參數是沒有實際意義的
lastdriver lastdriver 規定用戶可以訪問的最大驅動器符數目，也就是DOS所能
識別的最後的驅動器符(字母)。如果設定的驅動器符數目小於本機上
的實際驅動器數，則此lastdriver命令會被忽略掉。缺省的最大驅動
器符數目爲本機的實際驅動器數目加一。
:: 二個冒號，它和批處理文件中的 rem 含義相同，即註釋
ramdrive.sys 虛擬磁盤文件。
只要在 config.sys 中加入 device=ramdrive.sys 就可使用虛擬磁盤了
比如:
device=c:\dos\ramdrive.sys 1024 /e
表示在擴展內存中建立 1M 的虛擬磁盤。如果加/a參數，則表示在擴充
內存中建立虛擬磁盤。
%CDROM% %CDROM%是光驅盤符的變量字符串,用它可以把所在的任意光驅盤符替爲
真實盤符, 需要與光驅驅動模塊一同執行,如:
LH \MSCDEX.EXE /D:mscd001 /L:%CDROM%
%RAMD% %RAMD%是隨機虛擬磁盤, 此盤創建在擴展內存中, 建立此盤的模塊就是
ramdrive.sys ,見上面的“虛擬磁盤文件”說明。
另外這個虛擬內在還有更強大的虛擬內存管理器，可以超過64MB的內存
管理，就是 XMSDSK.EXE 與 EMSDSK.EXE，
第三課 Windows 98 啓動盤的詳細講解
在開始前選講一下 Windows 98 啓動盤的特徵和功能，現已對 Windows 98 的
啓動盤作了很大的更改。下列各項是針對 Windows98 的新增特性。
- 多配置啓動菜單
- 實模式 CD-ROM 支持
- EBD.CAB 文件
- RAMDRIVE
- WINDOWS98 啓動問題
- 使用啓動盤上的工具
多配置啓動菜單
==============
如果用新的 Windows98 啓動盤啓動計算機，那麼，系統將顯示引導菜單，用於
加載常用CD-ROM 驅動器或執行正常的乾淨引導。進行選擇之後，Config.sys
文件就加載對應的 CD-ROM 驅動程序（如果已經選定），然後加載 2MB RAMDrive。
RAMDrive 存儲解決常見問題所必須的診斷工具。
要注意是：
RAMdrive 可能導致 CD-ROM 的驅動器號向後順延一個字母。如果 CD-ROM 常爲
驅動器 D:，現在可能就變爲驅動器 E:。
實模式 CD-ROM 驅動程序
=====================
Windows 98 啓動盤中含有常規的 ATAPI IDE 和 SCSI CD-ROM 驅動程序，
使用此驅動程序，即使 Windows98 GUI 不可用，CD-ROM 也可在 DOS 中
正常工作。
注意，並不支持所有 CD-ROM 驅動器。如果使用這些驅動程序時，CD-ROM
驅動器無法正常工作，那麼，就必須使用 CD-ROM 驅動器所附帶的驅動程序。
Windows 98 啓動盤裏面共有文件 24 個, 下面先把這 24 個文件
的功能和作用作個詳細說明。啓動盤的文件如下：
=================================================================
文件 功能
Aspi2dos.sys 實模式的 Adaptec CD-ROM 驅動程序
Aspi4dos.sys 實模式的 Adaptec CD-ROM 驅動程序
Aspi8dos.sys 實模式的 Adaptec CD-ROM 驅動程序
Aspi8u2.sys 實模式的 Adaptec CD-ROM 驅動程序
Aspicd.sys 實模式的 Adaptec CD-ROM 驅動程序
Autoexec.bat 啓動批處理文件（也就是我們常要修改的文件，在啓動時用到的
第五個文件，一般來說也就是最後一個啓動時用到的文件，當它
執行完後，基本完成了操作，計算機就等待着你執行以後程序或
命令了）
Btcdrom.sys Mylex/BusLogic CD-ROM 驅動程序
Btdosm.sys Mylex/BusLogic CD-ROM 驅動程序
Command.com DOS 命令解釋程序（在啓動時用到的第四個文件）
Config.sys 加載設備驅動程序（這個也是我們常要修改的文件，很重要的一個，
在啓動時用到的第三個文件）
Drvspace.bin Microsoft 磁盤空間管理壓縮驅動程序
Ebd.cab 包含解壓縮實用程序的 Cab 文件
Ebd.sys EBD 標識的文件
Extract.exe 解壓 Ebd.cab 文件的文件
Fdisk.exe 磁盤分區工具
Findramd.exe 啓動過程中查找 RAMDrive 的實用程序
Flashpt.sys Mylex/BusLogic CD-ROM 驅動程序
Himem.sys XMS 內存管理程序
Io.sys 系統引導文件（在啓動時第一個用到的文件）
Msdos.sys 引導選項信息、路徑、多層引導等等（在啓動時第二個用到的文件）
Oakcdrom.sys ATAPI CD-ROM 驅動器的通用設備驅動程序
Ramdrive.sys 啓動時創建 Ramdrive （也就是這個變量符 %RAMD% 是隨機虛擬磁盤）
Setramd.bat 搜索第一個可用作 Ramdrive 的虛擬磁盤驅動器
下面是 Windows 98 啓動盤裏的 EBD.CAB 文件
===========================================
Ebd.cab 文件是一個壓縮文件，在啓動時，其內容被解壓縮釋放至 Ramdrive
虛擬磁盤下，也就是仿真物理硬盤。下面順便先講說一下這個 Ramdrive 的創建。
創建 RAMDrive 虛擬磁盤即仿真物理硬盤
======================================
RAMDrive 是在處理 Config.sys 文件的過程中予以創建的，其大小爲 2MB。
Ramdrive 是用系統 RAM 創建的，用以仿真物理硬盤。如果不創建 RAMdrive 虛擬
硬盤（仿真物理硬盤），在單張 1.44 MB 的軟盤上就沒有足夠的空間存放診斷工具
以及 CD-ROM 驅動程序。
警告：
由於 RAMDrive 是在處理 Config.sys 文件的過程中用由系統 RAM 予以創建的，
因此，它只臨時存在。如果正常重啓動計算機，它將消失。
下面列出了 Ebd.cab 文件中所包含的文件及功能。
================================================
文件 功能
Attrib.exe 添加或刪除文件屬性
Chkdsk.exe 小而簡單的磁盤狀態工具
Debug.exe 調試實用程序
Edit.com 實模式的緊急文本編輯器
Ext.exe 新的簡單文件提取實用程序
format.com 磁盤格式化工具
Mscdex.exe 用於 MS-DOS 的 Microsoft CD-ROM 文件擴展
Scandisk.exe 磁盤狀態工具
Scandisk.ini 磁盤狀態工具配置文件
Sys.com 傳輸系統文件，將磁盤製成啓動盤
好了，到此我們已經講了 Windows98 啓動盤的各個文件的用途和作用，下面開始
講解我們常要修改的二個文件了，
1、Windows98 啓動盤啓動的過程如下：
啓動過程：開機後從→IO.SYS→MSDOS.SYS→CONFIG.SYS→COMMAND.COM→AUTOEXEC.BAT
一般來說我們需要修改的是 CONFIG.SYS 和 AUTOEXEC.BAT 而涉及到啓動光盤製作的則
主要就是這二個 CONFIG.SYS 和 AUTOEXEC.BAT 文件。
2、CONFIG.SYS 文件內的詳細講解
========================================================================
[menu] 這是啓動時顯示的菜單選頂
menuitem=CD, Start computer with CD-ROM support. 選擇這項後啓動時帶光驅支持
menuitem=NOCD, Start computer without CD-ROM support. 選擇這項後啓動時不帶光驅支持
menuitem=HELP, View the Help file. 選擇這項啓動後進入查看幫助文件
menudefault=CD,30 這項是顯示等待進入的時間，默認爲30秒，可以自己設定。
menucolor=7,0 這項是屏幕顯示顏色，默認是黑底白字。詳細如下：
0= 黑色 1=藍色 2=綠色 3=青色 4=紅色 5=紅紫色 6=棕色 7=白色 8=灰色
9=淡藍色 10=淡綠色 11=淡青色 12=淡紅色 13=淡紅紫色 14=黃色 15=淡白色
[CD] 這個標籤是當菜單選項選擇了 CD 標籤就對應着執行這項
device=himem.sys /testmem:off 這項是 XMS 內存管理程序
device=oakcdrom.sys /D:mscd001 這項是 ATAPI CD-ROM 驅動器的通用設備驅動程序
device=btdosm.sys 這項是 Mylex/BusLogic CD-ROM 驅動程序
device=flashpt.sys 這項是 Mylex/BusLogic CD-ROM 驅動程序
device=btcdrom.sys /D:mscd001 這項是 Mylex/BusLogic CD-ROM 驅動程序
device=aspi2dos.sys 這項是 實模式的 Adaptec CD-ROM 驅動程序
device=aspi8dos.sys 這項是 實模式的 Adaptec CD-ROM 驅動程序
device=aspi4dos.sys 這項是 實模式的 Adaptec CD-ROM 驅動程序
device=aspi8u2.sys 這項是 實模式的 Adaptec CD-ROM 驅動程序
device=aspicd.sys /D:mscd001 這項是 實模式的 Adaptec CD-ROM 驅動程序
[NOCD] 這個標籤是當菜單選項選擇了 NOCD 標籤就對應着執行這項
device=himem.sys /testmem:off 這項是 XMS 內存管理程序
[HELP] 這個標籤是當菜單選項選擇了 HELP 標籤就對應着執行這項
device=himem.sys /testmem:off 這項是 XMS 內存管理程序
[COMMON] 這個是公用標籤
files=10 這項是允許同時打開的文件個數，默認是10個文件，一般不要超過 30 個文件
buffers=10 這項是設置系統的磁盤緩存塊數，默認是10塊數，一般不要超過 30 個文件
dos=high,umb 這項是把 DOS 載入到高端內存
stacks=9,256 這項是設置DOS堆棧的個數
devicehigh=ramdrive.sys /E 2048 這項是設置虛擬盤即仿真物理硬盤並設置大小爲2MB
lastdrive=z 這項是設置最後盤符爲 Z ，也就是說最大不能超過這個值
3、AUTOEXEC.ABT 文件內的詳細講解
======================================================
@ECHO OFF 這項是不顯示 DOS 屏幕提示
set EXPAND=YES 這項是設置解壓爲自動，也就是 EBD 的解壓
SET DIRCMD=/O:N
set LglDrv=27 * 26 Z 25 Y 24 X 23 W 22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15
set LglDrv=%LglDrv% O 14 N 13 M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
以上三條是設置虛擬內存的參數
cls 這是清屏命令
call setramd.bat %LglDrv% 這項是調用 setramd.bat 文件並設置虛擬磁盤的內存
set temp=c:\ 這項是設置臨時文件夾路徑爲 C 盤
set tmp=c:\ 這項是設置臨時文件夾路徑爲 C 盤
path=%RAMD%:\;a:\;%CDROM%:\ 這項是設置系統環境變量，在DOS下就不用來回切換盤符了
copy command.com %RAMD%:\ > NUL 這項是複製 command.com 到虛擬盤中
>NUL 是在屏幕上不顯示執行後的結果
set comspec=%RAMD%:\command.com 這項是設置 DOS 命令解釋器的路徑爲 %RAMD%:\command.com
copy extract.exe %RAMD%:\ > NUL 這項是複製 extract.exe 到虛擬盤中 >NUL 同上
copy readme.txt %RAMD%:\ > NUL 這項是複製 readme.txt 到虛擬盤中 >NUL 同上
:ERROR 這項是錯誤的提示標籤
IF EXIST ebd.cab GOTO EXT 這項是如果 ebd.cab 文件存在就跳轉到 EXT 標籤
echo Please insert Windows 98 Startup Disk 2 這項是如果 ebd.cab 文件不存在
屏幕上就將顯示“請插入 Windows 98 啓動盤 2”
echo. 這項是空一行
pause 這是項是執行到這裏時就暫停，屏幕上就顯示“Press any key to continue...”
意思是按任意鍵繼續...
GOTO ERROR 這項是跳轉到 ERROR 標籤
:EXT 這項是被跳轉過來的標籤，（就是這項 IF EXIST ebd.cab GOTO EXT）
%RAMD%:\extract /y /e /l %RAMD%: ebd.cab > NUL
在虛擬內存中執行 extract.exe，把 ebd.cab 裏面的文件解壓到虛擬盤中
echo The diagnostic tools were successfully loaded to drive %RAMD%.
這行是在屏幕上提示“診斷工具已經成功的載入內存"X"”X是你虛擬內存的盤符中
echo. 空一行
IF "%config%"=="NOCD" GOTO QUIT 如果你在 config.sys 標籤中選擇 NOCD 轉到 QUIT 標籤
IF "%config%"=="HELP" GOTO HELP 如果你在 config.sys 標籤中選擇 HELP 轉到 HELP 標籤
LH %ramd%:\MSCDEX.EXE /D:mscd001 /L:%CDROM% 這項是加載光驅命令並自動分配一個光盤符
echo. 空一行
GOTO QUIT 跳轉到 QUIT 標籤
:HELP 這項是幫助標籤，是在 config.sys 標籤中選擇 HELP 轉到這裏的標籤
cls 清屏命令
call help.bat 這項是調用幫助文件的命令
echo Your computer will now restart and the startup menu will appear.
這條是，當 HELP.BAT 這條命令執行完後屏幕上就顯示“你的計算機現在將重新啓動”
echo. 空一行,以下均是空一行
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
restart.com 這個就是重新啓動計算機的執行程序
GOTO QUIT 這項是跳轉到 QUIT 標籤
:QUIT 這項是跳轉標籤, 是由上面跳轉過來的
echo To get help, type HELP and press ENTER.
這項是屏幕上提示你，輸入“help”後回車來查看幫助文件。
echo. 空一行
rem clean up environment variables 這項是清理所有上面設置過的環境變量
set CDROM= 這項是設置 CDROM 爲盤符, 由變量而定
set LglDrv= 這項是設置虛擬磁盤爲盤符, 由變量而定
特別注意要點:
config.sys 裏的 menuitem=CD 和 下面 [CD] 還有 autoexec.bat 裏的 [CD] 一定
要保持一致，否則系統會找不到該執行的程序。依此類推....
device=oakcdrom.sys /D:mscd001 光驅驅動 命名爲“mscd001”
光驅的名字也要和 autoexec.bat 裏面的保持一致，目的和上面一樣
下面還有 Windows 98 啓動問題講說一下
=====================================================================
本節包含部分常用的疑難解答步驟，在需要使用 Windows98 啓動盤時，就可
以按此步驟進行操作。這些步驟至少可將用戶引導到“安全模式”，這樣就可
獲取 Windows98 的擴展“幫助”系統以進一步解答所遇到的問題。
以安全模式啓動計算機
--------------------
Windows 98 啓動失敗的原因很多。檢測故障的第一步，是嘗試以安全模式啓動計算機。
若安全模式能正常工作，則可以使用位於“開始”菜單/“幫助”選項中的擴展“幫
助”系統和疑難解答。
>>>以安全模式啓動計算機：
1. 取出啓動盤，重新啓動計算機。計算機重新啓動之後，在 Windows 開始裝載前請按
住 CTRL 鍵，直到顯示“Windows 98 Startup Menu”。（如果運行的是 Windows 95，
在出現“啓動 Windows 95”提示時請按 F8。）
2. 選擇“Startup”菜單上的“Safe Mode”。
如果能以“安全模式”啓動計算機，請用 Windows 98 的“幫助”解決存在的問題。
安裝失敗和計算機不啓動
----------------------
Windows 98 安裝不能成功完全的常見原因有多種。下面的章節將解釋如何克服這些問
題。關於其他安裝問題的更詳細信息，請參閱 Windows 98 光盤或第一張安裝軟盤上
Win98 文件夾中的 Setup.txt 文件。
在運行安裝程序時如果遇到以下錯誤消息：
* 非法系統盤
* MS-DOS 版本不對
* Command.com 文件丟失或損壞
* 壓縮驅動程序錯誤
這很可能是計算機的啓動驅動器需要更新系統文件。可用 SYS 命令將需要的文件複製
到計算機上。
注意：如果您正在裝入壓縮軟件，則需要知道您的主驅動器代號。一般爲 H。如果沒有裝
入任何壓縮軟件，則需使用 SYS 命令將系統文件傳入 C 驅動器。
>>>使用 SYS 命令將系統文件複製到計算機上：
1. 用 Windows 98 啓動盤重新啓動計算機，在啓動菜單上選擇選項 2，然後按 ENTER。
2. 在 A:\ 提示符後面鍵入：SYS X: （其中 X 爲主或啓動驅動器）。
3. 如果上述過程成功，則顯示“System transferred”消息。如果不成功，請檢查鍵
入的主驅動器號是否正確。
要點：如果已經安裝了硬盤所附帶的軟件，請仔細閱讀文檔，以瞭解用軟盤啓動計算機
的詳細方法。
反病毒軟件
----------
如在安裝期間仍在運行反病毒軟件，那麼，它們可能阻礙安裝程序更新系統文件。若果
真如此，請禁用或卸載反病毒軟件，然後再運行安裝程序。
注意：有些計算機內置有反病毒軟件。在運行安裝程序之前也應當禁用這些內置的反病
毒軟件。如果不禁用它們，可能會收到警告消息，通知您主引導記錄已被更改。如果接
收到此類消息，就必須接受這些更改，否則安裝程序可能停止響應。
在檢測硬件時安裝程序停止響應
----------------------------
如果在檢測硬件時安裝程序停止響應，請關閉計算機稍等數秒鐘，然後再開機。可能需
要如此反覆多次，因爲安裝程序在多種不同的檢測模式中可能停止響應。
注意：關閉計算機的電源。不要用復位按鈕或 CTRL+ALT+DELETE 重新啓動計算機。
如果安裝仍然不能順利進行，可能需要以安全模式啓動計算機，以便查閱與硬件檢測有
關的幫助主題。
壓縮的驅動器未連接
------------------
不能訪問壓縮驅動器的原因很多。如果 Windows 目錄在一個尚未連接的驅動器上，則
無法啓動 Windows。如果懷疑壓縮驅動器有問題，請試用磁盤掃描程序來修復。
在 A:\ 提示符後面鍵入：
Scandisk /Mount X:
其中 X 爲壓縮驅動器號。磁盤掃描程序將會修復此磁盤並連接該驅動器。
如果沒有足夠的內存來檢查壓縮的磁盤，請參閱第一張安裝軟盤或 Windows
98 光盤中 Setup.txt 文件的“從 MS-DOS 安裝 Windows 98”一節。
使用啓動盤上的工具
==================
本節介紹 Windows 98 啓動盤上所附帶的實用程序。運行這些工具的步驟如下：
1. 將 Windows 98 啓動盤插入軟盤驅動器，然後重新啓動計算機。
2. 在啓動菜單上選擇選項 1 或 2（取決於您是否要訪問CD-ROM），然後按 ENTER。
3. 在 MS-DOS 命令提示符 (A:\) 後面鍵入要運行的實用程序名稱，然後按 ENTER。
SCANDISK.EXE 和 CHKDSK.EXE
----------------------------
這兩個程序常用於檢查硬盤錯誤。如果您懷疑硬盤上有文件毀壞或存在其他問題，請運
行磁盤掃描程序來檢查並修復硬盤。
要檢查所有硬盤錯誤，請鍵入：
Scandisk /all
要掃描硬盤的所有表面，最大限度防止數據丟失，請鍵入：
Scandisk /all /Surface
注意：
您可能會收到關於長文件名的錯誤消息。MS-DOS 版本的磁盤掃描程序對於長文件名方
面的問題，只能檢測而無法糾正。要糾正此類錯誤，必須在 Windows 98 中運行磁盤掃
描程序。
如果您有壓縮磁盤，可能會收到“沒有足夠的內存來檢查壓縮磁盤”的消息。解決這個
問題的方法是：按照在本節前面的步驟 1 中介紹的方法，用 Windows 98 啓動盤來啓
動計算機。選擇選項 2。這樣便有足夠的內存，令磁盤掃描程序檢查壓縮的硬盤。
如果磁盤掃描程序不能檢查您的驅動器，請用 CHKDSK.EXE 試一試。CHKDSK 可以檢查
鏈接的文件和丟失的單元。
SYS.COM
=======
SYS 命令用於在盤與盤之間複製系統文件。這些系統文件是計算機啓動時必需的。
>>>向 C 盤傳輸系統，請鍵入：
SYS C:
然後按 ENTER。稍侯幾秒鐘，將出現“System transferred”消息。
執行 SYS 的結果，下述文件被複制到盤中：
* IO.SYS
* MSDOS.SYS
* COMMAND.COM
如果 SYS C: 命令未工作，而且 C 盤爲壓縮盤，則需要鍵入主驅動器名。如果使用
DblSpace 或 DrvSpace 程序，通常主驅動器爲 H 盤。如果您不知道該驅動器的號，
請運行 ScanDisk 並等待觀察有沒有關於壓縮磁盤的提示。
FDISK.EXE 和 formAT.EXE
------------------------
FDISK 和 formAT 實用程序是在機器中安裝新盤或清理舊盤時必需的。先用 FDISK 創
建分區，然後再用 formAT 格式化該分區以便使用。
警告： 使用 FDISK 不當可能會毀掉硬盤上的所有數據。如果不會使用 FDISK，先查閱
計算機文檔。
可以用 Windows 98 版本的 FDISK，在 512 兆以上的盤上創建 FAT32 分區。FAT32 減
少了較大驅動器上的簇的大小，並允許在 2 GB 以上的硬盤上創建單一的分區。
要查看當前驅動器的狀態，請在 MS-DOS 命令提示符後面鍵入： FDISK /STATUS。
用 FDISK 對磁盤分區之後，便該使用 formAT 命令。要格式化最新分區的驅動器，
請鍵入：
formAT X:
其中 X 爲要格式化的驅動器。
要格式化 C 盤，必須將此盤格式化爲系統盤，才能用它啓動計算機，請在 formAT 命
令後面鍵入 /s：
formAT C: /s
在該驅動器格式化之後，將自動複製系統啓動文件。
CD-ROM 驅動器
--------------
Windows 98 啓動盤包含一組通用的 CD-ROM 驅動程序。這些驅動程序可用於大多數
IDE ATAPI 和 SCSI CD-ROM 模式。
如果個別 CD-ROM 驅動器不能使用這些驅動程序，則需要使用 CD-ROM 驅動器所附帶的
驅動程序。
下面是關於 CD-ROM 驅動程序的已知問題：
1. 和聲卡連接的 CD-ROM 驅動器不能正常工作。
2. 早期的 CD-ROM 驅動器（例如 Mitsumi、Panasonic 和 Sony）可能不能使用這些
驅動程序。一些老的 IDE 控制器同樣不能使用。
3. 啓動盤上的 SCSI 驅動程序支持大多數 Adaptec、Buslogic 和 Mylex 適配器。有
些其他 SCSI CD-ROM 驅動器可能無法使用啓動盤上的驅動程序。
4. 如果 SCSI 控制器被配置爲非默認的 I/O 區域，則驅動程序可能不檢測您的 SCSI
卡。有關該卡的默認 I/O 區域，請參閱 SCSI 驅動程序文檔。
5. 不含許多 PC 卡 (PCMCIA) CD-ROM 驅動器的驅動程序。
EXT.EXE
-------
EXT 命令與 Extract.exe 實用程序連用，很容易將 Windows 98 文件摘取到硬盤。可
以用它恢復丟失或毀壞的文件。
如果在安裝時遇到“文件丟失”或“執行文件錯誤（如一般保護錯誤）”或“非法頁面
錯誤”的消息，則這個實用程序特別有用。
>>>用 Ext.exe 摘取文件的步驟：
1. 使用 Windows 98 啓動盤重新啓動計算機，選擇選項 1，然後按 ENTER。
2. 將 Windows 98 光盤插入驅動器。
3. 在 MS-DOS 命令提示符後面鍵入 EXT，然後按 ENTER。
4. 在提示後面輸入 Windows 98 安裝文件的位置、要抽取的文件位置和安放所抽取文
件位置。
注意：
如果 CD-ROM 驅動器號爲 E，則安裝文件的位置爲 E:\WIN98。
如果想一次摘取多個文件，可以使用通配
第四課 全自動安裝 Windows 98 詳細講解
一、利用 EasyBoot自帶的 setup98.img 啓動映像來改制自己的 Windows 98 全自動安裝盤,
這個文件我們已經有了，還要的就是做自動應答文件的工具了，這個工具在 Windows 98 安裝
盤裏，我還記得我第一次安裝 Windows 98 時候那種激動的心情，因爲第一次還不懂安裝，在
安裝過程中看着精美的畫面，伴隨着功能介紹，又順利的安裝着，這過程簡直就是一種享受。
隨着Windows 的不斷更新，在裏面安裝的軟件越多，系統也是越不穩定，重裝 Windowns 就成
了家常便飯。重複的事情做多了就覺得煩，在這個時候就還談上享受羅，只有折磨纔對了。
Windows 98 全自動的配置過程
選介紹一下 MS Batch 98 是一個可以讓 Windows 98 自動安裝的工具，使用 MS Batch 98
可以輕鬆地創建自動執行“Windows 98 安裝程序”的腳本（.INF文件）。在安裝 Windows 98
時，只要調用這個腳本文件，那麼在安裝程序將不在有提示信息，而是完全自動安裝。同時，它
還可以使用立即獲取功能搜索本地的註冊表，輕鬆創建腳本文件，供你下次重裝系統時使用。
首先你要安裝 MS Batch 98，其安裝文件在 Windows 98 安裝盤中。
此軟件在 Windows 98 的完整安裝盤中的路徑爲 *:\Tools\Reskit\Batch。如圖1
此主題相關圖片如下：
按此查看圖片詳細信息正在讀取此圖片的詳細信息，請稍候 ...
可以雙擊 Setup.exe 將其安裝到硬盤上，再通過選“開始→程序→Microsoft Batch 98”來
運行它；也可以在安裝目錄中直接雙擊 Batch.exe 運行它。
該軟件運行後主界面如圖2。
此主題相關圖片如下：
按此查看圖片詳細信息正在讀取此圖片的詳細信息，請稍候 ...
運行後，其界面如上圖。單擊主界面上的“一般安裝選項”、“網絡選項”、“可選的組件”、
“Internet Explorer選項”、"高級選項"按鈕可進行相應的設置。其中所包含的設置非常豐富，從
產品序列號、用戶名稱、Windows 98安裝目錄到IE 4.0瀏覽器的起始頁，還有是否安裝哪些網絡協
議。對於一般用戶來說“一般安裝選項”和“可選的組件”按鈕最爲常用。設置好有關選項後，單
擊“保存設置到INF”按鈕，程序將提示保存的路徑與文件名，輸入後單擊"確定"按鈕。如果你要修
改已有的腳本文件，只需選擇菜單"文件"中的"打開"，選擇腳本文件所在的位置，然後主界面的相
關欄目修改即可。
使用腳本文件也很簡單，在 DOS 命令提示符下按照“setup 腳本文件名”即可完成自動安裝。
例如：setup *:\batch.inf。在使用時需要注意，必須指定腳本文件的完整路徑，否則，安裝程序
將由於錯誤而終止（* 號代表所在盤符）。
如果你已經安裝了 Windows 98 系統，可以通過註冊表中的內容自動創建腳本文件。具體操作
是，單擊"現在收集"按鈕，然後在相應欄目做適當修改保存即可。
例子就是這樣，單擊“現在收集”則可將本機上次安裝 Windows 98 的相關設置讀爲默認值，
之後可再根據自己的實際情況修改；如欲進行全新的設置，則跳過此步。
在“一般安裝選項”中可輸入（或選擇）產品序列號、默認安裝目錄、用戶信息和計算機信息、地
區設置及其他一些安裝提示。
在“網絡選項”中可設置本機安裝的協議、網絡屬性等。 也可不改！
在“可選的組件”中可修改附件或桌面主題的內容等。 也可不改！
在“Internet Explorer選項”中可修改Internet選項的值。 也可不改！
在“高級選項”中爲在線升級等信息的設置。 也可不改！
單擊“保存設置到 INF”即可將相關設置保存爲安裝腳本文件(XXX.inf)，如保存爲 *:\Autobatch.inf。
最後要說明的是，該版本的 Batch.exe 是使用 Win95 公用控件的32位應用程序，所以該程序只
能在 Windows 98 下運行。並且 Windows NT 也不支持註冊表的自動檢查。另外 MS Batch 98 有詳細
的中文幫助文件，有什麼疑問可以到裏面去查詢。
同樣 Windows ME 也可以使用這個文件進行安裝。
二、下面是 Windows 98 的安裝參數
setup 所有命令行參數的使用及語法的有關幫助，有可能也不完全哦。
/C
不安裝Smartdrive磁盤緩存。
/D
忽略現有版本Windows的初始設置。如果用戶是在Windows系統文件缺少或損壞時重新安裝Windows時可使用該參數。
/DOMAIN: domain_name
設置Microsoft網絡用戶的Windows
NT的合法登錄域名爲domain_name。
/F
忽略在文件名的本地緩存中尋找文件。這樣雖然安裝時間稍長，但卻
佔用極少的內存。
/IA
不運行Setup.inf文件中的［AfterProvider］節（這個最常用）。
/IB
不運行Setup.inf文件中的［BeforeProvider］節。
/IC
如果使用該參數並未設置RMDrivers=1，則啓動時不運行Config.sys/
Autoexec.bat文件。
/ID
忽略檢查安裝Windows98所需的最小磁盤空間。
/IE
不創建啓動盤。如使用此參數，則相應也不創建windowscommandebd文
件夾。
/IF
快速安裝。
/IG
允許在一些含較早版本BIOS的Gateway和Micro計算機上運行Setup。
/IH
在顯着位置運行Scandisk。使用該參數有利於用戶在運行Scandisk過
程中或發生錯誤時清楚瞭解運行結果。
/IL
安裝Logitech鼠標驅動。如果用戶使用的是Logitech Series C鼠標，
可使用該參數。
/IM
忽略對低位常規內存的檢查 （這個最常用）
/IN
不執行網絡安裝程序。跳過網絡軟件和網絡設置畫面顯示。
/IQ
不檢查交叉鏈接文件。
/IR
不更新主引導紀錄（MBR）。
/IS
不運行 Scandisk （也就是磁盤檢測，這個最常用）。
/IV
Windows 升級安裝時跳過顯示安裝畫面（這個最常用）。
/M
跳過安裝時音頻（.wav）文件的播放。
/N
沒有鼠標時運行Setup。
/NA#
# =0 缺省
# =1 不檢查基於Windows的程序，排列基於MS-DOS的程序
# =2不檢查基於MS-DOS的程序，排列基於的Windows程序
# =3不檢查基於Windows和MS-DOS的程序
/ND
忽略Migration.dll文件，並強制Windows98覆蓋較新的文件
/NF
在“複製Windows98文件至你的計算機”結束後，不顯示“從驅動器A
中移去軟盤”。一般在用戶用可啓動光盤安裝Windows98時使用該參數
。等價於在Msbatch.inf文件中設置BootCD=1。
/NH
在Windows95用戶界面運行Setup時，不運行Hwinfo.exe。
/nm
忽略檢查運行Windows98所需的最低要求處理器（66MHz 486）。
/NOSTART
複製安裝Windows98所需的動態鏈接庫文件(DLLs)的最小安裝版本，然
後不安裝Windows98而直接退回MS-DOS狀態。
/NR
忽略註冊表檢查。
/NX
不檢查正在運行的Setupx的版本。
/PI
保留硬件的特定設置（硬件未使用缺省設置）。有的版本的BIOS要求
硬件根據特定的設置工作。默認情況下，Setup刪除硬件的特定設置從
而造成部分硬件不能正常工作。
/PJ
默認安裝Advanced Configuration and Power Interface (ACPI)
script_filename
使用指定位置的包含安裝選項的宏文件自動安裝Windows98。
/SRCDIR
指定Windows98安裝文件的初始目錄
/S filename
安裝時裝載指定的SETUP.INF文件。
/T:tempdir
爲安裝程序指定複製臨時文件的目錄。如果目錄不存在，將自動創建
該目錄。若該目錄存在，則此目錄中的任何舊文件都將被刪除。
/U:UPI
指定UPI
/IV
在安裝過程跳過公告板顯示（這個最常用）
/IW
在安裝過程跳過許可協議顯示（這個最常用）
/IX
忽略字符集檢查
例子：我們一般這要用到這幾個參數就夠了
setup /is /iv /im /iw Autobatch.inf
如果要了解更詳細的內容請登上微軟的網站：
http://support.microsoft.com/ph/1139
使用自動安裝腳本文件全自動安裝 Windows 98 的格式爲：Setup *:\Autobatch.inf （注：必須包括完整路徑！）。
三、修改 setup98.img 文件
我們已經做了上述的準備，這裏就只要簡單的修改一下映像文件就行了，
1、如果我們是把所做好的映像文件IMG直接添加到引導區的話，那麼 setup98.img 裏的 jo.sys 保留着，在安裝時
Windows 98 在重啓動時會很好地幫助你進入安裝程序，不然你會感到沒有完全自動了，因爲它默認的是從硬盤啓
動，如果你是用 EasyBoot 菜單來調用做全自動安裝的話,請你把這個 jo.sys 這個文件刪除掉，否則又會帶來不
便。
2、用 Winp_w_picpath 打開 setup98.img 修改文件，提取 autoexec.bat 文件，把這句 OEMSETUP.EXE /K "/IE /NF" 命令改成下面的就 OK 了，
%CDROM%:\SETUP /IS /IV /IM /IW AUTOBATCH.INF (注:這個AUTOBATCH.INF文件必須在安裝程序目錄下)
也可用自定義目錄來安裝,比如:我們建立一個配置文件目錄,取名爲 AUTO 目錄.
%CDROM%:\SETUP /IS /IV /IM /IW %CDROM%:\AUTO\AUTOBATCH.INF
也可以把配置應答文件放在硬盤上,
%CDROM%:\SETUP /IS /IV /IM /IW D:\AUTO\AUTOBATCH.INF(必須完整路徑)
3、修改完成後，把 autoexec.bat 文件添加進 setup98.img 修改文件進行覆蓋原文件就行了
這個貼子最後由xzf在 2005/08/31 00:18pm 第 2 次編輯]
前 言
在這篇裏講解做一個全自動備份和恢復的 IMG 映像文件, 其實做這個啓動盤也不難的, 只要用 Windows 98 的 標準 IMG 來做一下修改就行了, 很簡單的, 所需的工具這要一個 Winp_w_picpath 映像編輯軟件就行了。
因爲現在大家都在想學電腦，裝程序等等！一旦程序或系統出了嚴重的問題需重裝系統是一件
很煩的事，自從有了 GHOST 程序後，就變得很輕鬆了，這要先裝好一個乾淨健康的系統用 GHOST 程序做備份，一旦系統出問題，只要把這個啓動盤一放後啓動電腦後一鍵就搞定，真是輕鬆多了。
注：因爲詳細的命令在以幾篇中都已講過，所以不再詳解，現在這是實例了，這篇就寫到這裏。
注：未經同意, 不準轉貼, 謝謝合作! QQ 羣號: 11175590
第四課 全自動備份和恢復的 IMG 啓動盤詳細講解
一、利用 Windows 98 的 標準 IMG 啓動映像來改制自己想要的備份和恢復啓動盤, 首先把 IMG
映像文件裏的二個文件 config.sys 和 autoexec.bat 這二個提取出來，然後再進行修改。
1、config.sys 的文件做修改
============================================================================
[menu]
menuitem=CD, Start computer with CD-ROM support.
menuitem=NOCD, Start computer without CD-ROM support.
menuitem=HELP, View the Help file.
menudefault=CD,30
menucolor=7,0
[CD]
device=himem.sys /testmem:off
device=oakcdrom.sys /D:mscd001
device=btdosm.sys
device=flashpt.sys
device=btcdrom.sys /D:mscd001
device=aspi2dos.sys
device=aspi8dos.sys
device=aspi4dos.sys
device=aspi8u2.sys
device=aspicd.sys /D:mscd001
[NOCD]
device=himem.sys /testmem:off
[HELP]
device=himem.sys /testmem:off
[COMMON]
files=10
buffers=10
dos=high,umb
stacks=9,256
devicehigh=ramdrive.sys /E 2048
lastdrive=z
================================================================================
改成爲這樣，
如下： （把下面的紅色字全部複製一份到 config.sys 裏就可以了，原來的全部覆蓋）
================================================================================
[menu]
menuitem=CD, Ghsot Huifu from CDROM to C Disk 從光盤恢復到 C 盤
menuitem=DISK1, Ghsot Huifu from F Disk to C disk 從 F 盤恢復到 C 盤
menuitem=DISK2, Ghost Beifen C Disk to F Disk 備份 C 盤到 F 盤
menudefault=CD,30
menucolor=7,0
[CD]
device=himem.sys /testmem:off
device=oakcdrom.sys /D:mscd001
device=btdosm.sys
device=flashpt.sys
device=btcdrom.sys /D:mscd001
device=aspi2dos.sys
device=aspi8dos.sys
device=aspi4dos.sys
device=aspi8u2.sys
device=aspicd.sys /D:mscd001
[DISK1]
device=himem.sys /testmem:off
[DISK2]
device=himem.sys /testmem:off
[COMMON]
files=10
buffers=10
dos=high,umb
stacks=9,256
devicehigh=ramdrive.sys /E 2048
lastdrive=z
=============================================================================
config.sys 的以下菜單[menu] 和 [CD] 修改好就可以了 [DISK1] 和 [DISK2] 項都不需
要修改的，只修改一下標籤就行了，其實不修改標籤也一樣可以，我們只是爲了放便記住
它，不會搞錯，所以還是修改一下的好。其它它用默認就可以了。
2、autolexec.bat 文件的做修改
==============================================================================
@ECHO OFF
set EXPAND=YES
SET DIRCMD=/O:N
set LglDrv=27 * 26 Z 25 Y 24 X 23 W 22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15
set LglDrv=%LglDrv% O 14 N 13 M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
cls
call setramd.bat %LglDrv%
set temp=c:\
set tmp=c:\
path=%RAMD%:\;a:\;%CDROM%:\
copy command.com %RAMD%:\ > NUL
set comspec=%RAMD%:\command.com
copy extract.exe %RAMD%:\ > NUL
copy readme.txt %RAMD%:\ > NUL
:ERROR
IF EXIST ebd.cab GOTO EXT
echo Please insert Windows 98 Startup Disk 2
echo.
pause
GOTO ERROR
:EXT
%RAMD%:\extract /y /e /l %RAMD%: ebd.cab > NUL
echo The diagnostic tools were successfully loaded to drive %RAMD%.
echo.
IF "%config%"=="NOCD" GOTO QUIT
IF "%config%"=="HELP" GOTO HELP
LH %ramd%:\MSCDEX.EXE /D:mscd001 /L:%CDROM%
echo.
GOTO QUIT
:HELP
cls
call help.bat
echo Your computer will now restart and the startup menu will appear.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
restart.com
GOTO QUIT
:QUIT
echo To get help, type HELP and press ENTER.
echo.
rem clean up environment variables
set CDROM=
set LglDrv=
================================================================================
改成這樣：
如下： （把下面的紅色字全部複製一份到 autolexec.bat 裏就可以了，原來的全部覆蓋）
================================================================================
@ECHO OFF
set EXPAND=YES
SET DIRCMD=/O:N
set LglDrv=27 * 26 Z 25 Y 24 X 23 W 22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15
set LglDrv=%LglDrv% O 14 N 13 M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
cls
call setramd.bat %LglDrv%
set temp=c:\
set tmp=c:\
path=%RAMD%:\;a:\;%CDROM%:\
copy command.com %RAMD%:\ > NUL
set comspec=%RAMD%:\command.com
copy extract.exe %RAMD%:\ > NUL
copy readme.txt %RAMD%:\ > NUL
:ERROR
IF EXIST ebd.cab GOTO EXT
echo Please insert Windows 98 Startup Disk 2
echo.
pause
GOTO ERROR
:EXT
%RAMD%:\extract /y /e /l %RAMD%: ebd.cab > NUL
echo The diagnostic tools were successfully loaded to drive %RAMD%.
echo.
IF "%config%"=="CD" GOTO HUIFU1
IF "%config%"=="DISK1" GOTO HUIFU2
IF "%config%"=="DISK2" GOTO BEIFEN
:HUIFU1
LH %ramd%:\MSCDEX.EXE /D:mscd001 /L:%CDROM%
%CDROM%:\ghost.exe -clone,mode=pload,src=%CDROM%:\xp.gho:1,dst=1:1 -sure -rb
:HUIFU2
f:\ghost.exe -clone,mode=pload,src=f:\xp.gho:1,dst=1:1 -sure -rb
:BEIFEN
f:\ghost.exe -clone,mode=pdump,src=1:1,dst=f:\xp.gho -fx -sure -z9 -rb
:QUIT
echo To get help, type HELP and press ENTER.
echo.
rem clean up environment variables
set CDROM=
set LglDrv=
==================================================================================
以上的修改完成後，把它導入到 SETUP98.IMG 映像中覆蓋原文件即可，這樣我們所做的自動
備份和恢復就完成了。
二、下面將 GHOST 程序詳細說明也發一下
Ghost 使用詳解
--------------------------------------------------------------------------------
一、分區備份
使用Ghost進行系統備份，有整個硬盤（Disk）和分區硬盤（Partition）兩種方式。在菜單中點擊 Local（本地）項，在右面彈出的菜單中有3個子項，其中 Disk表示備份整個硬盤（即克隆）、Partition 表示備份硬盤的單個分區、Check 表示檢查硬盤或備份的文件，查看是否可能因分區、硬盤被破壞等造成備份或還原失敗。分區備份作爲個人用戶來保存系統數據，特別是在恢復和複製系統分區時具有實用價值。
選 Local→Partition→To Image 菜單，彈出硬盤選擇窗口，開始分區備份操作。點擊該窗口中白色的硬盤信息條，選擇硬盤，進入窗口，選擇要操作的分區（若沒有鼠標，可用鍵盤進行操作：TAB鍵進行切換，回車鍵進行確認，方向鍵進行選擇）。 在彈出的窗口中選擇備份儲存的目錄路徑並輸入備份文件名稱，注意備份文件的名稱帶有 GHO 的後綴名。 接下來，程序會詢問是否壓縮備份數據，並給出3個選擇：No 表示不壓縮，Fast表示壓縮比例小而執行備份速度較快，High 就是壓縮比例高但執行備份速度相當慢。最後選擇 Yes 按鈕即開始進行分區硬盤的備份。Ghost 備份的速度相當快，不用久等就可以完成，備份的文件以 GHO 後綴名儲存在設定的目錄中。
二、硬盤克隆與備份
硬盤的克隆就是對整個硬盤的備份和還原。選擇菜單Local→Disk→To Disk，在彈出的窗口中選擇源硬盤（第一個硬盤），然後選擇要複製到的目標硬盤（第二個硬盤）。注意，可以設置目標硬盤各個分區的大小，Ghost 可以自動對目標硬盤按設定的分區數值進行分區和格式化。選擇 Yes 開始執行。
Ghost 能將目標硬盤複製得與源硬盤幾乎完全一樣，並實現分區、格式化、複製系統和文件一步完成。只是要注意目標硬盤不能太小，必須能將源硬盤的數據內容裝下。
Ghost 還提供了一項硬盤備份功能，就是將整個硬盤的數據備份成一個文件保存在硬盤上（菜單 Local→Disk→To Image），然後就可以隨時還原到其他硬盤或源硬盤上，這對安裝多個系統很方便。使用方法與分區備份相似。
三、備份還原
如果硬盤中備份的分區數據受到損壞，用一般數據修復方法不能修復，以及系統被破壞後不能啓動，都可以用備份的數據進行完全的復原而無須重新安裝程序或系統。當然，也可以將備份還原到另一個硬盤上。
要恢復備份的分區，就在界面中選擇菜單Local→Partition→From Image，在彈出窗口中選擇還原的備份文件，再選擇還原的硬盤和分區，點擊 Yes 按鈕即可。
四、局域網操作
LPT 是通過並口傳送備份文件,下面有兩個選項：slave 和 master, 分別用以連接主機和客戶機。 網絡基本輸入輸出系統 NetBios 和 LPT 相似, 也有 slave 和 master 兩個選項, 作用與 LPT 相同。
先和平時一樣將要 ghost 的分區做成一個 *.gho 文件，再在一臺 win98 上安裝Symantec Ghost 企業版，重啓。
1. 首先製作一張 ghost 帶網卡驅動的啓動盤。Start > Programs > Symantec Ghost > Ghost Boot Wizard－>Network Boot Disk 如果你的網卡在列表內直接選擇它就可以生成一張帶 PC-DOS 的啓動盤。（但 6.5版的生成的軟盤經常有問題，不能成功啓動）如果你的網卡不在列表內，你要建立專用的 Packet Driver。ADD->Packet Driver (網卡的驅動程序中有)往下根據提示一步一步走，填入工作站的 ip（ghost 一定要 tcp/ip 協議）。最後生成一張軟盤，但此軟盤仍不能使用，要改 autoexec.bat 文件在 net xxxx.dos 後面加一個16進制的地址，如 0X75 等。多臺計算機只需改 wattcp.cfg 文件中的 ip 即可:
IP = 192.168.100.44
NETMASK = 255.255.255.0
GATEWAY = 192.168.100.1
2. 在 server 端運行 multicast server 出來的畫面。先給 server一個Session Name（別名）如：bb，再選擇 p_w_picpath file 就是你的 gho 文件。然後 －>Dump From Client->rtitions->More Options-> 在 auto start 的 client 中填入 50（如果你要同時複製50臺）->accept client 就算完成了，當你的工作站數達到50臺時，server就自動傳送*.gho 文件。
3.詳述：
目前，相當多的電子教室都採用了沒有軟驅、光驅的工作站。在沒有軟驅、光驅的情況下，當硬盤的軟件系統出現問題時，能否實現網絡硬盤克隆呢？PXE（Preboot Execution Environment，它是基於 TCP/IP、DHCP、TFTP 等 Internet 協議之上的擴展網絡協議）技術提供的從網絡啓動的功能，讓我們找到了解決之道。下面，我們就來講解怎樣採用Ghost 7.0來實現基於 PXE 的網絡硬盤克隆。
網絡硬盤克隆過程簡述
網絡硬盤克隆過程爲：在裝有軟驅的工作站上，用一張引導盤來啓動機器，連接到服務器，使用 Ghost 多播服務（Multicast Server）將硬盤或分區的映像克隆到工作站，這樣就實現了不拆機、安全、快速的網絡硬盤克隆。
實現 PXE 網絡啓動方式
對於沒有軟驅、光驅的工作站，要實現PXE網絡啓動方式，需要完成三個步驟：
1、工作站的PXE啓動設置
PXE網絡啓動一般要求在網卡上加裝 PXE 啓動芯片（PXE Boot ROM）；對於某些型號的網卡，也可以將 PXE 啓動代碼（Boot Code）寫入主板的 Flash ROM；而一些主板上集成了網卡的品牌機（例如清華同方的商用機），可直接支持PXE啓動。
常用的 RTL8139 芯片的網卡，其 PXE 啓動設置方式是：機器啓動時根據屏幕提示按下Shift+F10，在啓動類型中選擇PXE，開啓網絡啓動選項即可。
2、製作 PXE 啓動文件
製作 PXE 的啓動文件，推薦使用 3Com 的 DABS（Dynamic Access Boot Services）。DABS 提供了功能強大的 PXE 啓動服務、管理功能，但是，網上可供下載的是一個30天的試用版。所以，我們只用它的啓動映像文件製作功能，而由 Windows 2000 Server 的 DHCP 服務器來提供 PXE 啓動服務。
DABS 可以安裝在任何一臺運行 Windows 的機器上。安裝後，運行 3Com Boot Image Editor，出現主界面圖。選擇“創建TCP/IP或PXE映像文件（Create a TCP/IP or PXE p_w_picpath file）”，出現對話窗口。爲即將建立的映像文件命名，例如：pxeghost.img，其他採用默認選項，將經測試正常的網絡啓動盤放入軟驅，選擇[OK]，創建PXE啓動映像 Pxeghost.img文件。
在 3Com Boot Image Editor 的主菜單中，選擇“創建PXE菜單啓動文件（Creat a PXE menu boot file）”，在出現的窗口中選擇[添加（Add）]，加入我們剛剛創建的啓動映像文件Pxeghost.img，在“選項（Options）”標籤中可以設置菜單標題和等待時間。
選擇[保存（Save）]，給保存的PXE菜單啓動文件命名爲 Pxemenu.pxe。
3、服務器的PXE啓動服務設置
Windows 2000 Server 的 DHCP 服務支持兩種啓動協議：DHCP 和 BOOTP。我們可以設定以下三種選擇：僅 DHCP、僅 BOOTP、兩者。如果我們的局域網中由其他的 DHCP 服務器提供動態 IP 地址分配，那麼這裏選“僅BOOTP”即可；如果需要這臺服務器提供動態 IP 地址分配，則需要選“兩者”。
接下來，設置啓動文件名。在DHCP服務器的作用域選項中配置選項“067:啓動文件名”，字串值爲我們創建的 PXE 菜單啓動文件名 Pxemenu.pxe。注意：文件名不包含路徑。
DHCP 服務器只是將啓動文件名通知給 BOOTP 客戶機，客戶機通過什麼方式下載啓動文件呢？答案是，需要 TFTP 服務。3Com 的 DABS 包含了一個 TFTP 服務組件，當然，也可以下載一個免費的 TFTP 服務器軟件長期使用。
在 TFTP 服務器的設置中，規定一個服務目錄。將製作的 PXE 啓動文件 Pxeghost.img、Pxemenu.pxe 放到 TFTP 的服務目錄中。TFTP 服務器設置爲自動運行。
用 Ghost 多播克隆硬盤
現在運行 Ghost 多播服務器，任務名稱爲 Restore。設置完畢，按下[接受客戶（Accept Clients）]按鈕。啓動要接受硬盤克隆的無軟驅工作站，如果以上步驟操作無誤，應該能夠實現 PXE 啓動，加入到多播克隆的任務當中。所有的目標工作站連接到本次任務之後，按下[發送（Send）]按鈕，開始克隆任務。
五、參數設置
在 Options 中可以設置參數。下面簡單介紹一下:
1．p_w_picpath write buffering：在建立備份文件時, 打開寫緩衝；
2．sure：選擇此項後, 不再會出現最終確認詢問 (建議不要選擇此項)；
3．no int 13：選擇此項後, 不支持中斷 13 (缺省時不選擇)；
4．reboot：在對硬盤或者分區操作完成之後, 自動重啓計算機；
5．spanning：通過多個卷架構備份文件 (選擇此項時, 關閉 write buffering)；
6．autoname：自動爲 spanning 文件命名；
7．allow 64k fat clusters：允許使用 64K FAT 簇 (僅在 Windows NT 中支持)；
8．ignore CRC errors：忽略 CRC 錯誤；
9．override size limit：如果出現分區大小不相配, 可忽略執行；
10．p_w_picpath read buffering：打開生成備份文件時的讀緩存 (缺省時選中此項)。
六、軟件特性
1.存貯介質
Ghost 支持的存儲介質超出了我們的想象，它支持對等 LPT 接口、對等 USB 接口、對等 TCP/IP 接口、SCSI磁帶機、便攜式設備（JAZ、ZIP、MO等）、光盤刻錄機（CDR、CDRW）等。而這些特性不需要任何外帶的驅動程序和軟件，只需一張軟盤就可以做到！特別是對光盤刻錄機的支持，如今的刻錄機和空白光盤都十分便宜，非常適合作備份的用途。
2.兼容性
Ghost 對現有的操作系統都有良好的支持，包括 FAT16、FAT32、NTFS、HPFS、UNIX、NOVELL 等文件存儲格式。同以前版本不同的是，Ghost 2001 加入了對 Linux EX2的支持（FIFO 文件存儲格式），這也就意味着 Linux 的用戶也可以用 Ghost 來備份系統了。
3.配套軟件
A.Ghost 瀏覽器
在以前的 Ghost版本中，我們只能對整個系統進行簡單的備份、複製、還原，要恢復單個的文件和文件夾還要使用外帶的 GhostEXP 軟件。現在，Symantec 公司已經將 Ghost 瀏覽器整合在軟件中。Ghost 瀏覽器採用類似於資源管理器的界面，通過它，我們可以方便迅速地在備份包中找出我們想要的文件和文件夾並還原。
使用Explorer可以備份整個硬盤或單個硬盤分區，點擊工具欄上的圓柱形圖標，彈出硬盤或分區選擇對話窗口，然後再選擇備份文件的儲存目錄並輸入名稱即可完成。要注意的是，非註冊用戶不能使用備份這項功能。
在 Ghost Explorer 中管理硬盤備份文件就非常方便了。首先選擇打開一個備份文件(File/Open)，這時備份中的文件就像資源管理器一樣在程序界面窗口中列出，可以在其中非常方便地查看、打開文件，也可以查找文件，或者將某個文件刪除(但不能刪除目錄)。
在 Ghost Explorer 中提供了多種還原硬盤備份文件的方法，最方便的方法是使用鼠標右鍵點擊某個文件，在彈出菜單中選擇 Restore，然後輸入要還原到的目錄，這樣，單個文件就從整個磁盤備份中還原出來了。當然，如果要還原整個磁盤備份，只需選擇左面目錄列表欄中最上面的帶磁盤圖標的目錄項，然後點擊工具欄中的還原圖標 (第二個) 就可以了。
B.GDisk
GDisk 是一個新加入的實用工具，它徹底取代了 FDisk 和 format，功能有：
* 快速格式化。
* 隱藏和顯示分區。此功能允許一個以上的主 DOS分區，並且每個分區上的操作系統有不同的版本。隱藏分區的能力使計算機習慣於引導到選定的可引導分區，忽略其他隱藏分區中相同操作系統的安裝。
* 全面的分區報告。
* 高度安全的磁盤擦除。提供符合美國國防部標準和更高安全標準的磁盤擦除選項。
與使用交互式菜單的 FDisk 不同，GDisk是由命令行驅動的。這提供了更快的配置磁盤分區和在批處理文件中定義 GDisk操作的能力。但與此同時，幾十個參數會令普通用戶頭疼，因此筆者不推薦一般用戶使用，Symantec 公司也應該推出相應的GUI（圖形用戶界面）控制檯以方便用戶使用。具體的參數說明可以用命令行 gdisk/? 瞭解。
C.Live Update
Live Update 是 Symantec公司軟件的一個通用升級程序，它能夠檢查當前系統中已安裝的 Symantec 軟件，並且通過英特網對軟件進行在線升級。
在安裝 Ghost 2001 時，安裝程序自動升級了 Live Update 程序的版本。
七、命令行參數：（Ghost 的無人 備份/恢復/複製 操作）
其實 Ghost 2001 的功能遠遠不止它主程序中顯示的那些，Ghost 可以在其啓動的命令行中添加衆多參數以實現更多的功能。命令行參數在使用時頗爲複雜，不過我們可以製作批處理文件，從而“一勞永逸”（類似於無人安裝 Windows 98 和Windows 2000）。現在讓我們來了解一些常用的參數（瞭解更加詳細的參數介紹可查看 Ghost 的幫助文件）。
1.-rb
本次 Ghost 操作結束退出時自動重啓。這樣，在複製系統時就可以放心離開了。
2.-fx
本次 Ghost 操作結束退出時自動回到DOS提示符。
3.-sure
對所有要求確認的提示或警告一律回答“Yes”。此參數有一定危險性，只建議高級用戶使用。
4.-fro
如果源分區發現壞簇，則略過提示而強制拷貝。此參數可用於試着挽救硬盤壞道中的數據。
5.@filename
在 filename 中指定 txt 文件。txt文件中爲 Ghost 的附加參數，這樣做可以不受DOS命令行 150 個字符的限制。
6.-f32
將源 FAT16 分區拷貝後轉換成 FAT32（前提是目標分區不小於 2G）。WinNT 4 和Windows95、97用戶慎用。
7.-bootcd
當直接向光盤中備份文件時，此選項可以使光盤變成可引導。此過程需要放入啓動盤。
8.-fatlimit
將 NT 的 FAT16 分區限制在 2G。此參數在複製 Windows NT 分區，且不想使用64k/簇的 FAT16 時非常有用。
9.-span
分卷參數。當空間不足時提示覆制到另一個分區的另一個備份包。
10.-auto
分卷拷貝時不提示就自動賦予一個文件名繼續執行。
11.-crcignore
忽略備份包中的 CRC ERROR。除非需要搶救備份包中的數據，否則不要使用此參數，以防數據錯誤。
12.-ia
全部映像。Ghost 會對硬盤上所有的分區逐個進行備份。
13.-ial
全部映像，類似於 -ia 參數，對 Linux 分區逐個進行備份。
14.-id
全部映像。類似於 -ia 參數，但包含分區的引導信息。
15.-quiet
操作過程中禁止狀態更新和用戶干預。
16.-script
可以執行多個 Ghost 命令行。命令行存放在指定的文件中。
17.-split=x
將備份包劃分成多個分卷，每個分卷的大小爲 x兆。這個功能非常實用，用於大型備份包複製到移動式存儲設備上，例如將一個 1.9G 的備份包複製到 3 張刻錄盤上。
18.-z
將磁盤或分區上的內容保存到映像文件時進行壓縮。-z 或 -z1 爲低壓縮率（快速）；-z2 爲高壓縮率（中速）；-z3 至 -z9 壓縮率依次增大（速度依次減慢）。
19.-clone
這是實現 Ghost 無人備份/恢復的核心參數。使用語法爲：
-clone,MODE=(operation),SRC=(source),DST=(destination),[SZE(size),SZE(size)...]
此參數行較爲複雜，且各參數之間不能含有空格。其中 operation意爲操作類型，值可取：copy：磁盤到磁盤；load：文件到磁盤；dump：磁盤到文件；pcopy：分區到分區；pload：文件到分區；pdump：分區到文件。
Source 意爲操作源，值可取：驅動器號，從1開始；或者爲文件名，需要寫絕對路徑。
Destination 意爲目標位置，值可取：驅動器號，從 1開始；或者爲文件名，需要寫絕對路徑；@CDx，刻錄機，x 表示刻錄機的驅動器號，從1開始。
下面舉例說明：
1.命令行參數：ghostpe.exe -clone,mode=copy,src=1,dst=2
完成操作：將本地磁盤1複製到本地磁盤2。
2.命令行參數：ghostpe.exe -clone,mode=pcopy,src=1:2,dst=2:1
完成操作：將本地磁盤1上的第二分區複製到本地磁盤2的第一分區。
3.命令行參數：ghostpe.exe-clone,mode=load,src=g:\3prtdisk.gho,dst=1,sze1=450M,sze2=1599M,sze3=2047M
完成操作：從映像文件裝載磁盤1，並將第一個分區的大小調整爲450MB，第二個調整爲1599MB，第三個調整爲2047MB。
4.命令行參數：ghostpe.exe -clone,mode=pdump,src2:1:4:6,dst=d:\prt246.gho
完成操作：創建僅含有選定分區的映像文件。從磁盤2上選擇分區1、4、6。
八、一些示例
ghost.exe -clone,mode=copy,src=1,dst=2 -sure
硬盤對拷
ghost.exe -clone,mode=pcopy,src=1:2,dst=2:1 -sure
將一號硬盤的第二個分區複製到二號硬盤的第一個分區
ghost.exe -clone,mode=pdump,src=1:2,dst=g:\bac.gho
將一號硬盤的第二個分區做成映像文件放到 g 分區中
ghost.exe -clone,mode=pload,src=g:\bac.gho:2,dst=1:2
從內部存有兩個分區的映像文件中，把第二個分區還原到硬盤的第二個分區
ghost.exe -clone,mode=pload,src=g:\bac.gho,dst=1:1 -fx -sure -rb
用 g 盤的 bac.gho 文件還原 c 盤。完成後不顯示任何信息，直接啓動
ghost.exe -clone,mode=load,src=g:\bac.gho,dst=2,SZE1=60P,SZE2=40P
將映像文件還原到第二個硬盤，並將分區大小比例修改成 60:40
自動還原磁盤：
首先做一個啓動盤，包含 Config.sys, Autoexec.bat, Command.com, Io.sys, Ghost.exe 文件(可以用 windows 做啓動盤的程序完成)。Autoexec.bat 包含以下命令：
Ghost.exe -clone,mode=pload,src=d:\bac.gho,dst=1:1 -fx -sure -rb
利用在 D 盤的文件自動還原，結束以後自動退出 ghost 並且重新啓動。
自動備份磁盤：
ghost.exe -clone,mode=pdump,src=1:1,dst=d:\bac.gho -fx -sure -rb
自動還原光盤：
包含文件：Config.sys, Autoexec.bat, Mscdex.exe (CDROM 執行程序), Oakcdrom.sys (ATAPI CDROM 兼容驅動程序), Ghost.exe。
Config.sys 內容爲：
DEVICE=OAKCDROM.SYS /D:IDECD001
Autoexec.bat 內容爲：
MSCDEX.EXE /D:IDECE001 /L:Z
Ghost -clone,mode=load,src=z:\bac.gho,dst=1:1 -sure -rb
可以根據下面的具體說明修改示例：
1.-clone
-clone 在使用時必須加入參數，它同時也是所有的 switch{batch switch} 裏最實用的。下面是 clone 所定義的參數：
mode={copy|load|dump|pcopy|pload|pdump},
src={drive|file|driveartition},
dst={drive|file|driveartition}
mode 指定要使用哪種 clone 所提供的命令
copy 硬盤到硬盤的複製 (disk to disk copy)
load 文件還原到硬盤 (file to disk load)
dump 將硬盤做成映像文件 (disk to file dump)
pcopy 分區到分區的複製 (partition to partition copy)
pload 文件還原到分區 (file to partition load)
pdump 分區備份成映像文件（partition to file dump)
src 指定了 ghost 運行時使用的源分區的位置模式及其意義。對應 mode 命令 src 所使用參數例子:
COPY/DUMP 源硬盤號。以 1 代表第一號硬盤
LOAD 映像文件名。g:/back98/setup98.gho 或裝置名稱 (drive）
PCOPY/PDUMP 源分區號。1:2 代表的是硬盤１的第二個分區
PLOAD 分區映像文件名加上分區號或是驅動器名加上分區號。g:\back98.gho:2 代表映像文件裏的第二個分區
dst 指定運行 Ghost 時使用的目標位置模式及其意義。對應 mode 命令 dst 所使用參數例子：
COPY/DUMP 目的硬盤號。2 代表第二號硬盤
LOAD 硬盤映像文件名。例 g:\back98\setup98.gho
PCOPY/PLOAD 目的分區號。2:2 代表硬盤 2 的第二個分區
PDUMP 分區映像文件名加分區號。g:\back98\setup98.gho:2
SZEn 指定所使用目的分區的大小：
n=xxxxM 指定第 n 目的分區的大小爲 xxxxMB。如 SZE2=800M 表示分區 2 的大小爲 800MB
n=mmP 指定第 n 目的分區的大小爲整個硬盤的 mm 個百分比。
2.-fxo 當源物件出現壞塊時，強迫複製繼續進行
3.-fx 當ghost完成新系統的工作後不顯示 press ctrl-alt-del to reboot 直接回到DOS下
4.-ia 完全執行扇區到扇區的複製。當由一個映像文件或由另一個硬盤爲來源，複製一個分區時，Ghost將首先檢查來源分區，再決定是要複製文件和目錄結構還是要做映像複製(扇區到扇區)。預設是這種形式。但是有的時候，硬盤裏特定的位置可能會放一些隱藏的與系統安全有關的文件。只有用扇區到扇區複製的方法才能正確複製
5.-pwd and -pwd=x 給映像文件加密
6.-rb 在還原或複製完成以後，讓系統重新啓動
7.-sure 可以和 clone 合用。Ghost 不會顯示 proceed with disk clone-destination drive will be overwritten? 提示信息
九、注意事項
1.在備份系統時，單個的備份文件最好不要超過 2GB。
2.在備份系統前，最好將一些無用的文件刪除以減少Ghost文件的體積。通常無用的文件有：Windows 的臨時文件夾、IE 臨時文件夾、Windows 的內存交換文件。這些文件通常要佔去100 多兆硬盤空間。
3.在備份系統前，整理目標盤和源盤，以加快備份速度。
4.在備份系統前及恢復系統前，最好檢查一下目標盤和源盤，糾正磁盤錯誤。
5.在恢復系統時，最好先檢查一下要恢復的目標盤是否有重要的文件還未轉移，千萬不要等硬盤信息被覆蓋後才後悔莫及啊。
6.在選擇壓縮率時，建議不要選擇最高壓縮率，因爲最高壓縮率非常耗時，而壓縮率又沒有明顯的提高。
7.在新安裝了軟件和硬件後，最好重新制作映像文件，否則很可能在恢復後出現一些莫名其妙的錯誤。
啓動盤實戰系列三, 支持多光驅和 NTFS 分區 IMG 映像》
前 言
在上篇裏講到做一個全自動備份和恢復的 IMG 映像文件, 在這篇裏我們要學做的是帶菜單格式的多功能啓動盤,可以做成有以下功能:① 全自動 GHOST ; ② 啓動到 DOS 下手支操作; ③ DM 分區等等。其實做這個啓動盤也不難的, 只要用 Windows 98 的 啓動盤 IMG 來做一下修改, 需要修改好多地方，這樣做好的 IMG 啓動盤必須要用其它軟件來調用，因它超過了 1.44 MB，不能直接加載到引導扇區，但如果把其它工具都放到光盤上，也是可以不用軟件來調用的，只要把這個啓動盤一放進光驅啓動電腦後就可對相應的功能操作了，一鍵就搞定，真是輕鬆多了。
注：因爲詳細的命令在以前幾篇中都已講過，所以不再詳解，現在這是實例了，這篇就寫到這裏。
注：未經同意, 不準轉貼, 謝謝合作! QQ 羣號: 11175590
第一步 認識多光驅支持的原理，看下面的全自動 GHSOT 的詳細解釋，如下：
這是一個全自動的克隆 autohf.bat 文件，可以直接複製紅色文字到這個批處理中。在其它的地方
可以用這個方法來調用其它程序和小工具，這要改一下路徑就行了，簡單的很，在下面就有調用到
其它的方法。
======================================================================================
:: 測試虛擬盤是否建立成功
dready z: /w
if errorlevel 1 goto _errramd
:: 建立testdrv.bat臨時文件到虛擬盤上
set td=Z:\testdrv.bat
> %td% echo @echo off
>> %td% echo dready %%1
>> %td% echo if errorlevel 1 goto _quit
>> %td% echo set CDOK=%%CDOK%% %%1
>> %td% echo :_quit
:: 調用mscdex爲所有光驅分配盤符
LH MSCDEX.EXE /D:mscd001
set CDROM=
findcd /s > nul
:: 調用testdrv.bat檢測哪些光驅中有盤並將準備好的光驅保存到cdok變量中
SET CDOK=
for %%I in (%cdrom1% %cdrom2% %cdrom3%) DO call %td% %%I
::檢測哪些準備好的光驅中存在需要的GHO文件，並將結果保存到bootcd變量中
set bootcd=
for %%I in (%cdok%) DO if exist %%I\XPSP2\XP-SP2.GHO set BOOTCD=%%I
:: 檢測是否存在需要的啓動光盤
IF %BOOTCD%*==* goto _nobootcd
set CDROM=%bootcd%
echo bootcd=%bootcd%
goto _findbootcdok
:: 找不到所需啓動光盤的錯誤提示
:_nobootcd
echo.
echo Error: I cannot find your CDROM where we boot from!
echo Please make sure you insert the boot disc in it!
pause
goto _quit
:: 如果存在gho文件，則執行ghost過程並重新啓動
:_findbootcdok
%CDROM%\XPSP2\ghost.exe -clone,mode=pload,src=%CDROM%\XPSP2\XP-SP2.gho:1,dst=1:1 -sure -fx
::這是當GHOST工作完成後反回主菜單，在用EASYBOOT調用下，不調用下不要用這參數。
wboot.com
goto _quit
:: 沒有成功建立內存虛擬磁盤的錯誤提示
:_errramd
echo.
echo Error: I cannot access your RAM Disk at Q:!
echo Check if xmsdsk can create RAM Disk.
pause
goto _quit
:: 退出，清理環境變量
:_quit
for %%I in (cdrom1 cdrom2 cdrom3 cdok) do set %%I=
====================================================================================
知道上面的過程後，也就是這樣一個過程，也並不過的，（注意：帶雙冒號的是註解文字用的，
複製到批處理裏並不需要將其刪除，可以直接使用）
第二步 開始製作多功能啓動盤了
1、找一個 98 啓動盤IMG文件；
2、用 Winp_w_picpath 把裏面的所有文件全部提取到一個文件夾中。然後刪除IMG裏的所有文件，僅留
下這 Io.sys 、 msdos.sys 、 command.com 文件及建立二個目錄，一個是 DM 目錄、一個 temp
是臨時目錄。然後把剛纔提取的 ebd.cab 這個文件解壓到一個 ebd 目錄中，在 ebd 目錄下再建
立一個目錄，目錄名爲 DATA ，再把 DOS 下所用的 五筆和拼音及區位碼這 WB.MB、PY.MB、LX.LX
三個文件複製到 DATA 目錄裏，然後再重新制作 ebd.cab 文件，（五筆和拼音及區位碼這些文件
可以 DM 9.56 雙語版中提取）
其它的我們在後面加進去。
3、修改 CONFIG.SYS 文件爲以下內容：
====================================================
device=himem.sys /testmem:off
device=emm386.exe noems
device=oakcdrom.sys /D:mscd001
dos=high,umb
files=30
buffers=20
====================================================
把以上這 himem.sys、emm386.exe、oakcdrom.sys 三個文件加到IMG文件中，
4、修改 AUTOEXEC.BAT 文件爲以下內容：
====================================================
@ECHO OFF
set EXPAND=YES
SET DIRCMD=/O:N
cls
SET RAMD=Z
XMSDSK 9816 Z: /y
set temp=%RAMD%:\
set tmp=%RAMD%:\
mouse > NUL
FINDCD.EXE > NUL
path=%RAMD%:\;a:\;%CDROM%:\
copy command.com %RAMD%:\ > NUL
copy extract.exe %RAMD%:\ > NUL
:ERROR
IF EXIST ebd.cab GOTO EXT
echo Please insert Windows 98 Startup Disk 2
echo.
pause
GOTO ERROR
:EXT
%RAMD%:\extract /y /e /l %RAMD%: ebd.cab > NUL
cls
GOTO QUIT
:QUIT
set CDROM=
set LglDrv=
cls
tw > NUL
echo.
echo.
echo.
echo.
echo.
echo 內存虛擬磁盤已被成功創建，當前虛擬工作盤符爲 %RAMD% 盤。
echo.
echo 所需的工具都從 EBD.CAB 壓縮包中被釋放到虛擬 %RAMD% 盤中。
echo.
echo.
echo.
echo.
a:
zmenu.bat
====================================================
再把 AUTOEXEC.BAT 所需用的文件加入到 IMG 文件中。文件如下：
xmsdsk.exe、FINDCD.EXE、extract.exe、ebd.cab、tw.exe
5、主菜單的製作，我們現在以 7 個菜單項做實習，請看以下批處理文件，取名爲 ZMENU.BAT
ZMENU.BAT 批處理文件內容如下：
==================================================================================
@echo off
tw > nul
@echo off
echo.
echo 中文多功能 MS-DOS 系統啓動盤
echo ============================================================
echo.
echo 1、全自動從光盤上克隆 Windows XP SP2 專業版
echo 2、從光盤上安裝 Windows 98 SE
echo 3、帶光驅驅動的中文 Dos 命令行啓動模式
echo 4、克隆恢復從 E 盤 Tools 恢復到 C 盤模式
echo 5、啓動運行 DM 9.57 中英文雙語版分區程序
echo 6、進入查看 NTFS 分區
echo 7、工具箱 》》》
echo.
choice/c:1234567 /t:2,999 . 請在上面選項中選擇相應的數字鍵值。
if errorlevel 7 goto menu_7
if errorlevel 6 goto menu_6
if errorlevel 5 goto menu_5
if errorlevel 4 goto menu_4
if errorlevel 3 goto menu_3
if errorlevel 2 goto menu_2
if errorlevel 1 goto menu_1
:menu_1
cls
call autohf.bat
goto quit
:menu_2
cls
call 98se.bat
goto quit
:menu_3
cls
call doscd.bat
goto cdrom
:menu_4
cls
call ghosd.bat
goto quit
:menu_5
cls
call dm.bat
goto quit
:menu_6
cls
call ntfs.bat
goto quit
:menu_7
cls
call menu.bat
goto quit
:cdrom
@ECHO OFF
dready z: /w
if errorlevel 1 goto _errramd
set td=Z:\testdrv.bat
> %td% echo @echo off
>> %td% echo dready %%1
>> %td% echo if errorlevel 1 goto _quit
>> %td% echo set CDOK=%%CDOK%% %%1
>> %td% echo :_quit
LH MSCDEX.EXE /D:mscd001
set CDROM=
findcd /s > nul
SET CDOK=
for %%I in (%cdrom1% %cdrom2% %cdrom3%) DO call %td% %%I
set bootcd=
for %%I in (%cdok%) DO if exist %%I\GHOST\GHOST8.EXE set BOOTCD=%%I
IF %BOOTCD%*==* goto _nobootcd
set CDROM=%bootcd%
echo bootcd=%bootcd%
goto _findbootcdok
:_nobootcd
echo.
echo 錯誤: 系統沒有發現在 CDROM 中有光盤, 請插入配合此條件的光盤!
echo.
echo 在光盤根目錄中必須有 GHOST\GHOST.EXE 文件, 否則無法正確找到光盤!
pause
goto _quit
:_findbootcdok
echo.
echo.
echo.
echo 您當前所在的虛擬內存磁盤是在 %RAMD% 盤中!
echo.
echo.
echo 您當前所插入的光盤是在 %CDROM% 盤中!
echo.
echo.
echo 要輸入中文文字請按 Alt + F1 區位、Alt + F2 拼音、Alt + F3 五筆、
echo.
echo Alt + F4 雙拼來調出輸入法，Alt + F5 查看輸入法調出，Alt + F10 返回
echo.
goto _quit
:_errramd
echo.
echo 錯誤:不能在內存磁盤上存取 Q:!
echo.
echo 檢查 xmsdsk 是否能建立內存磁盤。
pause
goto _quit
:quit
a:
@echo off
cls
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo 如果你還想繼續操作返回主菜單請鍵入 ZMENU 回車即可!
echo.
set CDROM=
set RAMDRIVE=
:end
:_quit
a:
set CDROM=
set RAMDRIVE=
:end
==================================================================================
以上我們要用到的文件有工具和批處理文件,文件如下：
CHOICE.COM、MSCDEX.EXE、 小工具文件，其它都是批處理文件 7 個 autohf.bat、98se.bat、
doscd.bat、ghosd.bat、dm.bat、ntfs.bat、menu.bat 這 7 個批處理可以這樣寫只是提供參
考，大家可以修改，因時間有限呀。
① 這是一個全自動的克降文件。
autohf.bat
==================================================================================
這個全自動 AUTOHF.BAT 文件可按照認識多光驅支持的原理的來是一樣的，照紅色字複製就行了
==================================================================================
98se.bat 文件,這個是做全自動安裝98用的。
==================================================================================
@echo off
dready z: /w
if errorlevel 1 goto _errramd
set td=Z:\testdrv.bat
> %td% echo @echo off
>> %td% echo dready %%1:
>> %td% echo if errorlevel 1 goto _quit
>> %td% echo set CDOK=%%CDOK%% %%1
>> %td% echo :_quit
LH MSCDEX.EXE /D:mscd001
if not %CDROM%*==* set CDROM=
if not %CDROM%*==* set CDROM=
findcd /s > nul
SET CDOK=
for %%I in (%cdrom1%,%cdrom2%,%cdrom3%) DO call %td% %%I
IF NOT %CDROM%*==* set CDROM=
IF NOT %CDROM%*==* set CDROM=
set bootcd=
for %%I in (%cdok%) DO if exist %%I\setup.exe set BOOTCD=%%I
IF %BOOTCD%*==* goto _nobootcd
set CDROM=%bootcd%
echo bootcd=%bootcd%
goto _findbootcdok
:_nobootcd
echo.
echo.
echo.
echo.
echo 錯誤: 在光盤根目錄下沒有發現 WINDOWS 98 SE 的 SETUP.EXE 安裝文件 !
echo.
echo 請插入 WINDOWS 98 SE 的安裝光盤, 必須在光盤的根目錄, 不支持多層目錄!
echo.
echo.
echo.
echo.
pause
:_findbootcdok
%CDROM%\setup /is /ie /iv /im /il
zmenu.bat
goto _quit
==================================================================================
doscd.bat 文件，這個是啓動到DOS下的文件
==================================================================================
@echo off
%RAMD%:\
lh ctload VIDE-111.SYS /d:mscd001
LH MSCDEX.EXE /D:mscd001
path=%RAMD%:\;%CDROM%\;a:\
cls
a:
==================================================================================
ghosd.bat 文件，這個是手動克降的GHOST程序
==================================================================================
E:\tools\ghost -clone,mode=pload,src=E:\tools\xp-sp2.gho:1,dst=1:1,sze1=50p,sze2=50p -fx -ia -sure
zmenu.bat
==================================================================================
dm.bat 文件
==================================================================================
@echo off
tw /np > nul
dm\dm.com %1 %2 %3 %4 %5%
==================================================================================
ntfs.bat 文件
==================================================================================
ntfspro.exe > NUL 就這樣一句
==================================================================================
menu.bat 文件
==================================================================================
這是子菜單文件可以按你們的要求來寫，我這裏不做示範了。
==================================================================================
以上 7 個 菜單文件必須配合相應的工具和軟件，必須是無法運行本啓動盤的，如 DM 分區軟
件、DOS 下的五筆輸入法等等，
第三步 再把 NTFS 的程序添加到 IMG 文件中，此程序網上有下載的，名稱爲 NTFSPRO 5.0
這時因 98 的 IMG 文件只有 1.44 MB 是不夠大的，所以要加大這個 IMG 文件，可以用 EASYBOOT
裏的工具來完成，詳細不說了，如果不會做，可到我的永碩 E 盤中去下載，注意要點是必須把整
個啓動盤的文件一個不要少添加，路徑千萬不要搞錯，如我有錯處請大家指證。
《啓動盤實戰系列三, 支持多光驅和 NTFS 分區 IMG 映像》已發佈，也是結束課，如有錯處請高手指定，謝謝！
以後回覆請在本貼下回復，所有工具如果98啓動盤裏沒有，請從新 DOS 時代或DOS聯盟去下載，如實在沒有請發貼求助或在本 Q 羣裏發消息，我會上傳上來的。
注：未經同意, 不準轉貼, 謝謝合作! QQ 羣號: 11175590