ARDUINO與NRF24L01無線通信

使用的RF24庫作者TMRh20

在看到此文章前，需要確認你的板子沒有問題，新買的板子刷了Bootloader.我爲這個失誤浪費了一週的時間，所以排查任何可能。

實物接線如下：

一、nRF24L01硬件連接：
此模塊是使用SPI方式連接，在標準SPI口基礎增加CE和CSN引腳：
nRF24L01 Arduino UNO
VCC <-> 3.3V
GND <-> GND
CE <-> D9
CSN <-> D10
MOSI<-> D11
MISO<-> D12
SCK <-> D13
IRQ <-> 不接

二代碼如下：


/*
* Getting Started example sketch for nRF24L01+ radios
* This is a very basic example of how to send data from one node to another
* Updated: Dec 2014 by TMRh20
*/

#include <SPI.h>
#include "RF24.h"

/****************** User Config ***************************/
/***      Set this radio as radio number 0 or 1         ***/
bool radioNumber = 0;

/* Hardware configuration: Set up nRF24L01 radio on SPI bus plus pins 7 & 8 */
RF24 radio(9,10);
/**********************************************************/

byte addresses[][6] = {"1Node","2Node"};

// Used to control whether this node is sending or receiving
bool role = 0;

void setup() {
  Serial.begin(115200);
  Serial.println(F("RF24/examples/GettingStarted"));
  Serial.println(F("*** PRESS 'T' to begin transmitting to the other node"));
  
  radio.begin();

  // Set the PA Level low to prevent power supply related issues since this is a
 // getting_started sketch, and the likelihood of close proximity of the devices. RF24_PA_MAX is default.
  radio.setPALevel(RF24_PA_LOW);
  
  // Open a writing and reading pipe on each radio, with opposite addresses
  if(radioNumber){
    radio.openWritingPipe(addresses[1]);
    radio.openReadingPipe(1,addresses[0]);
  }else{
    radio.openWritingPipe(addresses[0]);
    radio.openReadingPipe(1,addresses[1]);
  }
  
  // Start the radio listening for data
  radio.startListening();
}

void loop() {
  
  
/****************** Ping Out Role ***************************/  
if (role == 1)  {
    
    radio.stopListening();                                    // First, stop listening so we can talk.
    
    
    Serial.println(F("Now sending"));

    unsigned long start_time = micros();                             // Take the time, and send it.  This will block until complete
     if (!radio.write( &start_time, sizeof(unsigned long) )){
       Serial.println(F("failed"));
     }
        
    radio.startListening();                                    // Now, continue listening
    
    unsigned long started_waiting_at = micros();               // Set up a timeout period, get the current microseconds
    boolean timeout = false;                                   // Set up a variable to indicate if a response was received or not
    
    while ( ! radio.available() ){                             // While nothing is received
      if (micros() - started_waiting_at > 200000 ){            // If waited longer than 200ms, indicate timeout and exit while loop
          timeout = true;
          break;
      }      
    }
        
    if ( timeout ){                                             // Describe the results
        Serial.println(F("Failed, response timed out."));
    }else{
        unsigned long got_time;                                 // Grab the response, compare, and send to debugging spew
        radio.read( &got_time, sizeof(unsigned long) );
        unsigned long end_time = micros();
        
        // Spew it
        Serial.print(F("Sent "));
        Serial.print(start_time);
        Serial.print(F(", Got response "));
        Serial.print(got_time);
        Serial.print(F(", Round-trip delay "));
        Serial.print(end_time-start_time);
        Serial.println(F(" microseconds"));
    }

    // Try again 1s later
    delay(1000);
  }



/****************** Pong Back Role ***************************/

  if ( role == 0 )
  {
    unsigned long got_time;
    
    if( radio.available()){
                                                                    // Variable for the received timestamp
      while (radio.available()) {                                   // While there is data ready
        radio.read( &got_time, sizeof(unsigned long) );             // Get the payload
      }
     
      radio.stopListening();                                        // First, stop listening so we can talk   
      radio.write( &got_time, sizeof(unsigned long) );              // Send the final one back.      
      radio.startListening();                                       // Now, resume listening so we catch the next packets.     
      Serial.print(F("Sent response "));
      Serial.println(got_time);  
   }
 }




/****************** Change Roles via Serial Commands ***************************/

  if ( Serial.available() )
  {
    char c = toupper(Serial.read());
    if ( c == 'T' && role == 0 ){      
      Serial.println(F("*** CHANGING TO TRANSMIT ROLE -- PRESS 'R' TO SWITCH BACK"));
      role = 1;                  // Become the primary transmitter (ping out)
    
   }else
    if ( c == 'R' && role == 1 ){
      Serial.println(F("*** CHANGING TO RECEIVE ROLE -- PRESS 'T' TO SWITCH BACK"));      
       role = 0;                // Become the primary receiver (pong back)
       radio.startListening();
       
    }
  }


} // Loop

代碼解析

/*
* Getting Started example sketch for nRF24L01+ radios 無線傳輸開始的示例程序
* This is a very basic example of how to send data from one node to another 這是非常基本的從一個節點向另一個節點發送數據的實例
* Updated: Dec 2014 by TMRh20 更新日期 2014年12 月
*/

#include <SPI.h>
#include "RF24.h"

/****************** User Config ***************************/
/*** Set this radio as radio number 0 or 1 設置無線編號爲0或1 ***/
bool radioNumber = 0;

/* Hardware configuration: Set up nRF24L01 radio on SPI bus plus pins 9 & 10 */硬件配置：設置RF2401在SPI總線上的脈衝引腳
RF24 radio(9,10);
/**********************************************************/

byte addresses[][6] = {"1Node","2Node"};

// Used to control whether this node is sending or receiving 用來控制這個是發送還是接收
bool role = 0;

void setup() {
Serial.begin(115200);
Serial.println(F("RF24/examples/GettingStarted"));
Serial.println(F("*** PRESS 'T' to begin transmitting to the other node"));//按“ T”開始傳輸到另一個節點

radio.begin();

// Set the PA Level low to prevent power supply related issues since this is a 將PA電平設置爲低以防止電源相關問題，因爲這是一個
// getting_started sketch, and the likelihood of close proximity of the devices. RF24_PA_MAX is default.入門程序，還介紹了設備緊密接近的可能性。默認爲RF24_PA_MAX。
radio.setPALevel(RF24_PA_LOW);

// Open a writing and reading pipe on each radio, with opposite addresses  在每個發射器上打開一個帶有相反地址的讀寫通道
if(radioNumber){
radio.openWritingPipe(addresses[1]);
radio.openReadingPipe(1,addresses[0]);
}else{
radio.openWritingPipe(addresses[0]);
radio.openReadingPipe(1,addresses[1]);
}

// Start the radio listening for data 啓動發射器收聽數據
radio.startListening();
}

void loop() {


/****************** Ping Out Role 發射發揮作用 ***************************/
if (role == 1) {

radio.stopListening(); // First, stop listening so we can talk. 首先，停止聽，以便我們交談。


Serial.println(F("Now sending"));

unsigned long start_time = micros(); // Take the time, and send it. This will block until complete 花點時間，然後發送。這將阻止直到完成
if (!radio.write( &start_time, sizeof(unsigned long) )){
Serial.println(F("failed"));
}

radio.startListening(); // Now, continue listening 現在，繼續聽

unsigned long started_waiting_at = micros(); // Set up a timeout period, get the current microseconds 設置超時時間，獲取當前的微秒
boolean timeout = false; // Set up a variable to indicate if a response was received or not 設置一個變量以指示是否收到響應

while ( ! radio.available() ){ // While nothing is received 雖然什麼也沒收到
if (micros() - started_waiting_at > 200000 ){ // If waited longer than 200ms, indicate timeout and exit while loop 如果等待時間超過200毫秒，則表示超時並在循環時退出
timeout = true;
break;
}
}

if ( timeout ){ // Describe the results 描述結果
Serial.println(F("Failed, response timed out."));
}else{
unsigned long got_time; // Grab the response, compare, and send to debugging spew 抓取響應，進行比較，然後發送給調試界面
radio.read( &got_time, sizeof(unsigned long) );
unsigned long end_time = micros();

// Spew it 吐出來
Serial.print(F("Sent "));
Serial.print(start_time);
Serial.print(F(", Got response "));
Serial.print(got_time);
Serial.print(F(", Round-trip delay "));
Serial.print(end_time-start_time);
Serial.println(F(" microseconds"));
}

// Try again 1s later 1S之後再試一次
delay(1000);
}

/****************** Pong Back Role 接收發揮作用***************************/

if ( role == 0 )
{
unsigned long got_time;

if( radio.available()){
// Variable for the received timestamp  接收時間戳的變量
while (radio.available()) { // While there is data ready 當數據準備就緒時
radio.read( &got_time, sizeof(unsigned long) ); // Get the payload 獲取有效載荷
}

radio.stopListening(); // First, stop listening so we can talk   首先，停止聽，這樣我們就可以說話
radio.write( &got_time, sizeof(unsigned long) ); // Send the final one back. 將最後一張發回。
radio.startListening(); // Now, resume listening so we catch the next packets. 現在，繼續收聽，以便我們捕獲下一個數據包。
Serial.print(F("Sent response "));
Serial.println(got_time);
}
}

/****************** Change Roles via Serial Commands 通過串口改變接收還是發送的角色 ***************************/

if ( Serial.available() )
{
char c = toupper(Serial.read());
if ( c == 'T' && role == 0 ){
Serial.println(F("*** CHANGING TO TRANSMIT ROLE -- PRESS 'R' TO SWITCH BACK"));
role = 1; // Become the primary transmitter (ping out) 成爲主要發送者（ping出）

}else
if ( c == 'R' && role == 1 ){
Serial.println(F("*** CHANGING TO RECEIVE ROLE -- PRESS 'T' TO SWITCH BACK"));
role = 0; // Become the primary receiver (pong back) 成爲主要接收者（回擊）
radio.startListening();

}
}

} // Loop

ARDUINO與NRF24L01無線通信

ACCELSTEPPER庫實例分析

AccelStepper功能及函數功能（一）

幾種步進電機控制

基於案例2，對代碼進行了修改

自動滑軌項目_參考案例2

https://yachay.unat.edu.pe/blog/index.php?comment_area=format_blog&comment_component=blog&comment_co

linux以太網驅動總結